vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/panelbar.cpp \
  74     ui/panelbase.cpp \
  75     ui/panelcontentstack.cpp \
  76     ui/panelcontextbuttonbar.cpp \
  77     ui/paneltab.cpp \
  78     ui/paneltabbar.cpp \
  79     ui/tabbedpanel.cpp \
  80     ui/routingpanel.cpp \
  81     ui/routewaypointlistitem.cpp \
  82     ui/routewaypointlistview.cpp \
  83     user/user.cpp \
  84     ui/meetpeoplepanel.cpp \
  85     situareservice/database.cpp
  86 HEADERS += application.h \
  87     common.h \
  88     coordinates/geocoordinate.h \
  89     coordinates/scenecoordinate.h \
  90     engine/engine.h \
  91     engine/mce.h \
  92     error.h \
  93     facebookservice/facebookauthentication.h \
  94     facebookservice/facebookcommon.h \
  95     facebookservice/facebookcredentials.h \
  96     gps/gpscommon.h \
  97     gps/gpsposition.h \
  98     map/baselocationitem.h \
  99     map/friendgroupitem.h \
 100     map/frienditemshandler.h \
 101     map/friendlocationitem.h \
 102     map/gpslocationitem.h \
 103     map/mapcommon.h \
 104     map/mapengine.h \
 105     map/mapfetcher.h \
 106     map/maprouteitem.h \
 107     map/mapscene.h \
 108     map/mapscroller.h \
 109     map/maptile.h \
 110     map/maptilerequest.h \
 111     map/mapview.h \
 112     map/osm.h \
 113     map/ownlocationitem.h \
 114     network/networkaccessmanager.h \
 115     network/networkcookiejar.h \
 116     network/networkhandler.h \
 117     network/networkreply.h \
 118     routing/geocodingservice.h \
 119     routing/location.h \
 120     routing/route.h \
 121     routing/routesegment.h \
 122     routing/routingcommon.h \
 123     routing/routingservice.h \
 124     situareservice/imagefetcher.h \
 125     situareservice/situarecommon.h \
 126     situareservice/situareservice.h \
 127     ui/updatelocation/texteditautoresizer.h \
 128     ui/updatelocation/updatelocationdialog.h \
 129     ui/avatarimage.h \
 130     ui/extendedlistitem.h \
 131     ui/extendedlistitemdelegate.h \
 132     ui/extendedlistitemstore.h \
 133     ui/friendlistitem.h \
 134     ui/friendlistitemdelegate.h \
 135     ui/friendlistpanel.h \
 136     ui/friendlistview.h \
 137     ui/fullscreenbutton.h \
 138     ui/imagebutton.h \
 139     ui/indicatorbutton.h \
 140     ui/indicatorbuttonpanel.h \
 141     ui/logindialog.h \
 142     ui/locationlistitem.h \
 143     ui/locationlistview.h \
 144     ui/mainwindow.h \
 145     ui/mapscale.h \
 146     ui/settingsdialog.h \
 147     ui/userinfo.h \
 148     ui/userinfopanel.h \
 149     ui/zoombutton.h \
 150     ui/zoombuttonpanel.h \
 151     ui/listcommon.h \
 152     ui/listview.h \
 153     ui/listitem.h \
 154     ui/listitemdelegate.h \
 155     ui/searchdialog.h \
 156     ui/panelbar.h \
 157     ui/panelbase.h \
 158     ui/panelcommon.h \
 159     ui/panelcontentstack.h \
 160     ui/panelcontextbuttonbar.h \
 161     ui/paneltab.h \
 162     ui/paneltabbar.h \
 163     ui/tabbedpanel.h \
 164     ui/routingpanel.h \
 165     ui/routewaypointlistitem.h \
 166     ui/routewaypointlistview.h \
 167     user/user.h \
 168     ui/meetpeoplepanel.h \
 169     situareservice/database.h
 170 QT += network \
 171     webkit \
 172     sql
 173
 174 DEFINES += QT_NO_DEBUG_OUTPUT
 175
 176 simulator {
 177     SOURCES += network/networkhandlerprivatestub.cpp \
 178                gps/gpspositionprivate.cpp
 179     HEADERS += network/networkhandlerprivatestub.h \
 180                gps/gpspositionprivate.h
 181     QT += maemo5
 182     CONFIG += mobility
 183     MOBILITY += location messaging
 184 } else:maemo5 {
 185     armel {
 186         DEFINES += ARMEL
 187         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 188         SOURCES += network/networkhandlerprivate.cpp \
 189                    engine/mceprivate.cpp
 190         HEADERS += network/networkhandlerprivate.h \
 191                    engine/mceprivate.h
 192         QT += dbus xml
 193         CONFIG += icd2 qdbus
 194         SOURCES += gps/gpspositionprivateliblocation.cpp \
 195                    gps/liblocationwrapper.cpp \
 196                    gps/geopositioninfo.cpp
 197         HEADERS += gps/gpspositionprivateliblocation.h \
 198                    gps/liblocationwrapper.h \
 199                    gps/geopositioninfo.h
 200         CONFIG += link_pkgconfig
 201         PKGCONFIG += glib-2.0 liblocation mce
 202         LIBS += -llocation
 203         CONFIG += mobility
 204         MOBILITY += messaging
 205
 206     } else {
 207         SOURCES += gps/gpspositionprivatestub.cpp \
 208                    network/networkhandlerprivatestub.cpp \
 209                    engine/mceprivatestub.cpp
 210         HEADERS += gps/gpspositionprivatestub.h \
 211                    network/networkhandlerprivatestub.h \
 212                    engine/mceprivatestub.h
 213     }
 214
 215     QT += maemo5
 216
 217     message([QJson])
 218     message(Make sure you have QJson development headers installed)
 219     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 220     message(to Scratchbox's sources.list in /etc/apt)
 221     message(run: apt-get update)
 222     message(install headers with: apt-get install libqjson-dev)
 223     message([QtMobility])
 224     message(Make sure you have QtMobility development headers installed)
 225     message(install headers with: apt-get install libqtm-dev)
 226 } else {
 227     SOURCES += gps/gpspositionprivatestub.cpp \
 228                network/networkhandlerprivatestub.cpp \
 229                engine/mceprivatestub.cpp
 230     HEADERS += gps/gpspositionprivatestub.h \
 231                network/networkhandlerprivatestub.h \
 232                engine/mceprivatestub.h
 233     message(QJson built in)
 234     message(Make sure you have QJson development headers installed)
 235     message(install headers with: sudo apt-get install libqjson-dev)
 236 }
 237
 238 # -----------------------------------------------------------------
 239 # Debian packetizing additions
 240 # -----------------------------------------------------------------
 241 unix {
 242     # VARIABLES
 243     isEmpty(PREFIX):PREFIX = /usr
 244     BINDIR = $$PREFIX/bin
 245     DATADIR = $$PREFIX/share
 246     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 247         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 248
 249     # MAKE INSTALL
 250     desktop.path = $$DATADIR/applications/hildon
 251     desktop.files += situare.desktop
 252     INSTALLS += desktop
 253     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 254     icon48.files += ../res/icon/48x48/situare.png
 255     INSTALLS += icon48
 256     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 257     icon64.files += ../res/icon/64x64/situare.png
 258     INSTALLS += icon64
 259     target.path = $$BINDIR
 260     INSTALLS += target
 261 }