vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc
   9 SOURCES += main.cpp \
  10     ui/mainwindow.cpp \
  11     situareservice/situareservice.cpp \
  12     situareservice/imagefetcher.cpp \
  13     facebookservice/facebookcredentials.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     map/mapengine.cpp \
  16     map/mapview.cpp \
  17     map/mapscene.cpp \
  18     map/maptile.cpp \
  19     map/mapfetcher.cpp \
  20     map/ownlocationitem.cpp \
  21     map/baselocationitem.cpp \
  22     map/friendlocationitem.cpp \
  23     ui/updatelocation/updatelocationdialog.cpp \
  24     ui/updatelocation/texteditautoresizer.cpp \
  25     ui/friendlistview.cpp \
  26     ui/friendlistitem.cpp \
  27     user/user.cpp \
  28     ui/avatarimage.cpp \
  29     engine/engine.cpp \
  30     ui/settingsdialog.cpp \
  31     ui/logindialog.cpp \
  32     map/maptilerequest.cpp \
  33     ui/imagebutton.cpp \
  34     ui/friendlistpanel.cpp \
  35     ui/userinfopanel.cpp \
  36     ui/panelsidebar.cpp \
  37     ui/panelsliderbar.cpp \
  38     map/friendgroupitem.cpp \
  39     map/frienditemshandler.cpp \
  40     gps/gpsposition.cpp \
  41     map/gpslocationitem.cpp \
  42     ui/zoombuttonpanel.cpp \
  43     ui/userinfo.cpp \
  44     ui/sidepanel.cpp \
  45     ui/zoombutton.cpp \
  46     network/networkaccessmanager.cpp \
  47     network/networkhandler.cpp \
  48     network/networkreply.cpp
  49 HEADERS += ui/mainwindow.h \
  50     map/mapengine.h \
  51     map/mapview.h \
  52     map/mapscene.h \
  53     map/maptile.h \
  54     map/mapfetcher.h \
  55     map/mapcommon.h \
  56     map/ownlocationitem.h \
  57     map/baselocationitem.h \
  58     map/friendlocationitem.h \
  59     ui/updatelocation/updatelocationdialog.h \
  60     ui/updatelocation/texteditautoresizer.h \
  61     situareservice/situareservice.h \
  62     situareservice/situarecommon.h \
  63     situareservice/imagefetcher.h \
  64     facebookservice/facebookcredentials.h \
  65     facebookservice/facebookauthentication.h \
  66     facebookservice/facebookcommon.h \
  67     ui/friendlistview.h \
  68     ui/friendlistitem.h \
  69     user/user.h \
  70     ui/avatarimage.h \
  71     engine/engine.h \
  72     ui/settingsdialog.h \
  73     ui/logindialog.h \
  74     map/maptilerequest.h \
  75     ui/imagebutton.h \
  76     ui/friendlistpanel.h \
  77     ui/userinfopanel.h \
  78     ui/panelcommon.h \
  79     ui/panelsidebar.h \
  80     ui/panelsliderbar.h \
  81     map/friendgroupitem.h \
  82     map/frienditemshandler.h \
  83     gps/gpsposition.h \
  84     map/gpslocationitem.h \
  85     gps/gpscommon.h \
  86     ui/zoombuttonpanel.h \
  87     common.h \
  88     ui/userinfo.h \
  89     ui/sidepanel.h \
  90     ui/zoombutton.h \
  91     network/networkaccessmanager.h \
  92     network/networkhandler.h \
  93     network/networkreply.h
  94 QT += network \
  95     webkit
  96
  97 DEFINES += QT_NO_DEBUG_OUTPUT
  98
  99 maemo5 | simulator {
 100     INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 101     SOURCES += gps/gpspositionprivate.cpp \
 102                network/networkhandlerprivate.cpp
 103     HEADERS += gps/gpspositionprivate.h \
 104                network/networkhandlerprivate.h
 105     QT += maemo5 dbus
 106     CONFIG += mobility icd2
 107     MOBILITY = location
 108     message([QJson])
 109     message(Make sure you have QJson development headers installed)
 110     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 111     message(to Scratchbox's sources.list in /etc/apt)
 112     message(run: apt-get update)
 113     message(install headers with: apt-get install libqjson-dev)
 114     message([QtMobility])
 115     message(Make sure you have QtMobility development headers installed)
 116     message(install headers with: apt-get install libqtm-dev)
 117 } else {
 118     SOURCES += gps/gpspositionprivatestub.cpp \
 119                network/networkhandlerprivatestub.cpp
 120     HEADERS += gps/gpspositionprivatestub.h \
 121                network/networkhandlerprivatestub.h
 122     message(QJson built in)
 123     message(Make sure you have QJson development headers installed)
 124     message(install headers with: sudo apt-get install libqjson-dev)
 125 }
 126
 127 # -----------------------------------------------------------------
 128 # Debian packetizing additions
 129 # -----------------------------------------------------------------
 130 unix {
 131     # VARIABLES
 132     isEmpty(PREFIX):PREFIX = /usr
 133     BINDIR = $$PREFIX/bin
 134     DATADIR = $$PREFIX/share
 135     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 136         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 137
 138     # MAKE INSTALL
 139     desktop.path = $$DATADIR/applications/hildon
 140     desktop.files += situare.desktop
 141     INSTALLS += desktop
 142     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 143     icon48.files += ../res/icon/48x48/situare.png
 144     INSTALLS += icon48
 145     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 146     icon64.files += ../res/icon/64x64/situare.png
 147     INSTALLS += icon64
 148     target.path = $$BINDIR
 149     INSTALLS += target
 150 }