vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/paneltab.cpp \
  74     ui/tabbedpanel.cpp \
  75     ui/panelbar.cpp \
  76     ui/panelcontent.cpp \
  77     ui/panelbase.cpp \
  78     user/user.cpp \
  79     ui/routingpanel.cpp
  80 HEADERS += application.h \
  81     common.h \
  82     engine/engine.h \
  83     error.h \
  84     facebookservice/facebookauthentication.h \
  85     facebookservice/facebookcommon.h \
  86     facebookservice/facebookcredentials.h \
  87     gps/gpscommon.h \
  88     gps/gpsposition.h \
  89     map/baselocationitem.h \
  90     map/friendgroupitem.h \
  91     map/frienditemshandler.h \
  92     map/friendlocationitem.h \
  93     map/gpslocationitem.h \
  94     map/mapcommon.h \
  95     map/mapengine.h \
  96     map/mapfetcher.h \
  97     map/mapscene.h \
  98     map/mapscroller.h \
  99     map/maptile.h \
 100     map/maptilerequest.h \
 101     map/mapview.h \
 102     map/ownlocationitem.h \
 103     network/networkaccessmanager.h \
 104     network/networkcookiejar.h \
 105     network/networkhandler.h \
 106     network/networkreply.h \
 107     situareservice/imagefetcher.h \
 108     situareservice/situarecommon.h \
 109     situareservice/situareservice.h \
 110     ui/updatelocation/texteditautoresizer.h \
 111     ui/updatelocation/updatelocationdialog.h \
 112     ui/avatarimage.h \
 113     ui/friendlistitem.h \
 114     ui/friendlistpanel.h \
 115     ui/imagebutton.h \
 116     ui/logindialog.h \
 117     ui/mainwindow.h \
 118     ui/mapscale.h \
 119     ui/panelcommon.h \
 120     ui/settingsdialog.h \
 121     ui/userinfo.h \
 122     ui/userinfopanel.h \
 123     ui/zoombutton.h \
 124     ui/zoombuttonpanel.h \
 125     user/user.h \
 126     ui/fullscreenbutton.h \
 127     engine/mce.h \
 128     ui/indicatorbutton.h \
 129     ui/indicatorbuttonpanel.h \
 130     routing/geocodingservice.h \
 131     routing/routingservice.h \
 132     routing/routingcommon.h \
 133     routing/routesegment.h \
 134     routing/route.h \
 135     routing/location.h \
 136     map/maprouteitem.h \
 137     map/osm.h \
 138     coordinates/scenecoordinate.h \
 139     coordinates/geocoordinate.h \
 140     ui/listview.h \
 141     ui/listitem.h \
 142     ui/listitemdelegate.h \
 143     ui/friendlistitemdelegate.h \
 144     ui/listcommon.h \
 145     ui/searchdialog.h \
 146     ui/locationlistitem.h \
 147     ui/extendedlistitem.h \
 148     ui/extendedlistitemstore.h \
 149     ui/extendedlistitemdelegate.h \
 150     ui/locationlistview.h \
 151     ui/friendlistview.h \
 152     error.h \
 153     ui/paneltab.h \
 154     ui/tabbedpanel.h \
 155     ui/panelbar.h \
 156     ui/panelcontent.h \
 157     ui/panelbase.h \
 158     ui/routingpanel.h
 159 QT += network \
 160     webkit
 161
 162 DEFINES += QT_NO_DEBUG_OUTPUT
 163
 164 simulator {
 165     SOURCES += network/networkhandlerprivatestub.cpp \
 166                gps/gpspositionprivate.cpp
 167     HEADERS += network/networkhandlerprivatestub.h \
 168                gps/gpspositionprivate.h
 169     QT += maemo5
 170     CONFIG += mobility
 171     MOBILITY += location
 172 } else:maemo5 {
 173     armel {
 174         DEFINES += ARMEL
 175         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 176         SOURCES += network/networkhandlerprivate.cpp \
 177                    engine/mceprivate.cpp
 178         HEADERS += network/networkhandlerprivate.h \
 179                    engine/mceprivate.h
 180         QT += dbus xml
 181         CONFIG += icd2 qdbus
 182         SOURCES += gps/gpspositionprivateliblocation.cpp \
 183                    gps/liblocationwrapper.cpp \
 184                    gps/geopositioninfo.cpp
 185         HEADERS += gps/gpspositionprivateliblocation.h \
 186                    gps/liblocationwrapper.h \
 187                    gps/geopositioninfo.h
 188         CONFIG += link_pkgconfig
 189         PKGCONFIG += glib-2.0 liblocation mce
 190         LIBS += -llocation
 191     } else {
 192         SOURCES += gps/gpspositionprivatestub.cpp \
 193                    network/networkhandlerprivatestub.cpp \
 194                    engine/mceprivatestub.cpp
 195         HEADERS += gps/gpspositionprivatestub.h \
 196                    network/networkhandlerprivatestub.h \
 197                    engine/mceprivatestub.h
 198     }
 199
 200     QT += maemo5
 201
 202     message([QJson])
 203     message(Make sure you have QJson development headers installed)
 204     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 205     message(to Scratchbox's sources.list in /etc/apt)
 206     message(run: apt-get update)
 207     message(install headers with: apt-get install libqjson-dev)
 208     message([QtMobility])
 209     message(Make sure you have QtMobility development headers installed)
 210     message(install headers with: apt-get install libqtm-dev)
 211 } else {
 212     SOURCES += gps/gpspositionprivatestub.cpp \
 213                network/networkhandlerprivatestub.cpp \
 214                engine/mceprivatestub.cpp
 215     HEADERS += gps/gpspositionprivatestub.h \
 216                network/networkhandlerprivatestub.h \
 217                engine/mceprivatestub.h
 218     message(QJson built in)
 219     message(Make sure you have QJson development headers installed)
 220     message(install headers with: sudo apt-get install libqjson-dev)
 221 }
 222
 223 # -----------------------------------------------------------------
 224 # Debian packetizing additions
 225 # -----------------------------------------------------------------
 226 unix {
 227     # VARIABLES
 228     isEmpty(PREFIX):PREFIX = /usr
 229     BINDIR = $$PREFIX/bin
 230     DATADIR = $$PREFIX/share
 231     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 232         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 233
 234     # MAKE INSTALL
 235     desktop.path = $$DATADIR/applications/hildon
 236     desktop.files += situare.desktop
 237     INSTALLS += desktop
 238     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 239     icon48.files += ../res/icon/48x48/situare.png
 240     INSTALLS += icon48
 241     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 242     icon64.files += ../res/icon/64x64/situare.png
 243     INSTALLS += icon64
 244     target.path = $$BINDIR
 245     INSTALLS += target
 246 }