vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     engine/engine.cpp \
  13     facebookservice/facebookauthentication.cpp \
  14     facebookservice/facebookcredentials.cpp \
  15     gps/gpsposition.cpp \
  16     map/baselocationitem.cpp \
  17     map/friendgroupitem.cpp \
  18     map/frienditemshandler.cpp \
  19     map/friendlocationitem.cpp \
  20     map/gpslocationitem.cpp \
  21     map/mapengine.cpp \
  22     map/mapfetcher.cpp \
  23     map/mapscene.cpp \
  24     map/mapscroller.cpp \
  25     map/maptile.cpp \
  26     map/maptilerequest.cpp \
  27     map/mapview.cpp \
  28     map/ownlocationitem.cpp \
  29     network/networkaccessmanager.cpp \
  30     network/networkcookiejar.cpp \
  31     network/networkhandler.cpp \
  32     network/networkreply.cpp \
  33     situareservice/imagefetcher.cpp \
  34     situareservice/situareservice.cpp \
  35     ui/updatelocation/texteditautoresizer.cpp \
  36     ui/updatelocation/updatelocationdialog.cpp \
  37     ui/avatarimage.cpp \
  38     ui/friendlistitem.cpp \
  39     ui/friendlistpanel.cpp \
  40     ui/friendlistview.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp
  56 HEADERS += common.h \
  57     engine/engine.h \
  58     facebookservice/facebookauthentication.h \
  59     facebookservice/facebookcommon.h \
  60     facebookservice/facebookcredentials.h \
  61     gps/gpscommon.h \
  62     gps/gpsposition.h \
  63     map/baselocationitem.h \
  64     map/friendgroupitem.h \
  65     map/frienditemshandler.h \
  66     map/friendlocationitem.h \
  67     map/gpslocationitem.h \
  68     map/mapcommon.h \
  69     map/mapengine.h \
  70     map/mapfetcher.h \
  71     map/mapscene.h \
  72     map/mapscroller.h \
  73     map/maptile.h \
  74     map/maptilerequest.h \
  75     map/mapview.h \
  76     map/ownlocationitem.h \
  77     network/networkaccessmanager.h \
  78     network/networkcookiejar.h \
  79     network/networkhandler.h \
  80     network/networkreply.h \
  81     situareservice/imagefetcher.h \
  82     situareservice/situarecommon.h \
  83     situareservice/situareservice.h \
  84     ui/updatelocation/texteditautoresizer.h \
  85     ui/updatelocation/updatelocationdialog.h \
  86     ui/avatarimage.h \
  87     ui/friendlistitem.h \
  88     ui/friendlistpanel.h \
  89     ui/friendlistview.h \
  90     ui/imagebutton.h \
  91     ui/logindialog.h \
  92     ui/mainwindow.h \
  93     ui/mapscale.h \
  94     ui/panelcommon.h \
  95     ui/panelsidebar.h \
  96     ui/panelsliderbar.h \
  97     ui/settingsdialog.h \
  98     ui/userinfo.h \
  99     ui/userinfopanel.h \
 100     ui/sidepanel.h \
 101     ui/sidepanelbase.h \
 102     ui/zoombutton.h \
 103     ui/zoombuttonpanel.h \
 104     user/user.h \
 105     ui/fullscreenbutton.h
 106 QT += network \
 107     webkit
 108 DEFINES += QT_NO_DEBUG_OUTPUT
 109
 110 simulator {
 111     SOURCES += network/networkhandlerprivatestub.cpp \
 112                gps/gpspositionprivate.cpp
 113     HEADERS += network/networkhandlerprivatestub.h \
 114                gps/gpspositionprivate.h
 115     QT += maemo5
 116     CONFIG += mobility
 117     MOBILITY += location
 118 } else:maemo5 {
 119     armel {
 120         DEFINES += ARMEL
 121         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 122         SOURCES += network/networkhandlerprivate.cpp
 123         HEADERS += network/networkhandlerprivate.h
 124         QT += dbus
 125         CONFIG += icd2
 126         SOURCES += gps/gpspositionprivateliblocation.cpp \
 127                    gps/liblocationwrapper.cpp \
 128                    gps/geopositioninfo.cpp \
 129                    gps/geocoordinate.cpp
 130         HEADERS += gps/gpspositionprivateliblocation.h \
 131                    gps/liblocationwrapper.h \
 132                    gps/geopositioninfo.h \
 133                    gps/geocoordinate.h
 134         CONFIG += link_pkgconfig
 135         PKGCONFIG += glib-2.0 liblocation
 136     } else {
 137         SOURCES += gps/gpspositionprivatestub.cpp \
 138                    network/networkhandlerprivatestub.cpp
 139         HEADERS += gps/gpspositionprivatestub.h \
 140                    network/networkhandlerprivatestub.h
 141     }
 142
 143     QT += maemo5
 144
 145     message([QJson])
 146     message(Make sure you have QJson development headers installed)
 147     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 148     message(to Scratchbox's sources.list in /etc/apt)
 149     message(run: apt-get update)
 150     message(install headers with: apt-get install libqjson-dev)
 151     message([QtMobility])
 152     message(Make sure you have QtMobility development headers installed)
 153     message(install headers with: apt-get install libqtm-dev)
 154 } else {
 155     SOURCES += gps/gpspositionprivatestub.cpp \
 156                network/networkhandlerprivatestub.cpp
 157     HEADERS += gps/gpspositionprivatestub.h \
 158                network/networkhandlerprivatestub.h
 159     message(QJson built in)
 160     message(Make sure you have QJson development headers installed)
 161     message(install headers with: sudo apt-get install libqjson-dev)
 162 }
 163
 164 # -----------------------------------------------------------------
 165 # Debian packetizing additions
 166 # -----------------------------------------------------------------
 167 unix {
 168     # VARIABLES
 169     isEmpty(PREFIX):PREFIX = /usr
 170     BINDIR = $$PREFIX/bin
 171     DATADIR = $$PREFIX/share
 172     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 173         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 174
 175     # MAKE INSTALL
 176     desktop.path = $$DATADIR/applications/hildon
 177     desktop.files += situare.desktop
 178     INSTALLS += desktop
 179     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 180     icon48.files += ../res/icon/48x48/situare.png
 181     INSTALLS += icon48
 182     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 183     icon64.files += ../res/icon/64x64/situare.png
 184     INSTALLS += icon64
 185     target.path = $$BINDIR
 186     INSTALLS += target
 187 }