vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     routing/routingservice.cpp \
  58     routing/routesegment.cpp \
  59     routing/route.cpp \
  60     map/maprouteitem.cpp \
  61     coordinates/scenecoordinate.cpp \
  62     coordinates/geocoordinate.cpp \
  63     ui/listview.cpp \
  64     ui/listitem.cpp \
  65     ui/listitemdelegate.cpp \
  66     ui/friendlistitemdelegate.cpp
  67 HEADERS += application.h \
  68     common.h \
  69     engine/engine.h \
  70     facebookservice/facebookauthentication.h \
  71     facebookservice/facebookcommon.h \
  72     facebookservice/facebookcredentials.h \
  73     gps/gpscommon.h \
  74     gps/gpsposition.h \
  75     map/baselocationitem.h \
  76     map/friendgroupitem.h \
  77     map/frienditemshandler.h \
  78     map/friendlocationitem.h \
  79     map/gpslocationitem.h \
  80     map/mapcommon.h \
  81     map/mapengine.h \
  82     map/mapfetcher.h \
  83     map/mapscene.h \
  84     map/mapscroller.h \
  85     map/maptile.h \
  86     map/maptilerequest.h \
  87     map/mapview.h \
  88     map/ownlocationitem.h \
  89     network/networkaccessmanager.h \
  90     network/networkcookiejar.h \
  91     network/networkhandler.h \
  92     network/networkreply.h \
  93     situareservice/imagefetcher.h \
  94     situareservice/situarecommon.h \
  95     situareservice/situareservice.h \
  96     ui/updatelocation/texteditautoresizer.h \
  97     ui/updatelocation/updatelocationdialog.h \
  98     ui/avatarimage.h \
  99     ui/friendlistitem.h \
 100     ui/friendlistpanel.h \
 101     ui/imagebutton.h \
 102     ui/logindialog.h \
 103     ui/mainwindow.h \
 104     ui/mapscale.h \
 105     ui/panelcommon.h \
 106     ui/panelsidebar.h \
 107     ui/panelsliderbar.h \
 108     ui/settingsdialog.h \
 109     ui/userinfo.h \
 110     ui/userinfopanel.h \
 111     ui/sidepanel.h \
 112     ui/sidepanelbase.h \
 113     ui/zoombutton.h \
 114     ui/zoombuttonpanel.h \
 115     user/user.h \
 116     ui/fullscreenbutton.h \
 117     engine/mce.h \
 118     routing/routingservice.h \
 119     routing/routingcommon.h \
 120     routing/routesegment.h \
 121     routing/route.h \
 122     map/maprouteitem.h \
 123     map/osm.h \
 124     coordinates/scenecoordinate.h \
 125     coordinates/geocoordinate.h \
 126     ui/listview.h \
 127     ui/listitem.h \
 128     ui/listitemdelegate.h \
 129     ui/friendlistitemdelegate.h \
 130     ui/listcommon.h
 131 QT += network \
 132     webkit
 133
 134 DEFINES += QT_NO_DEBUG_OUTPUT
 135
 136 simulator {
 137     SOURCES += network/networkhandlerprivatestub.cpp \
 138                gps/gpspositionprivate.cpp
 139     HEADERS += network/networkhandlerprivatestub.h \
 140                gps/gpspositionprivate.h
 141     QT += maemo5
 142     CONFIG += mobility
 143     MOBILITY += location
 144 } else:maemo5 {
 145     armel {
 146         DEFINES += ARMEL
 147         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 148         SOURCES += network/networkhandlerprivate.cpp \
 149                    engine/mceprivate.cpp
 150         HEADERS += network/networkhandlerprivate.h \
 151                    engine/mceprivate.h
 152         QT += dbus
 153         CONFIG += icd2 qdbus
 154         SOURCES += gps/gpspositionprivateliblocation.cpp \
 155                    gps/liblocationwrapper.cpp \
 156                    gps/geopositioninfo.cpp
 157         HEADERS += gps/gpspositionprivateliblocation.h \
 158                    gps/liblocationwrapper.h \
 159                    gps/geopositioninfo.h
 160         CONFIG += link_pkgconfig
 161         PKGCONFIG += glib-2.0 liblocation mce
 162         LIBS += -llocation
 163     } else {
 164         SOURCES += gps/gpspositionprivatestub.cpp \
 165                    network/networkhandlerprivatestub.cpp \
 166                    engine/mceprivatestub.cpp
 167         HEADERS += gps/gpspositionprivatestub.h \
 168                    network/networkhandlerprivatestub.h \
 169                    engine/mceprivatestub.h
 170     }
 171
 172     QT += maemo5
 173
 174     message([QJson])
 175     message(Make sure you have QJson development headers installed)
 176     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 177     message(to Scratchbox's sources.list in /etc/apt)
 178     message(run: apt-get update)
 179     message(install headers with: apt-get install libqjson-dev)
 180     message([QtMobility])
 181     message(Make sure you have QtMobility development headers installed)
 182     message(install headers with: apt-get install libqtm-dev)
 183 } else {
 184     SOURCES += gps/gpspositionprivatestub.cpp \
 185                network/networkhandlerprivatestub.cpp \
 186                engine/mceprivatestub.cpp
 187     HEADERS += gps/gpspositionprivatestub.h \
 188                network/networkhandlerprivatestub.h \
 189                engine/mceprivatestub.h
 190     message(QJson built in)
 191     message(Make sure you have QJson development headers installed)
 192     message(install headers with: sudo apt-get install libqjson-dev)
 193 }
 194
 195 # -----------------------------------------------------------------
 196 # Debian packetizing additions
 197 # -----------------------------------------------------------------
 198 unix {
 199     # VARIABLES
 200     isEmpty(PREFIX):PREFIX = /usr
 201     BINDIR = $$PREFIX/bin
 202     DATADIR = $$PREFIX/share
 203     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 204         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 205
 206     # MAKE INSTALL
 207     desktop.path = $$DATADIR/applications/hildon
 208     desktop.files += situare.desktop
 209     INSTALLS += desktop
 210     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 211     icon48.files += ../res/icon/48x48/situare.png
 212     INSTALLS += icon48
 213     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 214     icon64.files += ../res/icon/64x64/situare.png
 215     INSTALLS += icon64
 216     target.path = $$BINDIR
 217     INSTALLS += target
 218 }