vcs.maemo.org Git - cinaest/blob - src/movie-list-window.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListWindow : StackableWindow {
  23         private MovieListMenu menu;
  24         private Hildon.EditToolbar edit_toolbar;
  25         private Hildon.Entry search_field;
  26         private Toolbar search_bar;
  27         private uint source_id;
  28         private MovieListView movie_list;
  29         private MovieFilter filter;
  30         private MovieListStore store;
  31         private Label no_movies;
  32         private bool search_bar_visible;
  33         private MovieWindow movie_window;
  34         private Alignment alignment;
  35
  36         public MovieListWindow (MovieSource source) {
  37                 set_title (source.get_description ());
  38
  39                 // View menu
  40                 menu = new MovieListMenu (this);
  41                 menu.source = source;
  42
  43                 set_main_menu (menu);
  44
  45                 // Search bar
  46                 search_field = new Hildon.Entry (SizeType.FINGER_HEIGHT);
  47
  48                 var search_field_item = new ToolItem ();
  49                 search_field_item.set_expand (true);
  50                 search_field_item.add (search_field);
  51
  52                 var icon_theme = Gtk.IconTheme.get_default ();
  53                 var pixbuf = icon_theme.load_icon ("general_close",
  54                                                    48,
  55                                                    Gtk.IconLookupFlags.NO_SVG);
  56                 var close_image = new Image.from_pixbuf (pixbuf);
  57                 var close_button = new ToolButton (close_image, _("Close"));
  58
  59                 search_bar = new Toolbar ();
  60                 search_bar.insert (search_field_item, 0);
  61                 search_bar.insert (close_button, 1);
  62
  63                 add_toolbar (search_bar);
  64
  65                 // Movie list - connected to menu for sorting
  66                 movie_list = new MovieListView ();
  67                 menu.sortable = movie_list.sorted_store;
  68                 store = movie_list.store;
  69                 store.source = source;
  70
  71                 no_movies = new Label (_("No movies"));
  72                 Hildon.helper_set_logical_font (no_movies, "LargeSystemFont");
  73                 Hildon.helper_set_logical_color (no_movies, RcFlags.FG, StateType.NORMAL, "SecondaryTextColor");
  74                 no_movies.set_size_request (-1, 6 * 70);
  75                 no_movies.set_alignment ((float) 0.5, (float) 0.42);
  76
  77                 var vbox = new VBox (false, 0);
  78                 vbox.pack_start (movie_list, true, true, 0);
  79                 vbox.pack_start (no_movies, false, false, 0);
  80
  81                 alignment = new Alignment (0.0f, 0.0f, 1.0f, 1.0f);
  82                 alignment.top_padding = MARGIN_HALF;
  83                 alignment.left_padding = MARGIN_DOUBLE;
  84                 alignment.right_padding = MARGIN_DOUBLE;
  85
  86                 alignment.add (vbox);
  87                 add (alignment);
  88
  89                 edit_toolbar = new Hildon.EditToolbar.with_text (_("Select movies"), _("Delete"));
  90                 set_edit_toolbar (edit_toolbar);
  91
  92                 // Connect signals
  93                 menu.filter_changed.connect (() => { start_search (); });
  94                 edit_toolbar.button_clicked.connect (on_delete_button_clicked);
  95                 edit_toolbar.arrow_clicked.connect (leave_edit_mode);
  96                 search_field.changed.connect (on_search_field_changed);
  97                 close_button.clicked.connect (on_close_button_clicked);
  98                 key_press_event.connect (on_key_press_event);
  99                 movie_list.movie_activated.connect (on_movie_activated);
 100                 store.search_finished.connect (on_search_finished);
 101
 102                 store.notify["update-running"].connect (on_update_running_changed);
 103
 104                 search_field.set_flags (WidgetFlags.CAN_DEFAULT);
 105                 search_field.grab_default ();
 106
 107                 show_all ();
 108                 edit_toolbar.hide ();
 109                 search_bar_visible = false;
 110                 search_bar.hide ();
 111
 112                 filter = new MovieFilter ();
 113                 menu.filter = filter;
 114                 filter.title = "";
 115                 if (store.start_search (filter)) {
 116                         no_movies.hide ();
 117                 } else {
 118                         movie_list.hide ();
 119                 }
 120         }
 121
 122         public void on_delete_movies_clicked () {
 123                 fullscreen ();
 124                 edit_toolbar.show ();
 125                 movie_list.set_hildon_ui_mode (UIMode.EDIT);
 126
 127                 var selection = movie_list.get_selection ();
 128                 selection.unselect_all ();
 129         }
 130
 131         private void on_delete_button_clicked () {
 132                 var selection = movie_list.get_selection ();
 133                 int count = selection.count_selected_rows ();
 134                 if (count == 0) {
 135                         Banner.show_information (this, null, _("No movies selected"));
 136                         leave_edit_mode ();
 137                         return;
 138                 }
 139
 140                 var dialog = new Note.confirmation (this, _("Delete %d movies?").printf (count));
 141                 var res = dialog.run ();
 142
 143                 if (res == Gtk.ResponseType.OK) {
 144                         weak TreeModel model;
 145                         var rows = selection.get_selected_rows (out model);
 146
 147                         var movies = new List<Movie> ();
 148
 149                         // get selected movies from the store
 150                         foreach (TreePath path in rows) {
 151                                 TreeIter iter;
 152
 153                                 if (model.get_iter (out iter, path)) {
 154                                         Movie movie;
 155
 156                                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 157                                         if (movie != null) {
 158                                                 movies.append (movie);
 159                                         }
 160                                 }
 161                         }
 162                         // and remove them
 163                         foreach (Movie movie in movies) {
 164                                 store.remove (movie);
 165                         }
 166
 167                         // Switch to "No movies" label if the store is emptied
 168                         TreeIter iter;
 169                         if (!store.get_iter_first (out iter)) {
 170                                 movie_list.hide ();
 171                                 no_movies.show ();
 172                         }
 173                 }
 174                 dialog.destroy ();
 175                 leave_edit_mode ();
 176         }
 177
 178         private void leave_edit_mode () {
 179                 movie_list.set_hildon_ui_mode (UIMode.NORMAL);
 180                 edit_toolbar.hide ();
 181                 unfullscreen ();
 182         }
 183
 184         private void on_close_button_clicked () {
 185                 search_field.set_text ("");
 186                 search_bar_visible = false;
 187                 search_bar.hide ();
 188         }
 189
 190         private bool on_key_press_event (Widget widget, Gdk.EventKey event) {
 191                 if (event.str != "") {
 192                         if (!search_bar_visible) {
 193                                 search_bar_visible = true;
 194                                 search_bar.show ();
 195                         }
 196                         search_field.grab_focus ();
 197                 }
 198
 199                 return false;
 200         }
 201
 202         private void on_search_field_changed () {
 203                 // With every change we reset the timer to 500ms
 204                 if (source_id != 0) {
 205                         Source.remove (source_id);
 206                 }
 207                 source_id = Timeout.add (500, start_search);
 208         }
 209
 210         private bool start_search () {
 211                 filter.title = search_field.get_text ();
 212                 if (store.start_search (filter)) {
 213                         movie_list.show ();
 214                         no_movies.hide ();
 215                 }
 216
 217                 // One-shot only
 218                 return false;
 219         }
 220
 221         private void on_search_finished (int movies) {
 222                 if (movies > 6)
 223                         alignment.right_padding = MARGIN_DEFAULT;
 224                 else
 225                         alignment.right_padding = MARGIN_DOUBLE;
 226                 if (movies > 100) {
 227                         Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 228                 }
 229         }
 230
 231         private void on_movie_activated (Movie movie) {
 232                 if (movie_window != null)
 233                         return;
 234
 235                 movie_window = new MovieWindow.with_movie (movie, store);
 236                 movie_window.destroy.connect (() => { movie_window = null; });
 237                 movie_window.show ();
 238         }
 239
 240         private void on_update_running_changed (GLib.Object source, ParamSpec spec) {
 241                 TreeIter iter;
 242
 243                 Hildon.gtk_window_set_progress_indicator (this, (int) store.update_running);
 244                 // Update finished, but store still empty?
 245                 if (!store.update_running && !store.get_iter_first (out iter)) {
 246                         movie_list.hide ();
 247                         no_movies.show ();
 248                 }
 249         }
 250 }
 251