vcs.maemo.org Git - cinaest/blob - src/movie-list-window.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListWindow : StackableWindow {
  23         private Hildon.Entry search_field;
  24         private Toolbar search_bar;
  25         private uint source_id;
  26         private MovieListView movie_list;
  27         private MovieListStore store;
  28         private Label no_movies;
  29         private bool search_bar_visible;
  30
  31         construct {
  32                 // View menu
  33                 var menu = new MovieListMenu (this);
  34
  35                 set_main_menu (menu);
  36
  37                 // Search bar
  38                 search_field = new Hildon.Entry (SizeType.FINGER_HEIGHT);
  39
  40                 var search_field_item = new ToolItem ();
  41                 search_field_item.set_expand (true);
  42                 search_field_item.add (search_field);
  43
  44                 var close_image = new Image.from_file("/usr/share/icons/hicolor/48x48/hildon/general_close.png");
  45                 var close_button = new ToolButton (close_image, _("Close"));
  46
  47                 search_bar = new Toolbar ();
  48                 search_bar.insert (search_field_item, 0);
  49                 search_bar.insert (close_button, 1);
  50
  51                 add_toolbar (search_bar);
  52
  53                 // Movie list - connected to menu for sorting
  54                 movie_list = new MovieListView ();
  55                 menu.sortable = movie_list.sorted_store;
  56                 store = movie_list.store;
  57
  58                 no_movies = new Label (_("No movies"));
  59                 Hildon.helper_set_logical_font (no_movies, "LargeSystemFont");
  60                 Hildon.helper_set_logical_color (no_movies, RcFlags.FG, StateType.NORMAL, "SecondaryTextColor");
  61                 no_movies.set_size_request (-1, 6 * 70);
  62                 no_movies.set_alignment ((float) 0.5, (float) 0.42);
  63
  64                 var vbox = new VBox (false, 0);
  65                 vbox.pack_start (movie_list, true, true, 0);
  66                 vbox.pack_start (no_movies, false, false, 0);
  67
  68                 add (vbox);
  69
  70                 // Connect signals
  71                 search_field.changed.connect (on_search_field_changed);
  72                 close_button.clicked.connect (on_close_button_clicked);
  73                 key_press_event.connect (on_key_press_event);
  74
  75                 store.notify["update-running"].connect (on_update_running_changed);
  76
  77                 search_field.set_flags (WidgetFlags.CAN_DEFAULT);
  78                 search_field.grab_default ();
  79
  80                 show_all ();
  81                 search_bar_visible = false;
  82                 search_bar.hide ();
  83                 movie_list.hide ();
  84         }
  85
  86         public MovieSource source {
  87                 get { return store.source; }
  88                 set { store.source = value; set_title ("Cinæst: " + value.get_description ()); }
  89         }
  90
  91         private void on_close_button_clicked () {
  92                 search_field.set_text ("");
  93                 search_bar_visible = false;
  94                 search_bar.hide ();
  95         }
  96
  97         private bool on_key_press_event (Widget widget, Gdk.EventKey event) {
  98                 if (event.str != "") {
  99                         if (!search_bar_visible) {
 100                                 search_bar_visible = true;
 101                                 search_bar.show ();
 102                         }
 103                         search_field.grab_focus ();
 104                 }
 105
 106                 return false;
 107         }
 108
 109         private void on_search_field_changed () {
 110                 if (search_field.get_text () == "") {
 111                         store.clear ();
 112                         movie_list.hide ();
 113                         no_movies.show ();
 114                         return;
 115                 }
 116
 117                 // With every change we reset the timer to 500ms
 118                 if (source_id != 0) {
 119                         Source.remove (source_id);
 120                 }
 121                 source_id = Timeout.add (500, start_search);
 122         }
 123
 124         private bool start_search () {
 125                 if (store.start_search (search_field.get_text ())) {
 126                         movie_list.show ();
 127                         no_movies.hide ();
 128                 }
 129
 130                 // One-shot only
 131                 return false;
 132         }
 133
 134         private void on_update_running_changed (GLib.Object source, ParamSpec spec) {
 135                 Hildon.gtk_window_set_progress_indicator (this, (int) store.update_running);
 136         }
 137 }
 138