vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         construct {
  28                 store = new MovieListStore ();
  29
  30                 // Add filter wrapper
  31                 var filtered_store = new TreeModelFilter (store, null);
  32
  33                 // Add sort wrapper
  34                 sorted_store = new TreeModelSort.with_model (filtered_store);
  35
  36                 // Tree View
  37                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  38                 tree.set_headers_visible (false);
  39
  40                 add (tree);
  41
  42                 tree.set_rules_hint (true);
  43
  44                 // Tree selection object
  45                 var selection = tree.get_selection ();
  46                 selection.set_mode (SelectionMode.SINGLE);
  47
  48                 // Title column with poster
  49                 var title_column = new TreeViewColumn ();
  50                 title_column.set_title (_("Movie"));
  51                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  52                 title_column.set_reorderable (false);
  53                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  54                 title_column.set_expand (true);
  55
  56                 // Add poster icon to column
  57                 var pixbuf_renderer = new CellRendererPixbuf ();
  58                 pixbuf_renderer.width = 64;
  59                 title_column.pack_start (pixbuf_renderer, false);
  60                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  61
  62                 // Add text to column
  63                 var vbox_renderer = new CellRendererVBox ();
  64
  65                 var renderer = new CellRendererText ();
  66                 renderer.set ("ellipsize", Pango.EllipsizeMode.END);
  67                 title_column.add_attribute (renderer, "text", MovieListStore.Columns.TITLE);
  68
  69                 vbox_renderer.append (renderer, true);
  70                 vbox_renderer.set_data ("title", renderer);
  71
  72                 // Add secondary text to column (Genres, Director, etc.)
  73                 renderer = new CellRendererText ();
  74                 renderer.set ("ellipsize", Pango.EllipsizeMode.END);
  75
  76                 Pango.AttrList attr_list = new Pango.AttrList ();
  77                 var style = Gtk.rc_get_style_by_paths (this.get_settings (), "SmallSystemFont", null, typeof (void));
  78                 if (style != null) {
  79                         Pango.Attribute attr_font_desc = Pango.attr_font_desc_new (style.font_desc.copy ());
  80                         attr_list.insert ((owned) attr_font_desc);
  81                 } else {
  82                         Pango.Attribute attr_font_scale = Pango.attr_scale_new (Pango.Scale.SMALL);
  83                         attr_list.insert ((owned) attr_font_scale);
  84                 }
  85                 Gdk.Color color;
  86                 if (!style.lookup_color ("SecondaryTextColor", out color)) {
  87                         Gdk.Color.parse ("grey", out color);
  88                 }
  89                 Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
  90                 attr_list.insert ((owned) attr_color);
  91                 renderer.attributes = attr_list;
  92
  93                 vbox_renderer.append (renderer, true);
  94                 vbox_renderer.set_data ("secondary", renderer);
  95
  96                 title_column.pack_start (vbox_renderer, true);
  97                 title_column.set_cell_data_func (vbox_renderer, vbox_data_func);
  98
  99                 tree.append_column (title_column);
 100
 101                 // Sort by title
 102                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 103
 104                 // Year column
 105                 renderer = new CellRendererText ();
 106                 var year_column = new TreeViewColumn.with_attributes (_("Year"), renderer, "text", MovieListStore.Columns.YEAR);
 107                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 108                 year_column.set_reorderable (false);
 109                 year_column.set_sort_order (SortType.DESCENDING);
 110                 tree.append_column (year_column);
 111
 112                 // Rating column
 113                 renderer = new CellRendererText ();
 114                 var rating_column = new TreeViewColumn.with_attributes (_("Rating"), renderer, "text", MovieListStore.Columns.RATING);
 115                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 116                 rating_column.set_reorderable (false);
 117                 rating_column.set_sort_order (SortType.DESCENDING);
 118                 rating_column.set_cell_data_func (renderer, rating_data_func);
 119                 rating_column.xalign = (float) 1.0;
 120                 tree.append_column (rating_column);
 121         }
 122
 123         private void vbox_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 124                 Movie movie;
 125                 CellRendererText renderer;
 126
 127                 model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 128
 129                 renderer = (CellRendererText) cell.get_data ("title");
 130                 renderer.text = movie.title;
 131
 132                 renderer = (CellRendererText) cell.get_data ("secondary");
 133                 renderer.text = movie.secondary;
 134         }
 135
 136         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 137                 int rating;
 138
 139                 model.get (iter, MovieListStore.Columns.RATING, out rating);
 140                 ((CellRendererText) cell).text = "%d.%d".printf (rating / 10, rating % 10);
 141         }
 142 }