vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         public signal void movie_activated (Movie movie);
  28
  29         public MovieListView (Gtk.Window window) {
  30                 store = new MovieListStore ();
  31
  32                 // Add filter wrapper
  33                 var filtered_store = new TreeModelFilter (store, null);
  34
  35                 // Add sort wrapper
  36                 sorted_store = new TreeModelSort.with_model (filtered_store);
  37
  38                 // Tree View
  39                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  40                 tree.set_headers_visible (false);
  41
  42                 add (tree);
  43
  44                 tree.set_rules_hint (true);
  45
  46                 // Tree selection object
  47                 var selection = tree.get_selection ();
  48                 selection.set_mode (SelectionMode.SINGLE);
  49
  50                 // Title column with poster
  51                 var title_column = new TreeViewColumn ();
  52                 title_column.set_title (_("Movie"));
  53                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  54                 title_column.set_reorderable (false);
  55                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  56                 title_column.set_expand (true);
  57
  58                 // Add poster icon to column
  59                 var pixbuf_renderer = new CellRendererPixbuf ();
  60                 pixbuf_renderer.width = 64;
  61                 pixbuf_renderer.xalign = 0.0f;
  62                 title_column.pack_start (pixbuf_renderer, false);
  63                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  64
  65                 // Add text to column
  66                 var vbox_renderer = new CellRendererVBox ();
  67
  68                 var renderer = new CellRendererText ();
  69                 renderer.yalign = 1.0f;
  70                 renderer.ellipsize = Pango.EllipsizeMode.END;
  71
  72                 vbox_renderer.append (renderer, true);
  73                 vbox_renderer.set_data ("title", renderer);
  74
  75                 // Add secondary text to column (Genres, Director, etc.)
  76                 renderer = new CellRendererText ();
  77                 renderer.yalign = 0;
  78                 renderer.ellipsize = Pango.EllipsizeMode.END;
  79
  80                 Pango.AttrList attr_list = new Pango.AttrList ();
  81                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), "SmallSystemFont", null, typeof (void));
  82                 if (style != null) {
  83                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
  84                         attr_list.insert ((owned) attr_font_desc);
  85                 }
  86                 Gdk.Color color;
  87                 window.ensure_style ();
  88                 if (window.style.lookup_color ("SecondaryTextColor", out color)) {
  89                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
  90                         attr_list.insert ((owned) attr_color);
  91                 }
  92                 renderer.attributes = attr_list;
  93
  94                 vbox_renderer.append (renderer, true);
  95                 vbox_renderer.set_data ("secondary", renderer);
  96
  97                 title_column.pack_start (vbox_renderer, true);
  98                 title_column.set_cell_data_func (vbox_renderer, vbox_data_func);
  99
 100                 tree.append_column (title_column);
 101
 102                 // Sort by title
 103                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 104
 105                 // Year column
 106                 renderer = new CellRendererText ();
 107                 var year_column = new TreeViewColumn ();
 108                 year_column.set_title (_("Rating"));
 109                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 110                 year_column.set_reorderable (false);
 111                 year_column.set_sort_order (SortType.DESCENDING);
 112                 year_column.pack_start (renderer, true);
 113                 year_column.set_cell_data_func (renderer, year_data_func);
 114                 tree.append_column (year_column);
 115
 116                 // Rating column
 117                 renderer = new CellRendererText ();
 118                 var rating_column = new TreeViewColumn ();
 119                 rating_column.set_title (_("Rating"));
 120                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 121                 rating_column.set_reorderable (false);
 122                 rating_column.set_sort_order (SortType.DESCENDING);
 123                 rating_column.pack_start (renderer, true);
 124                 rating_column.set_cell_data_func (renderer, rating_data_func);
 125                 rating_column.xalign = (float) 1.0;
 126                 tree.append_column (rating_column);
 127
 128                 // Connect signals
 129                 tree.row_activated.connect (on_row_activated);
 130         }
 131
 132         public void set_hildon_ui_mode (UIMode mode) {
 133                 var selection = tree.get_selection ();
 134
 135                 if (mode == UIMode.NORMAL) {
 136                         selection.set_mode (SelectionMode.NONE);
 137                 }
 138                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 139                 if (mode == UIMode.EDIT) {
 140                         selection.set_mode (SelectionMode.MULTIPLE);
 141                 }
 142         }
 143
 144         public unowned TreeSelection get_selection () {
 145                 return tree.get_selection ();
 146         }
 147
 148         private void on_row_activated (TreeView tree, TreePath path_, TreeViewColumn column) {
 149                 TreePath path = path_.copy (); // FIXME - calling model.get_iter with path_ directly causes a C qualifier warning
 150                 TreeModel model = tree.model;
 151                 TreeIter iter;
 152
 153                 if (model.get_iter (out iter, path)) {
 154                         Movie movie;
 155                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 156                         movie_activated (movie);
 157                 }
 158         }
 159
 160         private void vbox_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 161                 Movie movie;
 162                 CellRendererText renderer;
 163
 164                 model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 165
 166                 renderer = cell.get_data ("title");
 167                 renderer.text = movie.title;
 168
 169                 renderer = cell.get_data ("secondary");
 170                 renderer.text = movie.secondary;
 171         }
 172
 173         private void year_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 174                 int year;
 175
 176                 model.get (iter, MovieListStore.Columns.YEAR, out year);
 177                 ((CellRendererText) cell).text = (year > 0) ? year.to_string () : "";
 178         }
 179
 180         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 181                 int rating;
 182
 183                 model.get (iter, MovieListStore.Columns.RATING, out rating);
 184                 ((CellRendererText) cell).text = (rating > 0) ? "%d.%d".printf (rating / 10, rating % 10) : "";
 185         }
 186 }