vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         public TreeSortable sorted_store;
  26
  27         public signal void movie_activated (Movie movie);
  28
  29         construct {
  30                 store = new MovieListStore ();
  31
  32                 // Add filter wrapper
  33                 var filtered_store = new TreeModelFilter (store, null);
  34
  35                 // Add sort wrapper
  36                 sorted_store = new TreeModelSort.with_model (filtered_store);
  37
  38                 // Tree View
  39                 tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, sorted_store);
  40                 tree.set_headers_visible (false);
  41
  42                 add (tree);
  43
  44                 tree.set_rules_hint (true);
  45
  46                 // Tree selection object
  47                 var selection = tree.get_selection ();
  48                 selection.set_mode (SelectionMode.SINGLE);
  49
  50                 // Title column with poster
  51                 var title_column = new TreeViewColumn ();
  52                 title_column.set_title (_("Movie"));
  53                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  54                 title_column.set_reorderable (false);
  55                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  56                 title_column.set_expand (true);
  57
  58                 // Add poster icon to column
  59                 var pixbuf_renderer = new CellRendererPixbuf ();
  60                 pixbuf_renderer.width = 64;
  61                 pixbuf_renderer.xalign = 0.0f;
  62                 title_column.pack_start (pixbuf_renderer, false);
  63                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.POSTER);
  64
  65                 // Add text to column
  66                 var vbox_renderer = new CellRendererVBox ();
  67
  68                 var renderer = new CellRendererText ();
  69                 renderer.set ("ellipsize", Pango.EllipsizeMode.END);
  70                 title_column.add_attribute (renderer, "text", MovieListStore.Columns.TITLE);
  71
  72                 vbox_renderer.append (renderer, true);
  73                 vbox_renderer.set_data ("title", renderer);
  74
  75                 // Add secondary text to column (Genres, Director, etc.)
  76                 renderer = new CellRendererText ();
  77                 renderer.set ("ellipsize", Pango.EllipsizeMode.END);
  78
  79                 Pango.AttrList attr_list = new Pango.AttrList ();
  80                 var style = Gtk.rc_get_style_by_paths (this.get_settings (), "SmallSystemFont", null, typeof (void));
  81                 if (style != null) {
  82                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
  83                         attr_list.insert ((owned) attr_font_desc);
  84                 } else {
  85                         Pango.Attribute attr_font_scale = Pango.attr_scale_new (Pango.Scale.SMALL);
  86                         attr_list.insert ((owned) attr_font_scale);
  87                 }
  88                 Gdk.Color color;
  89                 if (!style.lookup_color ("SecondaryTextColor", out color)) {
  90                         Gdk.Color.parse ("grey", out color);
  91                 }
  92                 Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
  93                 attr_list.insert ((owned) attr_color);
  94                 renderer.attributes = attr_list;
  95
  96                 vbox_renderer.append (renderer, true);
  97                 vbox_renderer.set_data ("secondary", renderer);
  98
  99                 title_column.pack_start (vbox_renderer, true);
 100                 title_column.set_cell_data_func (vbox_renderer, vbox_data_func);
 101
 102                 tree.append_column (title_column);
 103
 104                 // Sort by title
 105                 sorted_store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 106
 107                 // Year column
 108                 renderer = new CellRendererText ();
 109                 var year_column = new TreeViewColumn ();
 110                 year_column.set_title (_("Rating"));
 111                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 112                 year_column.set_reorderable (false);
 113                 year_column.set_sort_order (SortType.DESCENDING);
 114                 year_column.pack_start (renderer, true);
 115                 year_column.set_cell_data_func (renderer, year_data_func);
 116                 tree.append_column (year_column);
 117
 118                 // Rating column
 119                 renderer = new CellRendererText ();
 120                 var rating_column = new TreeViewColumn ();
 121                 rating_column.set_title (_("Rating"));
 122                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 123                 rating_column.set_reorderable (false);
 124                 rating_column.set_sort_order (SortType.DESCENDING);
 125                 rating_column.pack_start (renderer, true);
 126                 rating_column.set_cell_data_func (renderer, rating_data_func);
 127                 rating_column.xalign = (float) 1.0;
 128                 tree.append_column (rating_column);
 129
 130                 // Connect signals
 131                 tree.row_activated.connect (on_row_activated);
 132         }
 133
 134         public void set_hildon_ui_mode (UIMode mode) {
 135                 var selection = tree.get_selection ();
 136
 137                 if (mode == UIMode.NORMAL) {
 138                         selection.set_mode (SelectionMode.NONE);
 139                 }
 140                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 141                 if (mode == UIMode.EDIT) {
 142                         selection.set_mode (SelectionMode.MULTIPLE);
 143                 }
 144         }
 145
 146         public unowned TreeSelection get_selection () {
 147                 return tree.get_selection ();
 148         }
 149
 150         private void on_row_activated (TreeView tree, TreePath path_, TreeViewColumn column) {
 151                 TreePath path = path_.copy (); // FIXME - calling model.get_iter with path_ directly causes a C qualifier warning
 152                 TreeModel model = tree.model;
 153                 TreeIter iter;
 154
 155                 if (model.get_iter (out iter, path)) {
 156                         Movie movie;
 157                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 158                         movie_activated (movie);
 159                 }
 160         }
 161
 162         private void vbox_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 163                 Movie movie;
 164                 CellRendererText renderer;
 165
 166                 model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 167
 168                 renderer = cell.get_data ("title");
 169                 renderer.text = movie.title;
 170
 171                 renderer = cell.get_data ("secondary");
 172                 renderer.text = movie.secondary;
 173         }
 174
 175         private void year_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 176                 int year;
 177
 178                 model.get (iter, MovieListStore.Columns.YEAR, out year);
 179                 ((CellRendererText) cell).text = (year > 0) ? year.to_string () : "";
 180         }
 181
 182         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 183                 int rating;
 184
 185                 model.get (iter, MovieListStore.Columns.RATING, out rating);
 186                 ((CellRendererText) cell).text = (rating > 0) ? "%d.%d".printf (rating / 10, rating % 10) : "";
 187         }
 188 }