vcs.maemo.org Git - gnuplot/blob - demo/mousevariables.dem

   1 #
   2 # $Id: mousevariables.dem,v 1.8 2006/07/10 19:49:54 sfeam Exp $
   3 #
   4 # Demonstrate use of user variables
   5 # MOUSE_BUTTON MOUSE_X MOUSE_Y MOUSE_X2 MOUSE_Y2
   6 # and built-in function exists("<varname>")
   7 #
   8 reset
   9 set title "Scripted zoom using exported MOUSE variables"
  10 set samples 200
  11 set label 3 at graph 0.1, graph 0.9 tc lt 3
  12 set label 3 "Click on one corner of desired zoom region"
  13 plot sin(13*besj0(x))/x
  14 #
  15 pause mouse "Click on one corner of desired zoom region"
  16 #
  17 if (exists("MOUSE_BUTTON")) \
  18     print "Mouse button ", MOUSE_BUTTON, " at ", MOUSE_X, " ", MOUSE_Y ;\
  19     set label 1 sprintf("   Mouse button %d\n   clicked here!", MOUSE_BUTTON) ;\
  20     set label 1 at MOUSE_X, MOUSE_Y ;\
  21     set label 1 point pt 6 ps 6 ;\
  22     replot ;\
  23 else \
  24     print "No mouse click?" ;\
  25     exit ;
  26 #
  27 BOT_X = MOUSE_X
  28 BOT_Y = MOUSE_Y
  29 set label 3 "Click on diagonal corner of desired zoom region"
  30 replot
  31 #
  32 pause mouse "Click on diagonal corner of desired zoom region"
  33 #
  34 if (exists("MOUSE_BUTTON")) \
  35     print "Mouse button ", MOUSE_BUTTON, " at ", MOUSE_X, " ", MOUSE_Y ;\
  36     set label 2 sprintf("   Mouse button %d\n   clicked here!", MOUSE_BUTTON) ;\
  37     set label 2 at MOUSE_X, MOUSE_Y ;\
  38     set label 2 point pt 6 ps 6 ;\
  39     replot ;\
  40 else \
  41     print "No mouse click?" ;\
  42     exit ;
  43 #
  44 #
  45 TOP_X = MOUSE_X
  46 TOP_Y = MOUSE_Y
  47 #
  48 set label 3 "Plot will zoom in 3 seconds"
  49 replot
  50 pause 3
  51 #
  52 set xrange [ BOT_X : TOP_X ]
  53 set yrange [ BOT_Y : TOP_Y ]
  54 set grid
  55 #
  56 unset label 1
  57 unset label 2
  58 unset label 3
  59 set label 4 sprintf("zoom x range %.3f to %.3f",BOT_X,TOP_X)
  60 set label 5 sprintf("zoom y range %.3f to %.3f",TOP_X,TOP_Y)
  61 set label 4 at graph 0.1, graph 0.95 tc lt 3
  62 set label 5 at graph 0.1, graph 0.90 tc lt 3
  63 replot
  64 #
  65 print "Zoomed to xrange ",BOT_X," ",TOP_X
  66 print "Zoomed to yrange ",BOT_Y," ",TOP_Y
  67 #
  68 pause -1 "Type <cr> to continue"
  69
  70 reset