vcs.maemo.org Git - gnuplot/blob - demo/dashcolor.dem

   1 #
   2 # Demonstrate explicit choice of both dot/dash pattern (linetype) and color (linecolor).
   3 #
   4 reset
   5 set xrange [-0.5:3.5]
   6 set yrange [-1:1.4]
   7 set bmargin 7
   8 unset ytics
   9 unset xtics
  10 #
  11 set title "Independent colors and dot/dash styles"
  12 unset colorbox
  13 #
  14 # define line styles using explicit rgbcolor names
  15 #
  16 set style line 1 lt 2 lc rgb "red" lw 3
  17 set style line 2 lt 2 lc rgb "orange" lw 2
  18 set style line 3 lt 2 lc rgb "yellow" lw 3
  19 set style line 4 lt 2 lc rgb "green" lw 2
  20 #
  21 set label 1 'set style line 1 lt 2 lc rgb "red" lw 3'    at -0.4, -0.25 tc rgb "red"
  22 set label 2 'set style line 2 lt 2 lc rgb "orange" lw 2' at -0.4, -0.35 tc rgb "orange"
  23 set label 3 'set style line 3 lt 2 lc rgb "yellow" lw 3' at -0.4, -0.45 tc rgb "yellow"
  24 set label 4 'set style line 4 lt 2 lc rgb "green" lw 2'  at -0.4, -0.55 tc rgb "green"
  25 set label 5 'plot ... lt 1 lc 3 lw 3' at -0.4, -0.65 tc lt 3
  26 set label 6 'plot ... lt 3 lc 3 lw 2' at -0.4, -0.75 tc lt 3
  27 set label 7 'plot ... lt 5 lc 3 lw 3' at -0.4, -0.85 tc lt 3
  28 #
  29 set xlabel "You will only see dashed lines if your current terminal setting permits it"
  30 #
  31 show style line
  32 #
  33 # draw some plots
  34 #
  35 plot cos(x)     ls 1 title 'ls 1',   \
  36      cos(x-.2)  ls 2 title 'ls 2',\
  37      cos(x-.4)  ls 3 title 'ls 3',\
  38      cos(x-.6)  ls 4 title 'ls 4', \
  39      cos(x-.8)  lt 1 lc 3 title 'lt 1 lc 3',  \
  40      cos(x-1.)  lt 3 lc 3 title 'lt 3 lc 3',  \
  41      cos(x-1.2) lt 5 lc 3 title 'lt 5 lc 3'
  42
  43 #
  44 pause -1 "Hit return to continue"
  45 reset