vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [5])
   6 m4_define([conky_version_micro], [1])
   7 m4_define([conky_version_tag])dnl, [pre]) dnl [] for releases
   8 m4_define([conky_version_revision],[_pre@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [pre],
  12       [conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19
  20 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  21 dnl libtool must be deleted with make distclean to see this fix.
  22 if test x"$CFLAGS" = x""; then
  23   AC_SUBST(CFLAGS, [ ])
  24 fi
  25
  26 dnl
  27 dnl Tools
  28 dnl
  29 AC_PROG_CC
  30 AC_PROG_LD
  31 AC_PROG_INSTALL
  32 AC_PROG_LIBTOOL
  33
  34 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  35 if test x"$HAVE_PKGCONFIG" = x"no"; then
  36   AC_MSG_ERROR([pkg-config is required!])
  37 fi
  38 PKG_PROG_PKG_CONFIG([0.19])
  39
  40 AC_CONFIG_FILES(
  41   Makefile
  42   data/Makefile
  43   doc/Makefile
  44   src/Makefile
  45   src/build.h
  46   )
  47
  48 uname=`uname`
  49
  50 case $uname in
  51   Linux*)
  52     WANT_SYSINFO=yes
  53     ;;
  54   FreeBSD*|GNU/kFreeBSD*)
  55     WANT_KVM=yes
  56     WANT_DEVSTAT=yes
  57     ;;
  58 #  NetBSD*)
  59 #    WANT_KVM=yes
  60 #    WANT_OSSLIB=yes
  61 #    ;;
  62
  63   OpenBSD*)
  64     WANT_KVM=yes
  65     WANT_OSSLIB=yes
  66     ;;
  67
  68 # Solaris doesn't work at all right now
  69 #  SunOS*)
  70 #    WANT_KSTAT=yes
  71 #    ;;
  72
  73   *)
  74     echo "Your operating system $uname isn't supported"
  75     echo "Feel free to help. :P"
  76     exit 1
  77     ;;
  78 esac
  79
  80 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  81 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  82 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  83 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  84 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  85
  86 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  87 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  88 AC_SUBST(BUILD_DATE)
  89 AC_SUBST(BUILD_ARCH)
  90
  91
  92 dnl
  93 dnl OWN_WINDOW option
  94 dnl
  95
  96 AC_ARG_ENABLE([own_window],
  97               AC_HELP_STRING([--disable-own-window],
  98                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
  99               [dah="$enableval"], [dah=yes])
 100
 101 if test $dah != "no"; then
 102   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 103 fi
 104
 105
 106 dnl
 107 dnl Audacious Media Player
 108 dnl
 109
 110 AC_ARG_ENABLE([audacious],
 111               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 112                              [enable audacious player support @<:@default=no@:>@]),
 113               [want_audacious="$enableval"], [want_audacious=no])
 114
 115 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 116 if test x$want_audacious = xyes; then
 117       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 118       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 119       LIBS="$LIBS $Audacious_LIBS"
 120       save_CPPFLAGS="$CPPFLAGS"
 121       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 122       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 123                        [], AC_MSG_ERROR([required header(s) not found]))
 124       CPPFLAGS="$save_CPPFLAGS"
 125       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 126 else if test x$want_audacious = xlegacy; then
 127       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 128       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 129       LIBS="$LIBS $Audacious_LIBS"
 130       save_CPPFLAGS="$CPPFLAGS"
 131       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 132       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 133       CPPFLAGS="$save_CPPFLAGS"
 134       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 135       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 136       fi
 137 fi
 138
 139
 140 dnl
 141 dnl BMPx
 142 dnl
 143
 144 AC_ARG_ENABLE([bmpx],
 145               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 146               [want_bmpx="$enableval"], [want_bmpx=no])
 147
 148 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 149 if test x$want_bmpx = xyes; then
 150   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 151   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 152   LIBS="$LIBS $BMPx_LIBS"
 153   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 154 fi
 155
 156
 157 dnl
 158 dnl Hddtemp
 159 dnl
 160
 161 AC_ARG_ENABLE([hddtemp],
 162               AC_HELP_STRING([--disable-hddtemp],
 163                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 164               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 165
 166 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 167 if test x$want_hddtemp = xyes; then
 168   if test x"$uname" != xLinux; then
 169       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 170       want_hddtemp=no
 171   else
 172       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 173   fi
 174 fi
 175
 176 dnl
 177 dnl MPD
 178 dnl
 179
 180 AC_ARG_ENABLE([mpd],
 181               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 182               [want_mpd="$enableval"], [want_mpd=yes])
 183
 184 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 185 if test x$want_mpd = xyes; then
 186   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 187 fi
 188
 189 dnl
 190 dnl XMMS2
 191 dnl
 192
 193 AC_ARG_ENABLE([xmms2],
 194               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 195               [want_xmms2="$enableval"], [want_xmms2=no])
 196
 197 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 198 if test x$want_xmms2 = xyes; then
 199   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 200     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 201     LIBS="$LIBS $XMMS2_LIBS"
 202     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 203 fi
 204
 205 dnl
 206 dnl RSS
 207 dnl
 208
 209 AC_ARG_ENABLE([rss],
 210               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 211               [want_rss="$enableval"], [want_rss=no])
 212 #
 213 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 214 if test x$want_rss = xyes; then
 215         WANT_GLIB=yes
 216         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 217         PKG_CHECK_MODULES([libcurl], libcurl)
 218         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 219         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 220         AC_DEFINE(RSS, 1, [Define if you want rss support])
 221 fi
 222
 223 dnl
 224 dnl SMAPI
 225 dnl
 226
 227 AC_ARG_ENABLE([smapi],
 228               AC_HELP_STRING([--enable-smapi], [enable if you want smapi support @<:@default=no@:>@]),
 229               [want_smapi="$enableval"], [want_smapi=no])
 230
 231 AM_CONDITIONAL(BUILD_SMAPI, test x$want_smapi = xyes)
 232 if test x$want_smapi = xyes; then
 233         AC_DEFINE(SMAPI, 1, [Define if you want smapi support])
 234 fi
 235
 236 dnl
 237 dnl Wireless extensions
 238 dnl
 239
 240 AC_ARG_ENABLE([wlan],
 241               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 242               [want_wlan="$enableval"], [want_wlan=no])
 243 #
 244 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 245 if test x$want_wlan = xyes; then
 246   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 247   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 248         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 249 fi
 250
 251 dnl
 252 dnl IMLIB2
 253 dnl
 254
 255 dnl --commented out until brenden finishes it --
 256 dnl AC_ARG_ENABLE([imlib2],
 257 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 258 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 259 dnl
 260 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 261 dnl if test x$want_imlib2 = xyes; then
 262 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 263 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 264 dnl LIBS="$LIBS $Imlib2_LIBS"
 265 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 266 dnl fi
 267
 268
 269 dnl
 270 dnl PORT_MONITORS
 271 dnl
 272
 273 AC_ARG_ENABLE([portmon],
 274               AC_HELP_STRING([--disable-portmon],
 275                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 276               [want_portmon="$enableval"], [want_portmon=yes])
 277
 278 if test x"$want_portmon" = xyes; then
 279   if test x"$uname" != xLinux; then
 280       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 281       want_portmon=no
 282   else
 283         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 284            [PORT_MONITORS_MISSING=yes])
 285         if test x"$PORT_MONITORS_MISSING" = xyes; then
 286               AC_MSG_ERROR([missing a needed network header for port monitoring])
 287         fi
 288         WANT_GLIB=yes
 289         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 290   fi
 291 fi
 292 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 293
 294
 295 dnl
 296 dnl ICONV
 297 dnl
 298
 299 AM_ICONV
 300 if test "$am_cv_func_iconv" != yes; then
 301   AC_MSG_WARN([Could not find libiconv])
 302 else
 303   LIBS="$LIBS $LIBICONV"
 304 fi
 305
 306 dnl
 307 dnl X11
 308 dnl
 309
 310 AC_ARG_ENABLE([x11],
 311               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 312               [want_x11="$enableval"], [want_x11=yes])
 313
 314 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 315 if test "x$want_x11" = "xyes"; then
 316     if $PKG_CONFIG --exists x11; then
 317       PKG_CHECK_MODULES([X11], [x11])
 318       CFLAGS="$CFLAGS $X11_CFLAGS"
 319       LIBS="$LIBS $X11_LIBS"
 320     else
 321       dnl non-modular X11 installations
 322       AC_PATH_X
 323       AC_PATH_XTRA
 324       CFLAGS="$CFLAGS $X_CFLAGS"
 325       LIBS="$LIBS $X_LIBS"
 326       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 327       if test "x$no_x" = "xyes"; then
 328         AC_MSG_ERROR([Can't locate your X11 installation])
 329       fi
 330       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 331     fi
 332     AC_DEFINE(X11, 1, [Define if you want to use X11])
 333 fi
 334
 335
 336 dnl
 337 dnl Xext Double-buffering Extension
 338 dnl
 339
 340 AC_ARG_ENABLE([double_buffer],
 341               AC_HELP_STRING([--disable-double-buffer],
 342                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 343               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 344
 345 if test "x$want_double_buffer" = "xyes"; then
 346     if test "x$want_x11" != "xyes"; then
 347       dnl silently disable if no x11
 348       want_double_buffer=no
 349     else
 350       if $PKG_CONFIG --exists xext; then
 351         PKG_CHECK_MODULES([Xext],[xext])
 352         CFLAGS="$CFLAGS $Xext_CFLAGS"
 353         LIBS="$LIBS $Xext_LIBS"
 354       else
 355         dnl non-modular X11 installation
 356         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 357                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 358       fi
 359       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 360     fi
 361 fi
 362
 363
 364 dnl
 365 dnl Xdamage Extension
 366 dnl
 367
 368 AC_ARG_ENABLE([xdamage],
 369               AC_HELP_STRING([--disable-xdamage],
 370                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 371               [want_xdamage="$enableval"], [want_xdamage=yes])
 372
 373 if test "x$want_xdamage" = "xyes"; then
 374     if test "x$want_x11" != "xyes"; then
 375       dnl silently disable if no x11
 376       want_xdamage=no
 377     else
 378       if $PKG_CONFIG --exists xdamage; then
 379         PKG_CHECK_MODULES([XDamage],[xdamage])
 380         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 381         LIBS="$LIBS $XDamage_LIBS"
 382       else
 383         dnl non-modular X11 installation
 384         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 385                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 386       fi
 387       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 388     fi
 389 fi
 390
 391
 392 dnl
 393 dnl Xft
 394 dnl
 395
 396 AC_ARG_ENABLE([xft],
 397               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 398               [want_xft="$enableval"], [want_xft=yes])
 399
 400 if test x$want_xft = "xyes"; then
 401     if test "x$want_x11" != "xyes"; then
 402       dnl silently disable if no x11
 403       want_xft=no
 404     else
 405       PKG_CHECK_MODULES([Xft], [xft])
 406       CFLAGS="$CFLAGS $Xft_CFLAGS"
 407       LIBS="$LIBS $Xft_LIBS"
 408       AC_DEFINE(XFT, 1, [Define for Xft support])
 409     fi
 410 fi
 411
 412 dnl
 413 dnl GLIB
 414 dnl
 415
 416 if test x$WANT_GLIB = xyes; then
 417         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 418         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 419         LIBS="$LIBS $GLib2_LIBS"
 420 fi
 421
 422 dnl
 423 dnl KVM
 424 dnl
 425
 426 if test x$WANT_KVM = xyes; then
 427   AC_CHECK_LIB(kvm, kvm_open,
 428     LIBS="$LIBS -lkvm",
 429   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 430   )
 431 fi
 432
 433 dnl
 434 dnl devstat
 435 dnl
 436
 437 if test x$WANT_DEVSTAT = xyes; then
 438   AC_CHECK_LIB(devstat, devstat_getversion,
 439          LIBS="$LIBS -ldevstat",
 440          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 441   )
 442 fi
 443
 444 dnl
 445 dnl OSSLIB for NetBSD/OpenBSD
 446 dnl
 447
 448 if test x$WANT_OSSLIB = xyes; then
 449     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 450   LIBS="$LIBS -lossaudio",
 451   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 452     )
 453 fi
 454
 455 dnl
 456 dnl Some headers
 457 dnl
 458
 459 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 460       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 461 AC_CHECK_HEADERS([sys/mount.h], [], [],
 462      [#ifdef HAVE_SYS_PARAM_H
 463       #include <sys/param.h>
 464       #endif
 465       ])
 466
 467 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
 468
 469 dnl
 470 dnl Some functions
 471 dnl
 472
 473 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr])
 474 AC_SEARCH_LIBS(clock_gettime, [rt],
 475                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 476                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 477
 478 dnl
 479 dnl Structure checks
 480 dnl
 481
 482 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 483                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 484                  [],
 485                  [#include <sys/statfs.h>])
 486
 487 dnl
 488 dnl Check for zlib
 489 dnl
 490
 491 AC_CHECK_HEADER(zlib.h,
 492                 [],
 493                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 494
 495
 496 dnl
 497 dnl Check doc stuff
 498 dnl
 499
 500 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 501 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 502 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 503 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 504   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 505 else
 506   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 507 fi
 508
 509
 510 dnl
 511 dnl kstat in Solaris
 512 dnl
 513
 514 if test x$WANT_KSTAT = xyes; then
 515   dah=no
 516   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 517
 518   if test x$dah = xyes; then
 519     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 520     LDFLAGS="$LDFLAGS -lkstat"
 521   fi
 522 fi
 523
 524 AC_DEFUN([AM_LANGINFO_CODESET],
 525 [
 526   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 527     [AC_TRY_LINK([#include <langinfo.h>],
 528       [char* cs = nl_langinfo(CODESET);],
 529       am_cv_langinfo_codeset=yes,
 530       am_cv_langinfo_codeset=no)
 531     ])
 532   if test $am_cv_langinfo_codeset = yes; then
 533     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 534       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 535   fi
 536 ])
 537
 538
 539 dnl ************************
 540 dnl * Linker optimizations *
 541 dnl ************************
 542 AC_MSG_CHECKING([if $LD accepts -O1])
 543 case `$LD -O1 -v 2>&1 </dev/null` in
 544 *GNU* | *BSD*)
 545   LDFLAGS="$LDFLAGS -Wl,-O1"
 546   AC_MSG_RESULT([yes])
 547   ;;
 548 *)
 549   AC_MSG_RESULT([no])
 550   ;;
 551 esac
 552
 553
 554 dnl
 555 dnl Da.
 556 dnl
 557
 558 CFLAGS="$CFLAGS -Wall -W"
 559
 560 dnl
 561 dnl debug
 562 dnl
 563
 564 AC_ARG_ENABLE([debug],
 565               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 566               [want_debug="$enableval"], [want_debug=no])
 567
 568 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 569   CFLAGS="$CFLAGS -g3 -Werror"
 570   AC_DEFINE([DEBUG], [], [Define for debugging])
 571 fi
 572
 573 dnl
 574 dnl testing
 575 dnl
 576
 577 AC_ARG_ENABLE([testing],
 578               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 579               [want_testing="$enableval"], [want_testing=no])
 580
 581 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 582   if test "x$want_debug" = "xyes"; then
 583     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 584     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 585   else
 586     CFLAGS="$CFLAGS -g3 -Werror -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 587     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 588   fi
 589 fi
 590
 591 AC_SUBST(CFLAGS)
 592 AC_SUBST(X11_LIBS)
 593
 594 AC_OUTPUT
 595
 596 dnl
 597 dnl Print summary
 598 dnl
 599 cat << EOF
 600
 601 $PACKAGE $VERSION configured successfully:
 602
 603  Installing into:   $prefix
 604  System config dir: $sysconfdir
 605  C compiler flags:  $CFLAGS
 606  Linker flags:      $LDFLAGS
 607  Libraries:         $LIBS
 608
 609  * x11:
 610   x11 support:      $want_x11
 611   xdamage support:  $want_xdamage
 612   xdbe support:     $want_double_buffer
 613   xft support:      $want_xft
 614
 615  * music detection:
 616   audacious:        $want_audacious
 617   bmpx:             $want_bmpx
 618   mpd:              $want_mpd
 619   xmms2:            $want_xmms2
 620
 621  * general:
 622   hddtemp:          $want_hddtemp
 623   portmon:          $want_portmon
 624   rss:              $want_rss
 625   wireless:         $want_wlan
 626   smapi:            $want_smapi
 627 EOF