vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [4])
   6 m4_define([conky_version_micro], [7])
   7 m4_define([conky_version_tag], [svn]) dnl [] for releases
   8 m4_define([conky_version_revision],[r@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [svn],
  12       [-conky_version_tag()-conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [-conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19
  20 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  21 dnl libtool must be deleted with make distclean to see this fix.
  22 if test x"$CFLAGS" = x""; then
  23   AC_SUBST(CFLAGS, [ ])
  24 fi
  25
  26 dnl
  27 dnl Tools
  28 dnl
  29 AC_PROG_CC
  30 AC_PROG_LD
  31 AC_PROG_INSTALL
  32 AC_PROG_LIBTOOL
  33
  34 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  35 if test x"$HAVE_PKGCONFIG" = x"no"; then
  36   AC_MSG_ERROR([pkg-config is required!])
  37 fi
  38 PKG_PROG_PKG_CONFIG([0.17.2])
  39
  40 AC_CONFIG_FILES(
  41   Makefile
  42   doc/Makefile
  43   src/Makefile
  44   src/build.h
  45   )
  46
  47 uname=`uname`
  48
  49 case $uname in
  50   Linux*)
  51     WANT_SYSINFO=yes
  52     ;;
  53   FreeBSD*)
  54     WANT_KVM=yes
  55     WANT_DEVSTAT=yes
  56     ;;
  57 #  NetBSD*)
  58 #    WANT_KVM=yes
  59 #    WANT_OSSLIB=yes
  60 #    ;;
  61
  62   OpenBSD*)
  63     WANT_KVM=yes
  64     WANT_OSSLIB=yes
  65     ;;
  66
  67 # Solaris doesn't work at all right now
  68 #  SunOS*)
  69 #    WANT_KSTAT=yes
  70 #    ;;
  71
  72   *)
  73     echo "Your operating system $uname isn't supported"
  74     echo "Feel free to help. :P"
  75     exit 1
  76     ;;
  77 esac
  78
  79 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  80 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  81 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD)
  82 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  83 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  84
  85 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  86 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  87 AC_SUBST(BUILD_DATE)
  88 AC_SUBST(BUILD_ARCH)
  89
  90
  91 dnl
  92 dnl OWN_WINDOW option
  93 dnl
  94
  95 AC_ARG_ENABLE([own_window],
  96               AC_HELP_STRING([--disable-own-window],
  97                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
  98               [dah="$enableval"], [dah=yes])
  99
 100 if test $dah != "no"; then
 101   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 102 fi
 103
 104
 105 dnl
 106 dnl Audacious Media Player
 107 dnl
 108
 109 AC_ARG_ENABLE([audacious],
 110               AC_HELP_STRING([--enable-audacious], [enable audacious player support @<:@default=no@:>@]),
 111               [want_audacious="$enableval"], [want_audacious=no])
 112
 113 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes)
 114 if test x$want_audacious = xyes; then
 115   PKG_CHECK_MODULES([AUDACIOUS], [audacious >= 0.1])
 116       CFLAGS="$CFLAGS $AUDACIOUS_CFLAGS"
 117       LIBS="$LIBS $AUDACIOUS_LIBS"
 118       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 119 fi
 120
 121
 122 dnl
 123 dnl BMPx
 124 dnl
 125
 126 AC_ARG_ENABLE([bmpx],
 127               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 128               [want_bmpx="$enableval"], [want_bmpx=no])
 129
 130 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 131 if test x$want_bmpx = xyes; then
 132   PKG_CHECK_MODULES([BMPX], [bmp-2.0 >= 0.14.0])
 133   CFLAGS="$CFLAGS $BMPX_CFLAGS"
 134   LIBS="$LIBS $BMPX_LIBS"
 135   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 136 fi
 137
 138
 139 dnl
 140 dnl Hddtemp
 141 dnl
 142
 143 AC_ARG_ENABLE([hddtemp],
 144               AC_HELP_STRING([--disable-hddtemp],
 145                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 146               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 147
 148 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 149 if test x$want_hddtemp = xyes; then
 150   AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 151 fi
 152
 153 dnl
 154 dnl MPD
 155 dnl
 156
 157 AC_ARG_ENABLE([mpd],
 158               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 159               [want_mpd="$enableval"], [want_mpd=yes])
 160
 161 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 162 if test x$want_mpd = xyes; then
 163   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 164 fi
 165
 166 dnl
 167 dnl XMMS2
 168 dnl
 169
 170 AC_ARG_ENABLE([xmms2],
 171               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 172               [want_xmms2="$enableval"], [want_xmms2=no])
 173
 174 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 175 if test x$want_xmms2 = xyes; then
 176   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 177     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 178     LIBS="$LIBS $XMMS2_LIBS"
 179     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 180 fi
 181
 182 dnl
 183 dnl RSS
 184 dnl
 185
 186 AC_ARG_ENABLE([rss],
 187               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 188               [want_rss="$enableval"], [want_rss=no])
 189 #
 190 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 191 if test x$want_rss = xyes; then
 192         WANT_GLIB=yes
 193         PKG_CHECK_MODULES(RSS, libxml-2.0 libcurl,,exit)
 194         CFLAGS="$CFLAGS $RSS_CFLAGS"
 195         LIBS="$LIBS $RSS_LIBS"
 196         AC_DEFINE(RSS, 1, [Define if you want rss support])
 197 fi
 198
 199 dnl
 200 dnl Wireless extensions
 201 dnl
 202
 203 AC_ARG_ENABLE([wlan],
 204               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 205               [want_wlan="$enableval"], [want_wlan=no])
 206 #
 207 AM_CONDITIONAL(BUILD_RSS, test x$want_wlan = xyes)
 208 if test x$want_wlan = xyes; then
 209         LIBS="$LIBS -liw"
 210         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 211 fi
 212
 213 dnl
 214 dnl IMLIB2
 215 dnl
 216
 217 dnl --commented out until brenden finishes it --
 218 dnl AC_ARG_ENABLE([imlib2],
 219 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 220 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 221 dnl
 222 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 223 dnl if test x$want_imlib2 = xyes; then
 224 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 225 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 226 dnl LIBS="$LIBS $Imlib2_LIBS"
 227 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 228 dnl fi
 229
 230
 231 dnl
 232 dnl PORT_MONITORS
 233 dnl
 234
 235 AC_ARG_ENABLE([portmon],
 236               AC_HELP_STRING([--disable-portmon],
 237                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 238               [want_portmon="$enableval"], [want_portmon=yes])
 239
 240 if test x"$want_portmon" = xyes; then
 241   if test x"$uname" != xLinux; then
 242       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 243       want_portmon=no
 244   else
 245         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 246            [PORT_MONITORS_MISSING=yes])
 247         if test x"$PORT_MONITORS_MISSING" = xyes; then
 248               AC_MSG_ERROR([missing a needed network header for port monitoring])
 249         fi
 250         WANT_GLIB=yes
 251         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 252   fi
 253 fi
 254 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 255
 256
 257 dnl
 258 dnl ICONV
 259 dnl
 260
 261 AM_ICONV
 262 if test "$am_cv_func_iconv" != yes; then
 263   AC_MSG_WARN([Could not find libiconv])
 264 else
 265   LIBS="$LIBS $LIBICONV"
 266 fi
 267
 268 dnl
 269 dnl debug
 270 dnl
 271
 272 AC_ARG_ENABLE([debug],
 273               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 274               [want_debug="$enableval"], [want_debug=no])
 275
 276 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 277   CFLAGS="$CFLAGS -g3"
 278   AC_DEFINE([DEBUG], [], [Define for debugging])
 279 fi
 280
 281 dnl
 282 dnl X11
 283 dnl
 284
 285 AC_ARG_ENABLE([x11],
 286               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 287               [want_x11="$enableval"], [want_x11=yes])
 288
 289 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 290 if test "x$want_x11" = "xyes"; then
 291     if $PKG_CONFIG --exists x11; then
 292       PKG_CHECK_MODULES([X11], [x11])
 293       CFLAGS="$CFLAGS $X11_CFLAGS"
 294       LIBS="$LIBS $X11_LIBS"
 295     else
 296       dnl non-modular X11 installations
 297       AC_PATH_X
 298       AC_PATH_XTRA
 299       CFLAGS="$CFLAGS $X_CFLAGS"
 300       LIBS="$LIBS $X_LIBS"
 301       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 302       if test "x$no_x" = "xyes"; then
 303         AC_MSG_ERROR([Can't locate your X11 installation])
 304       fi
 305       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 306     fi
 307     AC_DEFINE(X11, 1, [Define if you want to use X11])
 308 fi
 309
 310
 311 dnl
 312 dnl Xext Double-buffering Extension
 313 dnl
 314
 315 AC_ARG_ENABLE([double_buffer],
 316               AC_HELP_STRING([--disable-double-buffer],
 317                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 318               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 319
 320 if test "x$want_double_buffer" = "xyes"; then
 321     if test "x$want_x11" != "xyes"; then
 322       dnl silently disable if no x11
 323       want_double_buffer=no
 324     else
 325       if $PKG_CONFIG --exists xext; then
 326         PKG_CHECK_MODULES([XEXT],[xext])
 327         CFLAGS="$CFLAGS $XEXT_CFLAGS"
 328         LIBS="$LIBS $XEXT_LIBS"
 329       else
 330         dnl non-modular X11 installation
 331         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 332                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 333       fi
 334       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 335     fi
 336 fi
 337
 338
 339 dnl
 340 dnl Xdamage Extension
 341 dnl
 342
 343 AC_ARG_ENABLE([xdamage],
 344               AC_HELP_STRING([--disable-xdamage],
 345                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 346               [want_xdamage="$enableval"], [want_xdamage=yes])
 347
 348 if test "x$want_xdamage" = "xyes"; then
 349     if test "x$want_x11" != "xyes"; then
 350       dnl silently disable if no x11
 351       want_xdamage=no
 352     else
 353       if $PKG_CONFIG --exists xdamage; then
 354         PKG_CHECK_MODULES([XDAMAGE],[xdamage])
 355         CFLAGS="$CFLAGS $XDAMAGE_CFLAGS"
 356         LIBS="$LIBS $XDAMAGE_LIBS"
 357       else
 358         dnl non-modular X11 installation
 359         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 360                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 361       fi
 362       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 363     fi
 364 fi
 365
 366
 367 dnl
 368 dnl Xft
 369 dnl
 370
 371 AC_ARG_ENABLE([xft],
 372               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 373               [want_xft="$enableval"], [want_xft=yes])
 374
 375 if test x$want_xft = "xyes"; then
 376     if test "x$want_x11" != "xyes"; then
 377       dnl silently disable if no x11
 378       want_xft=no
 379     else
 380       PKG_CHECK_MODULES(XFT, [xft])
 381       CFLAGS="$CFLAGS $XFT_CFLAGS"
 382       LIBS="$LIBS $XFT_LIBS"
 383       AC_DEFINE(XFT, 1, [Define for Xft support])
 384     fi
 385 fi
 386
 387 dnl
 388 dnl GLIB
 389 dnl
 390
 391 if test x$WANT_GLIB = xyes; then
 392         PKG_CHECK_MODULES([GLIB], [glib-2.0])
 393         CFLAGS="$CFLAGS $GLIB_CFLAGS"
 394         LIBS="$LIBS $GLIB_LIBS"
 395 fi
 396
 397 dnl
 398 dnl KVM
 399 dnl
 400
 401 if test x$WANT_KVM = xyes; then
 402   AC_CHECK_LIB(kvm, kvm_open,
 403     LIBS="$LIBS -lkvm",
 404   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 405   )
 406 fi
 407
 408 dnl
 409 dnl devstat
 410 dnl
 411
 412 if test x$WANT_DEVSTAT = xyes; then
 413   AC_CHECK_LIB(devstat, devstat_getversion,
 414          LIBS="$LIBS -ldevstat",
 415          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 416   )
 417 fi
 418
 419 dnl
 420 dnl OSSLIB for NetBSD/OpenBSD
 421 dnl
 422
 423 if test x$WANT_OSSLIB = xyes; then
 424     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 425   LIBS="$LIBS -lossaudio",
 426   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 427     )
 428 fi
 429
 430 dnl
 431 dnl Some headers
 432 dnl
 433
 434 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 435       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 436 AC_CHECK_HEADERS([sys/mount.h], [], [],
 437      [#ifdef HAVE_SYS_PARAM_H
 438       #include <sys/param.h>
 439       #endif
 440       ])
 441
 442 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
 443
 444 dnl
 445 dnl Some functions
 446 dnl
 447
 448 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr])
 449 AC_SEARCH_LIBS(clock_gettime, [rt],
 450                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 451                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 452
 453
 454 dnl
 455 dnl Check for zlib
 456 dnl
 457
 458 AC_CHECK_HEADER(zlib.h,
 459                 [],
 460                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 461
 462
 463 dnl
 464 dnl Check doc stuff
 465 dnl
 466
 467 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 468 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 469 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 470 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 471   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 472 else
 473   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 474 fi
 475
 476
 477 dnl
 478 dnl kstat in Solaris
 479 dnl
 480
 481 if test x$WANT_KSTAT = xyes; then
 482   dah=no
 483   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 484
 485   if test x$dah = xyes; then
 486     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 487     LDFLAGS="$LDFLAGS -lkstat"
 488   fi
 489 fi
 490
 491 AC_DEFUN([AM_LANGINFO_CODESET],
 492 [
 493   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 494     [AC_TRY_LINK([#include <langinfo.h>],
 495       [char* cs = nl_langinfo(CODESET);],
 496       am_cv_langinfo_codeset=yes,
 497       am_cv_langinfo_codeset=no)
 498     ])
 499   if test $am_cv_langinfo_codeset = yes; then
 500     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 501       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 502   fi
 503 ])
 504
 505
 506 dnl ************************
 507 dnl * Linker optimizations *
 508 dnl ************************
 509 AC_MSG_CHECKING([if $LD accepts -O1])
 510 case `$LD -O1 -v 2>&1 </dev/null` in
 511 *GNU* | *BSD*)
 512   LDFLAGS="$LDFLAGS -Wl,-O1"
 513   AC_MSG_RESULT([yes])
 514   ;;
 515 *)
 516   AC_MSG_RESULT([no])
 517   ;;
 518 esac
 519
 520
 521 dnl
 522 dnl Da.
 523 dnl
 524
 525 CFLAGS="$CFLAGS -Wall -W"
 526
 527 AC_SUBST(CFLAGS)
 528 AC_SUBST(X11_LIBS)
 529
 530 AC_OUTPUT
 531
 532 dnl
 533 dnl Print summary
 534 dnl
 535 cat << EOF
 536
 537 $PACKAGE $VERSION configured successfully:
 538
 539  Installing into:   $prefix
 540  C compiler flags:  $CFLAGS
 541  Linker flags:      $LDFLAGS
 542  Libraries:         $LIBS
 543
 544  * x11:
 545   x11 support:      $want_x11
 546   xdamage support:  $want_xdamage
 547   xdbe support:     $want_double_buffer
 548   xft support:      $want_xft
 549
 550  * music detection:
 551   audacious:        $want_audacious
 552   bmpx:             $want_bmpx
 553   mpd:              $want_mpd
 554   xmms2:            $want_xmms2
 555
 556  * general:
 557   hddtemp:          $want_hddtemp
 558   portmon:          $want_portmon
 559   RSS:              $want_rss
 560   wireless:         $want_wlan
 561 EOF