# -------------------------------------------------
# Project created by QtCreator 2010-02-17T11:50:47
# -------------------------------------------------
# Obsahuje Qt >= 4.6.* ?
contains(QT_VERSION, ^4\.[0-6]\.*) { 
    message("Use new version of QT, you are using: $$QT_VERSION .")
    error("Use Qt 4.6.*")
}

  unix {
    #VARIABLES
    isEmpty(PREFIX) {
        PREFIX = /usr
  }


# potřebuji přidat maemo5
QT += xml xmlpatterns dbus maemo5 network

# ted bude debug a potřebuji ještě pkgconfig
# http://doc.trolltech.com/4.6/qmake-project-files.html#configuration-features
CONFIG += debug link_pkgconfig qt mobility

MOBILITY += systeminfo
# pro d-bus v libprofile
PKGCONFIG += dbus-1

# include pro libprofile.h and cal backend
INCLUDEPATH += /usr/include/profiled \
    /usr/include/calendar-backend

# lib libprofile
LIBS += /usr/lib/libprofile.so \
    -lcalendar_backend

TARGET = N9Profil
TEMPLATE = app
SOURCES += main.cpp \
    mainwindow.cpp \
    controlclass.cpp \
    profil.cpp \
    profiledb.cpp \
    profiledeamon.cpp \
    profildialog.cpp \
    timeprofile.cpp \
    timedprofildialog.cpp \
    calendatprofile.cpp \
    calendar.cpp \
    event.cpp \
    calendarprofilesdialog.cpp \
    calendarsetprofiledialog.cpp \
    networkdialogdialog.cpp \
    networkprofile.cpp \
    networkdialogedit.cpp \
    telephonenumprofile.cpp \
    telenumdialog.cpp \
    telephonenumnewruledialog.cpp \
    profilesmanager.cpp \
    soundfilesmanager.cpp \
    rulesmanager.cpp
HEADERS += mainwindow.h \
    controlclass.h \
    profil.h \
    profiledb.h \
    profiledeamon.h \
    profildialog.h \
    timeprofile.h \
    timedprofildialog.h \
    calendatprofile.h \
    calendar.h \
    event.h \
    calendarprofilesdialog.h \
    calendarsetprofiledialog.h \
    networkdialogdialog.h \
    networkprofile.h \
    networkdialogedit.h \
    telephonenumprofile.h \
    telenumdialog.h \
    telephonenumnewruledialog.h \
    profilesmanager.h \
    soundfilesmanager.h \
    rulesmanager.h
FORMS += mainwindow.ui \
    profildialog.ui \
    timedprofildialog.ui \
    calendarprofilesdialog.ui \
    calendarsetprofiledialog.ui \
    networkdialogdialog.ui \
    networkdialogedit.ui \
    telenumdialog.ui \
    telephonenumnewruledialog.ui


# čeština a nastavení na UTF-8
TRANSLATIONS = N9Profil_cs_CZ.ts
CODECFORTR = UTF-8
RESOURCES += rcc.qrc

BINDIR = $$PREFIX/bin
DATADIR =$$PREFIX/share

DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"

#MAKE INSTALL

INSTALLS += target desktop iconxpm icon26 icon40 icon64 service

    target.path =$$BINDIR

    desktop.path = $$DATADIR/applications/hildon
    desktop.files += data/$${TARGET}.desktop

    iconxpm.path = $$DATADIR/pixmap
    iconxpm.files += data/maemo/$${TARGET}.xpm

    icon26.path = $$DATADIR/icons/hicolor/26x26/apps
    icon26.files += data/26x26/$${TARGET}.png

    icon40.path = $$DATADIR/icons/hicolor/40x40/apps
    icon40.files += data/40x40/$${TARGET}.png

    icon64.path = $$DATADIR/icons/hicolor/64x64/apps
    icon64.files += data/64x64/$${TARGET}.png

    service.path = $$DATADIR/dbus-1/services
    service.files += data/org.indt.N9Profil.service
}