TARGET = mdictionary
TEMPLATE = app

include(../../mdictionary.pri)


SOURCES += gui/main.cpp \
    backbone/ConfigGenerator.cpp \
    gui/MainWindow.cpp \
    gui/SearchBarWidget.cpp \
    gui/WordListWidget.cpp \
    gui/TranslationWidget.cpp \
    backbone/backbone.cpp \
    gui/MenuWidget.cpp \
    gui/MenuTabWidget.cpp \
    gui/DictManagerWidget.cpp \
    gui/DictTypeSelectDialog.cpp \
    backbone/History.cpp \
    gui/HistoryListDialog.cpp \
    gui/WordListProxyStyle.cpp \
    backbone/Bookmarks.cpp \
    gui/SettingsWidget.cpp \
    gui/BookmarksWidget.cpp \
    gui/WelcomeScreenWidget.cpp \
    gui/AboutWidget.cpp \
    gui/TranslationTextEdit.cpp \
    gui/DBusAdapter.cpp \
    gui/NotifyManager.cpp

HEADERS += gui/MainWindow.h \
    backbone/ConfigGenerator.h \
    gui/AboutWidget.h \
    gui/SearchBarWidget.h \
    gui/WordListWidget.h \
    gui/TranslationWidget.h \
    backbone/backbone.h \
    ../include/translation.h \
    ../include/settings.h \
    ../include/CommonDictInterface.h \
    gui/MenuWidget.h \
    gui/MenuTabWidget.h \
    gui/DictManagerWidget.h \
    gui/DictTypeSelectDialog.h \
    ../include/History.h \
    gui/HistoryListDialog.h \
    ../include/GUIInterface.h \
    gui/WordListProxyStyle.h \
    backbone/Bookmarks.h \
    backbone/BookmarkTranslations.h \
    gui/SettingsWidget.h \
    gui/BookmarksWidget.h \
    gui/WelcomeScreenWidget.h \
    ../include/Notify.h \
    gui/TranslationTextEdit.h \
    ../include/AccentsNormalizer.h \
    ../include/DictDialog.h \
    gui/DBusAdapter.h \
    gui/NotifyManager.h

RESOURCES += ../../data/gui.qrc

TRANSLATIONS += dict_pl.ts \
                dict_en.ts

target.path = $$BIN_DIR
INSTALLS += target

unix { 
	maemo5 {
		desktop.path = $$SHARE_DIR/applications/hildon
		icon64.path = $$SHARE_DIR/icons/hicolor/64x64/hildon
	}    
	!maemo5 {
		desktop.path = $$SHARE_DIR/applications
		icon64.path = $$SHARE_DIR/icons
	}

	desktop.files += ../../data/other/$${TARGET}.desktop
	icon64.files += ../../data/icons/64x64/$${TARGET}.png

	bookmarks.path = $$DATA_DIR
	bookmarks.files += ../../data/icons/16x16/staron.png

	service.path = $$SHARE_DIR/dbus-1/services
	service.files += ../../data/other/com.comarch.mdictionary.service
	
	INSTALLS += desktop icon64 bookmarks service
}


check.commands = echo 'No check here'
QMAKE_EXTRA_TARGETS += check