vcs.maemo.org Git - mdictionary/blob - trunk/src/base/base.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-08-03T08:54:27
   3 # -------------------------------------------------
   4 QT += core \
   5     gui \
   6     sql \
   7     xml \
   8     xmlpatterns
   9
  10 maemo5:QT += maemo5
  11 TARGET = mdictionary
  12 TEMPLATE = app
  13 MDICT_BINDIR = $$[MDICT_BINDIR]
  14 isEmpty(MDICT_BINDIR):MDICT_BINDIR = .
  15 DESTDIR = $${MDICT_BINDIR}
  16 SOURCES += gui/main.cpp \
  17     backbone/ConfigGenerator.cpp \
  18     gui/MainWindow.cpp \
  19     gui/SearchBarWidget.cpp \
  20     gui/WordListWidget.cpp \
  21     gui/TranslationWidget.cpp \
  22     backbone/backbone.cpp \
  23     gui/MenuWidget.cpp \
  24     gui/MenuTabWidget.cpp \
  25     gui/DictManagerWidget.cpp \
  26     gui/DictTypeSelectDialog.cpp \
  27     backbone/History.cpp \
  28     gui/HistoryListDialog.cpp \
  29     gui/WordListProxyStyle.cpp \
  30     backbone/Bookmarks.cpp \
  31     gui/SettingsWidget.cpp \
  32     gui/BookmarksWidget.cpp \
  33     gui/WelcomeScreenWidget.cpp \
  34     gui/AboutWidget.cpp \
  35     gui/TranslationTextEdit.cpp
  36 HEADERS += gui/MainWindow.h \
  37     backbone/ConfigGenerator.h \
  38     gui/AboutWidget.h \
  39     gui/SearchBarWidget.h \
  40     gui/WordListWidget.h \
  41     gui/TranslationWidget.h \
  42     backbone/backbone.h \
  43     ../includes/translation.h \
  44     ../includes/settings.h \
  45     ../includes/CommonDictInterface.h \
  46     gui/MenuWidget.h \
  47     gui/MenuTabWidget.h \
  48     gui/DictManagerWidget.h \
  49     gui/DictTypeSelectDialog.h \
  50     gui/TranslationWidgetAutoResizer.h \
  51     ../includes/History.h \
  52     gui/HistoryListDialog.h \
  53     ../includes/GUIInterface.h \
  54     gui/WordListProxyStyle.h \
  55     backbone/Bookmarks.h \
  56     backbone/BookmarkTranslations.h \
  57     gui/SettingsWidget.h \
  58     gui/BookmarksWidget.h \
  59     gui/WelcomeScreenWidget.h \
  60     ../includes/Notify.h \
  61     gui/TranslationTextEdit.h \
  62     ../includes/AccentsNormalizer.h \
  63     ../includes/DictDialog.h
  64 RESOURCES += ../../../data/icons/gui.qrc
  65 unix {
  66     # VARIABLES
  67     isEmpty(PREFIX):PREFIX = /usr
  68     BINDIR = $$PREFIX/bin
  69     DATADIR = $$PREFIX/share
  70     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
  71         PKGDATADIR=\\\"$$PKGDATADIR\\\"
  72
  73     # MAKE INSTALL
  74     INSTALLS += target \
  75         desktop \
  76         icon64 \
  77         configs
  78     configs.path = ~/.mdictionary
  79     configs.files += ../../../data/mdictionary.defaults
  80     target.path = $$BINDIR
  81     maemo5 {
  82         desktop.path = $$DATADIR/applications/hildon
  83         icon64.path = $$DATADIR/icons/hicolor/64x64/hildon
  84     }
  85     !maemo5 {
  86         desktop.path = $$DATADIR/applications
  87         icon64.path = $$DATADIR/icons
  88     }
  89     desktop.files += ../../../data/other/$${TARGET}.desktop
  90     icon64.files += ../../../data/icons/64x64/$${TARGET}.png
  91 }
  92 RESOURCES += xslt2.qrc