vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     routing/routingservice.cpp \
  58     routing/routesegment.cpp \
  59     routing/route.cpp \
  60     routing/location.cpp \
  61     map/maprouteitem.cpp \
  62     coordinates/scenecoordinate.cpp \
  63     coordinates/geocoordinate.cpp \
  64     ui/listview.cpp \
  65     ui/listitem.cpp \
  66     ui/listitemdelegate.cpp \
  67     ui/friendlistitemdelegate.cpp \
  68     ui/searchdialog.cpp
  69 HEADERS += application.h \
  70     common.h \
  71     engine/engine.h \
  72     facebookservice/facebookauthentication.h \
  73     facebookservice/facebookcommon.h \
  74     facebookservice/facebookcredentials.h \
  75     gps/gpscommon.h \
  76     gps/gpsposition.h \
  77     map/baselocationitem.h \
  78     map/friendgroupitem.h \
  79     map/frienditemshandler.h \
  80     map/friendlocationitem.h \
  81     map/gpslocationitem.h \
  82     map/mapcommon.h \
  83     map/mapengine.h \
  84     map/mapfetcher.h \
  85     map/mapscene.h \
  86     map/mapscroller.h \
  87     map/maptile.h \
  88     map/maptilerequest.h \
  89     map/mapview.h \
  90     map/ownlocationitem.h \
  91     network/networkaccessmanager.h \
  92     network/networkcookiejar.h \
  93     network/networkhandler.h \
  94     network/networkreply.h \
  95     situareservice/imagefetcher.h \
  96     situareservice/situarecommon.h \
  97     situareservice/situareservice.h \
  98     ui/updatelocation/texteditautoresizer.h \
  99     ui/updatelocation/updatelocationdialog.h \
 100     ui/avatarimage.h \
 101     ui/friendlistitem.h \
 102     ui/friendlistpanel.h \
 103     ui/imagebutton.h \
 104     ui/logindialog.h \
 105     ui/mainwindow.h \
 106     ui/mapscale.h \
 107     ui/panelcommon.h \
 108     ui/panelsidebar.h \
 109     ui/panelsliderbar.h \
 110     ui/settingsdialog.h \
 111     ui/userinfo.h \
 112     ui/userinfopanel.h \
 113     ui/sidepanel.h \
 114     ui/sidepanelbase.h \
 115     ui/zoombutton.h \
 116     ui/zoombuttonpanel.h \
 117     user/user.h \
 118     ui/fullscreenbutton.h \
 119     engine/mce.h \
 120     routing/routingservice.h \
 121     routing/routingcommon.h \
 122     routing/routesegment.h \
 123     routing/route.h \
 124     routing/location.h \
 125     map/maprouteitem.h \
 126     map/osm.h \
 127     coordinates/scenecoordinate.h \
 128     coordinates/geocoordinate.h \
 129     ui/listview.h \
 130     ui/listitem.h \
 131     ui/listitemdelegate.h \
 132     ui/friendlistitemdelegate.h \
 133     ui/listcommon.h \
 134     ui/searchdialog.h
 135 QT += network \
 136     webkit
 137
 138 DEFINES += QT_NO_DEBUG_OUTPUT
 139
 140 simulator {
 141     SOURCES += network/networkhandlerprivatestub.cpp \
 142                gps/gpspositionprivate.cpp
 143     HEADERS += network/networkhandlerprivatestub.h \
 144                gps/gpspositionprivate.h
 145     QT += maemo5
 146     CONFIG += mobility
 147     MOBILITY += location
 148 } else:maemo5 {
 149     armel {
 150         DEFINES += ARMEL
 151         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 152         SOURCES += network/networkhandlerprivate.cpp \
 153                    engine/mceprivate.cpp
 154         HEADERS += network/networkhandlerprivate.h \
 155                    engine/mceprivate.h
 156         QT += dbus
 157         CONFIG += icd2 qdbus
 158         SOURCES += gps/gpspositionprivateliblocation.cpp \
 159                    gps/liblocationwrapper.cpp \
 160                    gps/geopositioninfo.cpp
 161         HEADERS += gps/gpspositionprivateliblocation.h \
 162                    gps/liblocationwrapper.h \
 163                    gps/geopositioninfo.h
 164         CONFIG += link_pkgconfig
 165         PKGCONFIG += glib-2.0 liblocation mce
 166         LIBS += -llocation
 167     } else {
 168         SOURCES += gps/gpspositionprivatestub.cpp \
 169                    network/networkhandlerprivatestub.cpp \
 170                    engine/mceprivatestub.cpp
 171         HEADERS += gps/gpspositionprivatestub.h \
 172                    network/networkhandlerprivatestub.h \
 173                    engine/mceprivatestub.h
 174     }
 175
 176     QT += maemo5
 177
 178     message([QJson])
 179     message(Make sure you have QJson development headers installed)
 180     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 181     message(to Scratchbox's sources.list in /etc/apt)
 182     message(run: apt-get update)
 183     message(install headers with: apt-get install libqjson-dev)
 184     message([QtMobility])
 185     message(Make sure you have QtMobility development headers installed)
 186     message(install headers with: apt-get install libqtm-dev)
 187 } else {
 188     SOURCES += gps/gpspositionprivatestub.cpp \
 189                network/networkhandlerprivatestub.cpp \
 190                engine/mceprivatestub.cpp
 191     HEADERS += gps/gpspositionprivatestub.h \
 192                network/networkhandlerprivatestub.h \
 193                engine/mceprivatestub.h
 194     message(QJson built in)
 195     message(Make sure you have QJson development headers installed)
 196     message(install headers with: sudo apt-get install libqjson-dev)
 197 }
 198
 199 # -----------------------------------------------------------------
 200 # Debian packetizing additions
 201 # -----------------------------------------------------------------
 202 unix {
 203     # VARIABLES
 204     isEmpty(PREFIX):PREFIX = /usr
 205     BINDIR = $$PREFIX/bin
 206     DATADIR = $$PREFIX/share
 207     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 208         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 209
 210     # MAKE INSTALL
 211     desktop.path = $$DATADIR/applications/hildon
 212     desktop.files += situare.desktop
 213     INSTALLS += desktop
 214     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 215     icon48.files += ../res/icon/48x48/situare.png
 216     INSTALLS += icon48
 217     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 218     icon64.files += ../res/icon/64x64/situare.png
 219     INSTALLS += icon64
 220     target.path = $$BINDIR
 221     INSTALLS += target
 222 }