vcs.maemo.org Git - situare/blob - src/src.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-03-26T07:57:35
   4 #
   5 #-------------------------------------------------
   6
   7 TARGET = ../situare
   8 TEMPLATE = app
   9
  10
  11 SOURCES += main.cpp \
  12     ui/mainwindow.cpp \
  13     ui/mapviewscreen.cpp \
  14     ui/listviewscreen.cpp \
  15     map/mapengine.cpp \
  16     map/mapview.cpp \
  17     map/mapscene.cpp \
  18     map/maptile.cpp \
  19     map/mapfetcher.cpp
  20
  21 HEADERS += ui/mainwindow.h \
  22     ui/mapviewscreen.h \
  23     ui/listviewscreen.h \
  24     map/mapengine.h \
  25     map/mapview.h \
  26     map/mapscene.h \
  27     map/maptile.h \
  28     map/mapfetcher.h \
  29     common.h
  30
  31 QT += network \
  32       webkit
  33
  34
  35 # use don't use OpenGL when building in scratchbox
  36 !maemo5 {
  37     QT += opengl
  38     message(OpenGL built in)
  39     message(Make sure you have OpenGL development headers installed)
  40     message(install headers with: sudo apt-get install libgl-dev libglu-dev)
  41 }
  42
  43 # -----------------------------------------------------------------
  44 #                      Debian packetizing additions
  45 # -----------------------------------------------------------------
  46 unix {
  47 #VARIABLES
  48     isEmpty(PREFIX) {
  49         PREFIX = /usr
  50     }
  51 BINDIR = $$PREFIX/bin
  52 DATADIR =$$PREFIX/share
  53
  54 DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  55
  56 #MAKE INSTALL
  57
  58 desktop.path = $$DATADIR/applications/hildon
  59 desktop.files += situare.desktop
  60 INSTALLS += desktop
  61
  62 icon26.path = $$DATADIR/icons/hicolor/26x26/apps
  63 icon26.files += situare.png
  64 INSTALLS += icon26
  65
  66 target.path = $$BINDIR
  67 INSTALLS += target
  68 }