vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/paneltab.cpp \
  74     ui/tabbedpanel.cpp \
  75     ui/panelbar.cpp \
  76     ui/panelcontent.cpp \
  77     ui/panelbase.cpp \
  78     user/user.cpp \
  79     ui/routingpanel.cpp \
  80     ui/routewaypointlistview.cpp \
  81     ui/routewaypointlistitem.cpp
  82 HEADERS += application.h \
  83     common.h \
  84     engine/engine.h \
  85     error.h \
  86     facebookservice/facebookauthentication.h \
  87     facebookservice/facebookcommon.h \
  88     facebookservice/facebookcredentials.h \
  89     gps/gpscommon.h \
  90     gps/gpsposition.h \
  91     map/baselocationitem.h \
  92     map/friendgroupitem.h \
  93     map/frienditemshandler.h \
  94     map/friendlocationitem.h \
  95     map/gpslocationitem.h \
  96     map/mapcommon.h \
  97     map/mapengine.h \
  98     map/mapfetcher.h \
  99     map/mapscene.h \
 100     map/mapscroller.h \
 101     map/maptile.h \
 102     map/maptilerequest.h \
 103     map/mapview.h \
 104     map/ownlocationitem.h \
 105     network/networkaccessmanager.h \
 106     network/networkcookiejar.h \
 107     network/networkhandler.h \
 108     network/networkreply.h \
 109     situareservice/imagefetcher.h \
 110     situareservice/situarecommon.h \
 111     situareservice/situareservice.h \
 112     ui/updatelocation/texteditautoresizer.h \
 113     ui/updatelocation/updatelocationdialog.h \
 114     ui/avatarimage.h \
 115     ui/friendlistitem.h \
 116     ui/friendlistpanel.h \
 117     ui/imagebutton.h \
 118     ui/logindialog.h \
 119     ui/mainwindow.h \
 120     ui/mapscale.h \
 121     ui/panelcommon.h \
 122     ui/settingsdialog.h \
 123     ui/userinfo.h \
 124     ui/userinfopanel.h \
 125     ui/zoombutton.h \
 126     ui/zoombuttonpanel.h \
 127     user/user.h \
 128     ui/fullscreenbutton.h \
 129     engine/mce.h \
 130     ui/indicatorbutton.h \
 131     ui/indicatorbuttonpanel.h \
 132     routing/geocodingservice.h \
 133     routing/routingservice.h \
 134     routing/routingcommon.h \
 135     routing/routesegment.h \
 136     routing/route.h \
 137     routing/location.h \
 138     map/maprouteitem.h \
 139     map/osm.h \
 140     coordinates/scenecoordinate.h \
 141     coordinates/geocoordinate.h \
 142     ui/listview.h \
 143     ui/listitem.h \
 144     ui/listitemdelegate.h \
 145     ui/friendlistitemdelegate.h \
 146     ui/listcommon.h \
 147     ui/searchdialog.h \
 148     ui/locationlistitem.h \
 149     ui/extendedlistitem.h \
 150     ui/extendedlistitemstore.h \
 151     ui/extendedlistitemdelegate.h \
 152     ui/locationlistview.h \
 153     ui/friendlistview.h \
 154     error.h \
 155     ui/paneltab.h \
 156     ui/tabbedpanel.h \
 157     ui/panelbar.h \
 158     ui/panelcontent.h \
 159     ui/panelbase.h \
 160     ui/routingpanel.h \
 161     ui/routewaypointlistview.h \
 162     ui/routewaypointlistitem.h
 163 QT += network \
 164     webkit
 165
 166 DEFINES += QT_NO_DEBUG_OUTPUT
 167
 168 simulator {
 169     SOURCES += network/networkhandlerprivatestub.cpp \
 170                gps/gpspositionprivate.cpp
 171     HEADERS += network/networkhandlerprivatestub.h \
 172                gps/gpspositionprivate.h
 173     QT += maemo5
 174     CONFIG += mobility
 175     MOBILITY += location
 176 } else:maemo5 {
 177     armel {
 178         DEFINES += ARMEL
 179         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 180         SOURCES += network/networkhandlerprivate.cpp \
 181                    engine/mceprivate.cpp
 182         HEADERS += network/networkhandlerprivate.h \
 183                    engine/mceprivate.h
 184         QT += dbus xml
 185         CONFIG += icd2 qdbus
 186         SOURCES += gps/gpspositionprivateliblocation.cpp \
 187                    gps/liblocationwrapper.cpp \
 188                    gps/geopositioninfo.cpp
 189         HEADERS += gps/gpspositionprivateliblocation.h \
 190                    gps/liblocationwrapper.h \
 191                    gps/geopositioninfo.h
 192         CONFIG += link_pkgconfig
 193         PKGCONFIG += glib-2.0 liblocation mce
 194         LIBS += -llocation
 195     } else {
 196         SOURCES += gps/gpspositionprivatestub.cpp \
 197                    network/networkhandlerprivatestub.cpp \
 198                    engine/mceprivatestub.cpp
 199         HEADERS += gps/gpspositionprivatestub.h \
 200                    network/networkhandlerprivatestub.h \
 201                    engine/mceprivatestub.h
 202     }
 203
 204     QT += maemo5
 205
 206     message([QJson])
 207     message(Make sure you have QJson development headers installed)
 208     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 209     message(to Scratchbox's sources.list in /etc/apt)
 210     message(run: apt-get update)
 211     message(install headers with: apt-get install libqjson-dev)
 212     message([QtMobility])
 213     message(Make sure you have QtMobility development headers installed)
 214     message(install headers with: apt-get install libqtm-dev)
 215 } else {
 216     SOURCES += gps/gpspositionprivatestub.cpp \
 217                network/networkhandlerprivatestub.cpp \
 218                engine/mceprivatestub.cpp
 219     HEADERS += gps/gpspositionprivatestub.h \
 220                network/networkhandlerprivatestub.h \
 221                engine/mceprivatestub.h
 222     message(QJson built in)
 223     message(Make sure you have QJson development headers installed)
 224     message(install headers with: sudo apt-get install libqjson-dev)
 225 }
 226
 227 # -----------------------------------------------------------------
 228 # Debian packetizing additions
 229 # -----------------------------------------------------------------
 230 unix {
 231     # VARIABLES
 232     isEmpty(PREFIX):PREFIX = /usr
 233     BINDIR = $$PREFIX/bin
 234     DATADIR = $$PREFIX/share
 235     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 236         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 237
 238     # MAKE INSTALL
 239     desktop.path = $$DATADIR/applications/hildon
 240     desktop.files += situare.desktop
 241     INSTALLS += desktop
 242     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 243     icon48.files += ../res/icon/48x48/situare.png
 244     INSTALLS += icon48
 245     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 246     icon64.files += ../res/icon/64x64/situare.png
 247     INSTALLS += icon64
 248     target.path = $$BINDIR
 249     INSTALLS += target
 250 }