vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += "/usr/include/qjson"
   7 LIBS += "-lqjson"
   8 RESOURCES += ../images.qrc
   9 SOURCES += main.cpp \
  10     ui/mainwindow.cpp \
  11     ui/mapviewscreen.cpp \
  12     situareservice/situareservice.cpp \
  13     situareservice/imagefetcher.cpp \
  14     facebookservice/facebookcredentials.cpp \
  15     facebookservice/facebookauthentication.cpp \
  16     map/mapengine.cpp \
  17     map/mapview.cpp \
  18     map/mapscene.cpp \
  19     map/maptile.cpp \
  20     map/mapfetcher.cpp \
  21     map/ownlocationitem.cpp \
  22     map/baselocationitem.cpp \
  23     map/friendlocationitem.cpp \
  24     ui/updatelocation/updatelocationdialog.cpp \
  25     ui/updatelocation/texteditautoresizer.cpp \
  26     ui/friendlistview.cpp \
  27     ui/friendlistitem.cpp \
  28     user/user.cpp \
  29     ui/avatarimage.cpp \
  30     engine/engine.cpp \
  31     ui/settingsdialog.cpp \
  32     ui/logindialog.cpp \
  33     map/maptilerequest.cpp \
  34     ui/imagebutton.cpp \
  35     ui/friendlistpanel.cpp \
  36     ui/userpanel.cpp \
  37     ui/panelsidebar.cpp \
  38     ui/panelsliderbar.cpp \
  39     map/friendgroupitem.cpp \
  40     map/frienditemshandler.cpp \
  41     gps/gpspositioninterface.cpp \
  42     ui/zoombuttonpanel.cpp \
  43     ui/userinfo.cpp
  44 HEADERS += ui/mainwindow.h \
  45     ui/mapviewscreen.h \
  46     map/mapengine.h \
  47     map/mapview.h \
  48     map/mapscene.h \
  49     map/maptile.h \
  50     map/mapfetcher.h \
  51     map/mapcommon.h \
  52     map/ownlocationitem.h \
  53     map/baselocationitem.h \
  54     map/friendlocationitem.h \
  55     ui/updatelocation/updatelocationdialog.h \
  56     ui/updatelocation/texteditautoresizer.h \
  57     situareservice/situareservice.h \
  58     situareservice/situarecommon.h \
  59     situareservice/imagefetcher.h \
  60     facebookservice/facebookcredentials.h \
  61     facebookservice/facebookauthentication.h \
  62     facebookservice/facebookcommon.h \
  63     ui/friendlistview.h \
  64     ui/friendlistitem.h \
  65     user/user.h \
  66     ui/avatarimage.h \
  67     engine/engine.h \
  68     ui/settingsdialog.h \
  69     ui/logindialog.h \
  70     map/maptilerequest.h \
  71     ui/imagebutton.h \
  72     ui/friendlistpanel.h \
  73     ui/userpanel.h \
  74     ui/panelcommon.h \
  75     ui/panelsidebar.h \
  76     ui/panelsliderbar.h \
  77     map/friendgroupitem.h \
  78     map/frienditemshandler.h \
  79     gps/gpspositioninterface.h \
  80     ui/zoombuttonpanel.h \
  81     situarecommon.h \
  82     ui/userinfo.h
  83 QT += network \
  84     webkit
  85 DEFINES += QT_NO_DEBUG_OUTPUT
  86
  87 !maemo5 {
  88     SOURCES += gps/gpspositionmockup.cpp
  89     HEADERS += gps/gpspositionmockup.h
  90     message(QJson built in)
  91     message(Make sure you have QJson development headers installed)
  92     message(install headers with: sudo apt-get install libqjson-dev)
  93 }
  94 maemo5 {
  95     SOURCES += gps/gpsposition.cpp
  96     HEADERS += gps/gpsposition.h
  97     QT += maemo5
  98     CONFIG += mobility
  99     MOBILITY = location
 100     message([QJson])
 101     message(Make sure you have QJson development headers installed)
 102     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 103     message(to Scratchbox's sources.list in /etc/apt)
 104     message(run: apt-get update)
 105     message(install headers with: apt-get install libqjson-dev)
 106     message([QtMobility])
 107     message(Make sure you have QtMobility development headers installed)
 108     message(install headers with: apt-get install libqtm-dev)
 109 }
 110
 111 # -----------------------------------------------------------------
 112 # Debian packetizing additions
 113 # -----------------------------------------------------------------
 114 unix {
 115     # VARIABLES
 116     isEmpty(PREFIX):PREFIX = /usr
 117     BINDIR = $$PREFIX/bin
 118     DATADIR = $$PREFIX/share
 119     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 120         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 121
 122     # MAKE INSTALL
 123     desktop.path = $$DATADIR/applications/hildon
 124     desktop.files += situare.desktop
 125     INSTALLS += desktop
 126     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 127     icon48.files += ../res/icon/48x48/situare.png
 128     INSTALLS += icon48
 129     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 130     icon64.files += ../res/icon/64x64/situare.png
 131     INSTALLS += icon64
 132     target.path = $$BINDIR
 133     INSTALLS += target
 134 }