vcs.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     engine/engine.cpp \
  13     facebookservice/facebookauthentication.cpp \
  14     facebookservice/facebookcredentials.cpp \
  15     gps/gpsposition.cpp \
  16     map/baselocationitem.cpp \
  17     map/friendgroupitem.cpp \
  18     map/frienditemshandler.cpp \
  19     map/friendlocationitem.cpp \
  20     map/gpslocationitem.cpp \
  21     map/mapengine.cpp \
  22     map/mapfetcher.cpp \
  23     map/mapscene.cpp \
  24     map/maptile.cpp \
  25     map/maptilerequest.cpp \
  26     map/mapview.cpp \
  27     map/ownlocationitem.cpp \
  28     network/networkaccessmanager.cpp \
  29     network/networkcookiejar.cpp \
  30     network/networkhandler.cpp \
  31     network/networkreply.cpp \
  32     situareservice/imagefetcher.cpp \
  33     situareservice/situareservice.cpp \
  34     ui/updatelocation/texteditautoresizer.cpp \
  35     ui/updatelocation/updatelocationdialog.cpp \
  36     ui/avatarimage.cpp \
  37     ui/friendlistitem.cpp \
  38     ui/friendlistpanel.cpp \
  39     ui/friendlistview.cpp \
  40     ui/imagebutton.cpp \
  41     ui/logindialog.cpp \
  42     ui/mainwindow.cpp \
  43     ui/mapscale.cpp \
  44     ui/panelsidebar.cpp \
  45     ui/panelsliderbar.cpp \
  46     ui/settingsdialog.cpp \
  47     ui/sidepanel.cpp \
  48     ui/sidepanelbase.cpp \
  49     ui/userinfo.cpp \
  50     ui/userinfopanel.cpp \
  51     ui/zoombutton.cpp \
  52     ui/zoombuttonpanel.cpp \
  53     user/user.cpp
  54 HEADERS += common.h \
  55     engine/engine.h \
  56     facebookservice/facebookauthentication.h \
  57     facebookservice/facebookcommon.h \
  58     facebookservice/facebookcredentials.h \
  59     gps/gpscommon.h \
  60     gps/gpsposition.h \
  61     map/baselocationitem.h \
  62     map/friendgroupitem.h \
  63     map/frienditemshandler.h \
  64     map/friendlocationitem.h \
  65     map/gpslocationitem.h \
  66     map/mapcommon.h \
  67     map/mapengine.h \
  68     map/mapfetcher.h \
  69     map/mapscene.h \
  70     map/maptile.h \
  71     map/maptilerequest.h \
  72     map/mapview.h \
  73     map/ownlocationitem.h \
  74     network/networkaccessmanager.h \
  75     network/networkcookiejar.h \
  76     network/networkhandler.h \
  77     network/networkreply.h \
  78     situareservice/imagefetcher.h \
  79     situareservice/situarecommon.h \
  80     situareservice/situareservice.h \
  81     ui/updatelocation/texteditautoresizer.h \
  82     ui/updatelocation/updatelocationdialog.h \
  83     ui/avatarimage.h \
  84     ui/friendlistitem.h \
  85     ui/friendlistpanel.h \
  86     ui/friendlistview.h \
  87     ui/imagebutton.h \
  88     ui/logindialog.h \
  89     ui/mainwindow.h \
  90     ui/mapscale.h \
  91     ui/panelcommon.h \
  92     ui/panelsidebar.h \
  93     ui/panelsliderbar.h \
  94     ui/settingsdialog.h \
  95     ui/userinfo.h \
  96     ui/userinfopanel.h \
  97     ui/sidepanel.h \
  98     ui/sidepanelbase.h \
  99     ui/zoombutton.h \
 100     ui/zoombuttonpanel.h \
 101     user/user.h
 102 QT += network \
 103     webkit
 104
 105 DEFINES += QT_NO_DEBUG_OUTPUT
 106
 107 simulator {
 108     SOURCES += network/networkhandlerprivatestub.cpp \
 109                gps/gpspositionprivate.cpp
 110     HEADERS += network/networkhandlerprivatestub.h \
 111                gps/gpspositionprivate.h
 112     QT += maemo5
 113     CONFIG += mobility
 114     MOBILITY += location
 115 } else:maemo5 {
 116     armel {
 117         DEFINES += ARMEL
 118         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 119         SOURCES += network/networkhandlerprivate.cpp
 120         HEADERS += network/networkhandlerprivate.h
 121         QT += dbus
 122         CONFIG += icd2
 123 #        SOURCES += gps/gpspositionprivateliblocation.cpp \
 124 #                   gps/liblocationwrapper.cpp \
 125 #                   gps/geopositioninfo.cpp \
 126 #                   gps/geocoordinate.cpp
 127 #        HEADERS += gps/gpspositionprivateliblocation.h \
 128 #                   gps/liblocationwrapper.h \
 129 #                   gps/geopositioninfo.h \
 130 #                   gps/geocoordinate.h
 131 #        CONFIG += link_pkgconfig
 132 #        PKGCONFIG += glib-2.0 liblocation
 133         SOURCES += gps/gpspositionprivatestub.cpp
 134         HEADERS += gps/gpspositionprivatestub.h
 135     } else {
 136         SOURCES += gps/gpspositionprivatestub.cpp \
 137                    network/networkhandlerprivatestub.cpp
 138         HEADERS += gps/gpspositionprivatestub.h \
 139                    network/networkhandlerprivatestub.h
 140     }
 141
 142     QT += maemo5
 143
 144     message([QJson])
 145     message(Make sure you have QJson development headers installed)
 146     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 147     message(to Scratchbox's sources.list in /etc/apt)
 148     message(run: apt-get update)
 149     message(install headers with: apt-get install libqjson-dev)
 150     message([QtMobility])
 151     message(Make sure you have QtMobility development headers installed)
 152     message(install headers with: apt-get install libqtm-dev)
 153 } else {
 154     SOURCES += gps/gpspositionprivatestub.cpp \
 155                network/networkhandlerprivatestub.cpp
 156     HEADERS += gps/gpspositionprivatestub.h \
 157                network/networkhandlerprivatestub.h
 158     message(QJson built in)
 159     message(Make sure you have QJson development headers installed)
 160     message(install headers with: sudo apt-get install libqjson-dev)
 161 }
 162
 163 # -----------------------------------------------------------------
 164 # Debian packetizing additions
 165 # -----------------------------------------------------------------
 166 unix {
 167     # VARIABLES
 168     isEmpty(PREFIX):PREFIX = /usr
 169     BINDIR = $$PREFIX/bin
 170     DATADIR = $$PREFIX/share
 171     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 172         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 173
 174     # MAKE INSTALL
 175     desktop.path = $$DATADIR/applications/hildon
 176     desktop.files += situare.desktop
 177     INSTALLS += desktop
 178     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 179     icon48.files += ../res/icon/48x48/situare.png
 180     INSTALLS += icon48
 181     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 182     icon64.files += ../res/icon/64x64/situare.png
 183     INSTALLS += icon64
 184     target.path = $$BINDIR
 185     INSTALLS += target
 186 }