vcs.maemo.org Git - cinaest/blob - src/movie-list-window.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListWindow : StackableWindow {
  23         private MovieListMenu menu;
  24         private Hildon.EditToolbar edit_toolbar;
  25         private Hildon.Entry search_field;
  26         private Toolbar search_bar;
  27         private uint source_id;
  28         private MovieListView movie_list;
  29         private MovieFilter filter;
  30         private MovieListStore store;
  31         private Label no_movies;
  32         private bool search_bar_visible;
  33
  34         public MovieListWindow (MovieSource source) {
  35                 set_title (source.get_description ());
  36
  37                 // View menu
  38                 menu = new MovieListMenu (this);
  39                 menu.source = source;
  40
  41                 set_main_menu (menu);
  42
  43                 // Search bar
  44                 search_field = new Hildon.Entry (SizeType.FINGER_HEIGHT);
  45
  46                 var search_field_item = new ToolItem ();
  47                 search_field_item.set_expand (true);
  48                 search_field_item.add (search_field);
  49
  50                 var close_image = new Image.from_file("/usr/share/icons/hicolor/48x48/hildon/general_close.png");
  51                 var close_button = new ToolButton (close_image, _("Close"));
  52
  53                 search_bar = new Toolbar ();
  54                 search_bar.insert (search_field_item, 0);
  55                 search_bar.insert (close_button, 1);
  56
  57                 add_toolbar (search_bar);
  58
  59                 // Movie list - connected to menu for sorting
  60                 movie_list = new MovieListView ();
  61                 menu.sortable = movie_list.sorted_store;
  62                 store = movie_list.store;
  63                 store.source = source;
  64
  65                 no_movies = new Label (_("No movies"));
  66                 Hildon.helper_set_logical_font (no_movies, "LargeSystemFont");
  67                 Hildon.helper_set_logical_color (no_movies, RcFlags.FG, StateType.NORMAL, "SecondaryTextColor");
  68                 no_movies.set_size_request (-1, 6 * 70);
  69                 no_movies.set_alignment ((float) 0.5, (float) 0.42);
  70
  71                 var vbox = new VBox (false, 0);
  72                 vbox.pack_start (movie_list, true, true, 0);
  73                 vbox.pack_start (no_movies, false, false, 0);
  74
  75                 add (vbox);
  76
  77                 edit_toolbar = new Hildon.EditToolbar.with_text (_("Select movies"), _("Delete"));
  78                 set_edit_toolbar (edit_toolbar);
  79
  80                 // Connect signals
  81                 menu.filter_changed.connect (() => { start_search (); });
  82                 edit_toolbar.button_clicked.connect (on_delete_button_clicked);
  83                 edit_toolbar.arrow_clicked.connect (leave_edit_mode);
  84                 search_field.changed.connect (on_search_field_changed);
  85                 close_button.clicked.connect (on_close_button_clicked);
  86                 key_press_event.connect (on_key_press_event);
  87                 movie_list.movie_activated.connect (on_movie_activated);
  88                 store.search_finished.connect (on_search_finished);
  89
  90                 store.notify["update-running"].connect (on_update_running_changed);
  91
  92                 search_field.set_flags (WidgetFlags.CAN_DEFAULT);
  93                 search_field.grab_default ();
  94
  95                 show_all ();
  96                 edit_toolbar.hide ();
  97                 search_bar_visible = false;
  98                 search_bar.hide ();
  99
 100                 filter = new MovieFilter ();
 101                 menu.filter = filter;
 102                 filter.title = "";
 103                 if (store.start_search (filter)) {
 104                         no_movies.hide ();
 105                 } else {
 106                         movie_list.hide ();
 107                 }
 108         }
 109
 110         public void on_delete_movies_clicked () {
 111                 fullscreen ();
 112                 edit_toolbar.show ();
 113                 movie_list.set_hildon_ui_mode (UIMode.EDIT);
 114
 115                 var selection = movie_list.get_selection ();
 116                 selection.unselect_all ();
 117         }
 118
 119         private void on_delete_button_clicked () {
 120                 var selection = movie_list.get_selection ();
 121                 int count = selection.count_selected_rows ();
 122                 if (count == 0) {
 123                         Banner.show_information (this, null, _("No movies selected"));
 124                         leave_edit_mode ();
 125                         return;
 126                 }
 127
 128                 var dialog = new Note.confirmation (this, _("Delete %d movies?").printf (count));
 129                 var res = dialog.run ();
 130
 131                 if (res == Gtk.ResponseType.OK) {
 132                         weak TreeModel model;
 133                         var rows = selection.get_selected_rows (out model);
 134
 135                         var movies = new List<Movie> ();
 136
 137                         // get selected movies from the store
 138                         foreach (TreePath path in rows) {
 139                                 TreeIter iter;
 140
 141                                 if (model.get_iter (out iter, path)) {
 142                                         Movie movie;
 143
 144                                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 145                                         if (movie != null) {
 146                                                 movies.append (movie);
 147                                         }
 148                                 }
 149                         }
 150                         // and remove them
 151                         foreach (Movie movie in movies) {
 152                                 store.remove (movie);
 153                         }
 154
 155                         // Switch to "No movies" label if the store is emptied
 156                         TreeIter iter;
 157                         if (!store.get_iter_first (out iter)) {
 158                                 movie_list.hide ();
 159                                 no_movies.show ();
 160                         }
 161                 }
 162                 dialog.destroy ();
 163                 leave_edit_mode ();
 164         }
 165
 166         private void leave_edit_mode () {
 167                 movie_list.set_hildon_ui_mode (UIMode.NORMAL);
 168                 edit_toolbar.hide ();
 169                 unfullscreen ();
 170         }
 171
 172         private void on_close_button_clicked () {
 173                 search_field.set_text ("");
 174                 search_bar_visible = false;
 175                 search_bar.hide ();
 176         }
 177
 178         private bool on_key_press_event (Widget widget, Gdk.EventKey event) {
 179                 if (event.str != "") {
 180                         if (!search_bar_visible) {
 181                                 search_bar_visible = true;
 182                                 search_bar.show ();
 183                         }
 184                         search_field.grab_focus ();
 185                 }
 186
 187                 return false;
 188         }
 189
 190         private void on_search_field_changed () {
 191                 // With every change we reset the timer to 500ms
 192                 if (source_id != 0) {
 193                         Source.remove (source_id);
 194                 }
 195                 source_id = Timeout.add (500, start_search);
 196         }
 197
 198         private bool start_search () {
 199                 filter.title = search_field.get_text ();
 200                 if (store.start_search (filter)) {
 201                         movie_list.show ();
 202                         no_movies.hide ();
 203                 }
 204
 205                 // One-shot only
 206                 return false;
 207         }
 208
 209         private void on_search_finished (int movies) {
 210                 if (movies > 100) {
 211                         Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 212                 }
 213         }
 214
 215         private void on_movie_activated (Movie movie) {
 216                 var window = new MovieWindow.with_movie (movie, store);
 217
 218                 window.show ();
 219         }
 220
 221         private void on_update_running_changed (GLib.Object source, ParamSpec spec) {
 222                 TreeIter iter;
 223
 224                 Hildon.gtk_window_set_progress_indicator (this, (int) store.update_running);
 225                 // Update finished, but store still empty?
 226                 if (!store.update_running && !store.get_iter_first (out iter)) {
 227                         movie_list.hide ();
 228                         no_movies.show ();
 229                 }
 230         }
 231 }
 232