vcs.maemo.org Git - cinaest/blob - src/movie-list-view.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListView : PannableArea {
  23         public MovieListStore store;
  24         TreeView tree;
  25         IconView icons;
  26
  27         private bool more_movies_available;
  28         private CellRendererText title_renderer;
  29         private CellRendererText secondary_renderer;
  30         private CellRendererText rating_renderer;
  31         private CellRendererText date_renderer;
  32         private MoviePoster.Factory poster_factory;
  33
  34         private bool poster_mode_;
  35         public bool poster_mode {
  36                 get {
  37                         return poster_mode_;
  38                 }
  39                 set {
  40                         if (value & !poster_mode_) {
  41                                 remove (tree);
  42                                 add (icons);
  43                         } else if (!value & poster_mode_) {
  44                                 remove (icons);
  45                                 add (tree);
  46                         }
  47                         poster_mode_ = value;
  48                 }
  49         }
  50
  51         public signal void movie_activated (Movie movie);
  52
  53         private Gtk.TreeView create_treeview (Gtk.Window window, bool show_date) {
  54                 // Tree View
  55                 var tree = (TreeView) Hildon.gtk_tree_view_new_with_model (UIMode.NORMAL, store);
  56                 tree.set_headers_visible (false);
  57                 tree.set_rules_hint (true);
  58
  59                 // Tree selection object
  60                 var selection = tree.get_selection ();
  61                 selection.set_mode (SelectionMode.SINGLE);
  62
  63                 // Title column with poster
  64                 var title_column = new TreeViewColumn ();
  65                 title_column.set_title (_("Movie"));
  66                 title_column.set_sort_column_id (MovieListStore.Columns.TITLE);
  67                 title_column.set_reorderable (false);
  68                 title_column.set_sizing (TreeViewColumnSizing.AUTOSIZE);
  69                 title_column.set_expand (true);
  70
  71                 // Add poster icon to column
  72                 var pixbuf_renderer = new CellRendererPixbuf ();
  73                 pixbuf_renderer.width = 64;
  74                 pixbuf_renderer.xalign = 0.0f;
  75                 title_column.pack_start (pixbuf_renderer, false);
  76                 title_column.add_attribute (pixbuf_renderer, "pixbuf", MovieListStore.Columns.ICON);
  77
  78                 // Add text to column
  79                 var vbox_renderer = new CellRendererVBox ();
  80
  81                 title_renderer = new CellRendererText ();
  82                 title_renderer.yalign = 1.0f;
  83                 title_renderer.ellipsize = Pango.EllipsizeMode.END;
  84
  85                 vbox_renderer.append (title_renderer, true);
  86
  87                 // Add secondary text to column (Genres, Director, etc.)
  88                 secondary_renderer = new CellRendererText ();
  89                 secondary_renderer.yalign = 0;
  90                 secondary_renderer.ellipsize = Pango.EllipsizeMode.END;
  91                 secondary_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
  92
  93                 vbox_renderer.append (secondary_renderer, true);
  94
  95                 title_column.pack_start (vbox_renderer, true);
  96                 title_column.set_cell_data_func (vbox_renderer, title_data_func);
  97
  98                 tree.append_column (title_column);
  99
 100                 // Year column
 101                 var year_column = new TreeViewColumn ();
 102                 year_column.set_title (_("Year"));
 103                 year_column.set_sort_column_id (MovieListStore.Columns.YEAR);
 104                 year_column.set_reorderable (false);
 105                 year_column.set_sort_order (SortType.DESCENDING);
 106                 tree.append_column (year_column);
 107
 108                 // Rating column
 109                 var rating_column = new TreeViewColumn ();
 110                 rating_column.set_title (_("Rating"));
 111                 rating_column.set_sort_column_id (MovieListStore.Columns.RATING);
 112                 rating_column.set_reorderable (false);
 113                 rating_column.set_sort_order (SortType.DESCENDING);
 114                 rating_column.xalign = 1.0f;
 115
 116                 vbox_renderer = new CellRendererVBox ();
 117
 118                 rating_renderer = new CellRendererText ();
 119                 rating_renderer.xalign = 1.0f;
 120                 if (show_date)
 121                         rating_renderer.yalign = 1.0f;
 122
 123                 vbox_renderer.append (rating_renderer, true);
 124
 125                 date_renderer = new CellRendererText ();
 126                 date_renderer.yalign = 0;
 127                 date_renderer.attributes = get_attributes (window, "SmallSystemFont", "SecondaryTextColor");
 128
 129                 if (show_date)
 130                         vbox_renderer.append (date_renderer, true);
 131
 132                 rating_column.pack_start (vbox_renderer, true);
 133                 rating_column.set_cell_data_func (vbox_renderer, rating_data_func);
 134
 135                 tree.append_column (rating_column);
 136                 tree.show ();
 137                 return tree;
 138         }
 139
 140         private Gtk.IconView create_iconview () {
 141                 var iconview = (Gtk.IconView) Hildon.gtk_icon_view_new_with_model (Hildon.UIMode.NORMAL, store);
 142                 iconview.set_column_spacing (0);
 143                 iconview.set_pixbuf_column (MovieListStore.Columns.POSTER);
 144                 iconview.margin = 0;
 145                 iconview.item_width = Poster.SMALL_WIDTH;
 146                 iconview.column_spacing = Hildon.MARGIN_HALF;
 147                 iconview.row_spacing = Hildon.MARGIN_HALF;
 148                 iconview.show ();
 149
 150                 return iconview;
 151         }
 152
 153         public MovieListView (Gtk.Window window, bool show_date = false) {
 154                 store = new MovieListStore ();
 155
 156                 // Sort by title
 157                 store.set_sort_column_id (MovieListStore.Columns.TITLE, SortType.ASCENDING);
 158
 159                 Gdk.Color color;
 160                 window.ensure_style ();
 161                 if (window.style.lookup_color ("SecondaryTextColor", out color)) {
 162                         store.year_markup = "<span size=\"small\" fgcolor=\"%s\">(%%d)</span>".printf (color.to_string ());
 163                 }
 164
 165                 tree = create_treeview (window, show_date);
 166                 store.view = (Widget) tree;
 167
 168                 icons = create_iconview ();
 169
 170                 add (tree);
 171
 172                 // Connect signals
 173                 get_vadjustment ().value_changed.connect (on_adjustment_value_changed);
 174                 tree.row_activated.connect (on_row_activated);
 175                 icons.item_activated.connect (on_item_activated);
 176                 store.row_changed.connect (on_row_changed);
 177                 store.search_finished.connect (on_search_finished);
 178         }
 179
 180         construct {
 181                 hscrollbar_policy = Gtk.PolicyType.NEVER;
 182
 183                 poster_factory = MoviePoster.Factory.get_instance ();
 184         }
 185
 186         public void set_hildon_ui_mode (UIMode mode) {
 187                 var selection = tree.get_selection ();
 188
 189                 if (mode == UIMode.NORMAL) {
 190                         selection.set_mode (SelectionMode.NONE);
 191                         icons.set_selection_mode (SelectionMode.NONE);
 192                 }
 193                 Hildon.gtk_tree_view_set_ui_mode (tree, mode);
 194                 Hildon.gtk_icon_view_set_ui_mode (icons, mode);
 195                 if (mode == UIMode.EDIT) {
 196                         selection.set_mode (SelectionMode.MULTIPLE);
 197                         icons.set_selection_mode (SelectionMode.MULTIPLE);
 198                 }
 199         }
 200
 201         private Pango.AttrList get_attributes (Gtk.Window window, string font_name, string color_name) {
 202                 Pango.AttrList attr_list = new Pango.AttrList ();
 203                 var style = Gtk.rc_get_style_by_paths (Gtk.Settings.get_default (), font_name, null, typeof (void));
 204                 if (style != null) {
 205                         var attr_font_desc = new Pango.AttrFontDesc (style.font_desc.copy ());
 206                         attr_list.insert ((owned) attr_font_desc);
 207                 }
 208                 Gdk.Color color;
 209                 window.ensure_style ();
 210                 if (window.style.lookup_color (color_name, out color)) {
 211                         Pango.Attribute attr_color = Pango.attr_foreground_new (color.red, color.green, color.blue);
 212                         attr_list.insert ((owned) attr_color);
 213                 }
 214                 return attr_list;
 215         }
 216
 217         public void unselect_all () {
 218                 tree.get_selection ().unselect_all ();
 219                 icons.unselect_all ();
 220         }
 221
 222         public List<Movie> get_selected_movies () {
 223                 var movies = new List<Movie> ();
 224                 List<TreePath> paths;
 225
 226                 if (poster_mode_)
 227                         paths = icons.get_selected_items ();
 228                 else
 229                         paths = tree.get_selection ().get_selected_rows (null);
 230
 231                 // get selected movies from the store
 232                 foreach (TreePath path in paths) {
 233                         TreeIter iter;
 234
 235                         if (store.get_iter (out iter, path)) {
 236                                 Movie movie;
 237
 238                                 store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 239                                 if (movie != null) {
 240                                         movies.append (movie);
 241                                 }
 242                         }
 243                 }
 244
 245                 return movies;
 246         }
 247
 248         // TODO: after scrolling down 80% of the list, load more
 249         //       results if available.
 250         int last_a = 0;
 251         int last_b = 0;
 252         private void on_adjustment_value_changed () {
 253                 if (more_movies_available) {
 254                         var vadj = get_vadjustment ();
 255                         if (vadj.value > 0.8 * vadj.upper) {
 256                                 Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 257                                 more_movies_available = false;
 258                         }
 259                 }
 260
 261                 TreePath a_;
 262                 TreePath b_;
 263                 bool range;
 264                 if (poster_mode_) {
 265                         range = icons.get_visible_range (out a_, out b_);
 266                 } else {
 267                         range = tree.get_visible_range (out a_, out b_);
 268                 }
 269                 if (range) {
 270                         // We know the list store is flat
 271                         int a = a_.get_indices ()[0];
 272                         int b = b_.get_indices ()[0];
 273                         assert (a <= b);
 274
 275                         if (a == last_a && b == last_b)
 276                                 return;
 277
 278                         if (a > last_b || b < last_a) {
 279                                 check_posters (a, b);
 280                         } else if (a >= last_a && b > last_b) {
 281                                 check_posters (last_b + 1, b);
 282                         } else if (b <= last_b && a < last_a) {
 283                                 check_posters (a, last_a - 1);
 284                         }
 285
 286                         last_a = a;
 287                         last_b = b;
 288                 }
 289         }
 290
 291         private void check_posters (int a, int b) {
 292                 for (int i = a; i <= b; i++) {
 293                         var path = new TreePath.from_indices (i);
 294                         TreeIter iter;
 295                         if (store.get_iter (out iter, path)) {
 296                                 Movie movie;
 297                                 store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 298                                 if (movie != null) {
 299                                         if (poster_mode_) {
 300                                                 if (movie.poster == null || movie.poster.small == null) try {
 301                                                         poster_factory.queue_thumbnail (movie, Poster.SMALL_WIDTH, Poster.SMALL_HEIGHT, false, receive_poster_small);
 302                                                 } catch (Error e) {
 303                                                         warning ("Failed to queue poster request: %s\n", e.message);
 304                                                 }
 305                                         } else {
 306                                                 if (movie.poster == null || movie.poster.icon == null) try {
 307                                                         poster_factory.queue_thumbnail (movie, Poster.ICON_WIDTH, Poster.ICON_HEIGHT, false, receive_poster_icon);
 308                                                 } catch (Error e) {
 309                                                         warning ("Failed to queue poster request: %s\n", e.message);
 310                                                 }
 311                                         }
 312                                 }
 313                         }
 314                 }
 315         }
 316
 317         private void on_row_activated (TreeView tree, TreePath path, TreeViewColumn column) {
 318                 on_item_activated (path);
 319         }
 320
 321         private void on_item_activated (TreePath path) {
 322                 TreeIter iter;
 323
 324                 if (store.get_iter (out iter, path)) {
 325                         Movie movie;
 326                         store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 327                         movie_activated (movie);
 328                 }
 329         }
 330
 331         private void on_row_changed (TreePath path, TreeIter iter) {
 332                 TreePath a;
 333                 TreePath b;
 334                 bool range;
 335
 336                 if (poster_mode_) {
 337                         range = icons.get_visible_range (out a, out b);
 338                 } else {
 339                         range = tree.get_visible_range (out a, out b);
 340                 }
 341                 if (!range ||
 342                     (range && path.compare (a) >= 0 && path.compare (b) <= 0)) {
 343                         Movie movie;
 344
 345                         store.get (iter, MovieListStore.Columns.MOVIE, out movie);
 346                         if (movie == null)
 347                                 return;
 348
 349                         int i = path.get_indices ()[0];
 350                         check_posters (i, i);
 351                 }
 352         }
 353
 354         private void receive_poster_small (Gdk.Pixbuf pixbuf, Movie movie) {
 355                 Poster poster;
 356                 if (movie.poster != null)
 357                         poster = movie.poster;
 358                 else
 359                         poster = new Poster ();
 360                 poster.small = pixbuf;
 361                 movie.poster = poster;
 362         }
 363
 364         private void receive_poster_icon (Gdk.Pixbuf pixbuf, Movie movie) {
 365                 Poster poster;
 366                 if (movie.poster != null)
 367                         poster = movie.poster;
 368                 else
 369                         poster = new Poster ();
 370                 poster.icon = pixbuf;
 371                 movie.poster = poster;
 372         }
 373
 374         private void on_search_finished (int movies) {
 375                 more_movies_available = (movies > 100); // FIXME
 376         }
 377
 378         private void title_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 379                 Movie movie;
 380                 string markup;
 381
 382                 model.get (iter, MovieListStore.Columns.MOVIE, out movie,
 383                                  MovieListStore.Columns.MARKUP, out markup);
 384                 title_renderer.markup = markup;
 385                 secondary_renderer.text = movie.secondary;
 386         }
 387
 388         private void rating_data_func (CellLayout cell_layout, CellRenderer cell, TreeModel model, TreeIter iter) {
 389                 string rating;
 390                 Movie movie;
 391
 392                 model.get (iter, MovieListStore.Columns.RATING, out rating,
 393                                  MovieListStore.Columns.MOVIE, out movie);
 394                 rating_renderer.text = rating;
 395                 if (movie.julian_date != 0) {
 396                         var date = Date ();
 397                         date.set_julian (movie.julian_date);
 398                         var s = new char[64];
 399                         date.strftime (s, "%x");
 400                         date_renderer.text = (string) s;
 401                 } else {
 402                         date_renderer.text = "";
 403                 }
 404         }
 405 }