vcs.maemo.org Git - mdictionary/blob - src/mdictionary/mdictionary.pro

   1 TARGET = mdictionary
   2 TEMPLATE = app
   3
   4 include(../../mdictionary.pri)
   5
   6 QT = core \
   7     gui \
   8     xml \
   9     xmlpatterns \
  10     sql \
  11     dbus \
  12     webkit
  13
  14 maemo5:QT += maemo5
  15
  16 message($$CONFIG)
  17
  18 SOURCES += gui/main.cpp \
  19     backbone/ConfigGenerator.cpp \
  20     gui/MainWindow.cpp \
  21     gui/SearchBarWidget.cpp \
  22     gui/WordListWidget.cpp \
  23     gui/TranslationWidget.cpp \
  24     backbone/backbone.cpp \
  25     gui/MenuWidget.cpp \
  26     gui/MenuTabWidget.cpp \
  27     gui/DictManagerWidget.cpp \
  28     gui/DictTypeSelectDialog.cpp \
  29     backbone/History.cpp \
  30     gui/HistoryListDialog.cpp \
  31     gui/WordListProxyStyle.cpp \
  32     backbone/Bookmarks.cpp \
  33     gui/SettingsWidget.cpp \
  34     gui/BookmarksWidget.cpp \
  35     gui/WelcomeScreenWidget.cpp \
  36     gui/AboutWidget.cpp \
  37     gui/TranslationTextEdit.cpp \
  38     gui/DBusAdapter.cpp \
  39     gui/NotifyManager.cpp \
  40     gui/SpinBox.cpp
  41
  42 HEADERS += gui/MainWindow.h \
  43     backbone/ConfigGenerator.h \
  44     gui/AboutWidget.h \
  45     gui/SearchBarWidget.h \
  46     gui/WordListWidget.h \
  47     gui/TranslationWidget.h \
  48     backbone/backbone.h \
  49     ../include/translation.h \
  50     ../include/settings.h \
  51     ../include/CommonDictInterface.h \
  52     gui/MenuWidget.h \
  53     gui/MenuTabWidget.h \
  54     gui/DictManagerWidget.h \
  55     gui/DictTypeSelectDialog.h \
  56     ../include/History.h \
  57     gui/HistoryListDialog.h \
  58     ../include/GUIInterface.h \
  59     gui/WordListProxyStyle.h \
  60     backbone/Bookmarks.h \
  61     backbone/BookmarkTranslations.h \
  62     gui/SettingsWidget.h \
  63     gui/BookmarksWidget.h \
  64     gui/WelcomeScreenWidget.h \
  65     ../include/Notify.h \
  66     gui/TranslationTextEdit.h \
  67     ../include/AccentsNormalizer.h \
  68     ../include/DictDialog.h \
  69     gui/DBusAdapter.h \
  70     gui/NotifyManager.h \
  71     gui/SpinBox.h
  72
  73 RESOURCES += ../../data/gui.qrc
  74
  75 TRANSLATIONS += pl_PL.ts \
  76                 en_US.ts
  77
  78 target.path = $$BIN_DIR
  79 INSTALLS += target
  80
  81 unix {
  82         maemo5 {
  83                 desktop.path = $$SHARE_DIR/applications/hildon
  84                 icon64.path = $$SHARE_DIR/icons/hicolor/64x64/hildon
  85         }
  86         !maemo5 {
  87                 desktop.path = $$SHARE_DIR/applications
  88                 icon64.path = $$SHARE_DIR/icons
  89         }
  90
  91         desktop.files += ../../data/other/$${TARGET}.desktop
  92         icon64.files += ../../data/icons/64x64/$${TARGET}.png
  93
  94     shared.path = $$DATA_DIR
  95     shared.files += ../../data/icons/16x16/staron.png
  96     shared.files += ../../data/xsl/mask.png
  97
  98     meego {
  99         css.path = $$DATA_DIR/css
 100         css.files += ../../data/css_meego/style.css
 101
 102         css_images.path = $$DATA_DIR/css/images
 103         css_images.files += ../../data/css_meego/images/header-background.png
 104         css_images.files += ../../data/css_meego/images/header-border.png
 105         css_images.files += ../../data/css_meego/images/shadow-grey-bg.png
 106         css_images.files += ../../data/css_meego/images/shadow-white-bg.png
 107         css_images.files += ../../data/css_meego/images/tab-background.png
 108         css_images.files += ../../data/css_meego/images/key-background.png
 109         css_images.files += ../../data/css_meego/images/shadow-transparent-bg.png
 110         css_images.files += ../../data/css_meego/images/splash2.png
 111     }
 112     !meego {
 113         css.path = $$DATA_DIR/css
 114         css.files += ../../data/css_maemo/style.css
 115
 116         css_images.path = $$DATA_DIR/css/images
 117         css_images.files += ../../data/css_maemo/images/header-background.png
 118         css_images.files += ../../data/css_maemo/images/header-border.png
 119         css_images.files += ../../data/css_maemo/images/shadow-grey-bg.png
 120         css_images.files += ../../data/css_maemo/images/shadow-white-bg.png
 121         css_images.files += ../../data/css_maemo/images/tab-background.png
 122         css_images.files += ../../data/css_maemo/images/key-background.png
 123     }
 124     service.path = $$SHARE_DIR/dbus-1/services
 125     service.files += ../../data/other/com.comarch.mdictionary.service
 126
 127     INSTALLS += desktop icon64 shared service css css_images
 128 }
 129
 130
 131 check.commands = echo 'No check here'
 132 QMAKE_EXTRA_TARGETS += check