vcs.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml
   2
   3 SOURCES += \
   4     main.cpp \
   5     mainwindow.cpp \
   6     bookview.cpp \
   7     unzip/unzip.c \
   8     unzip/ioapi.c \
   9     extractzip.cpp \
  10     library.cpp \
  11     book.cpp \
  12     librarydialog.cpp \
  13     devtools.cpp \
  14     infodialog.cpp \
  15     translucentbutton.cpp \
  16     settingswindow.cpp \
  17     settings.cpp \
  18     bookmarksdialog.cpp \
  19     sortedlibrary.cpp \
  20     bookmarkinfodialog.cpp \
  21     dialog.cpp \
  22     chaptersdialog.cpp \
  23     fullscreenwindow.cpp \
  24     trace.cpp
  25
  26 HEADERS += \
  27     mainwindow.h \
  28     bookview.h \
  29     opshandler.h \
  30     unzip/unzip.h \
  31     unzip/ioapi.h \
  32     extractzip.h \
  33     library.h \
  34     book.h \
  35     librarydialog.h \
  36     devtools.h \
  37     infodialog.h \
  38     translucentbutton.h \
  39     settingswindow.h \
  40     settings.h \
  41     bookmarksdialog.h \
  42     xmlerrorhandler.h \
  43     containerhandler.h \
  44     sortedlibrary.h \
  45     ncxhandler.h \
  46     bookmarkinfodialog.h \
  47     dialog.h \
  48     chaptersdialog.h \
  49     fullscreenwindow.h \
  50     trace.h
  51
  52 RESOURCES += \
  53     dorian.qrc
  54
  55 OTHER_FILES += \
  56     TODO.txt \
  57     pkg/acknowledgements.txt \
  58     pkg/maemo/postinst \
  59     pkg/maemo/dorian.desktop \
  60     pkg/maemo/control \
  61     pkg/maemo/changelog \
  62     pkg/maemo/build.sh \
  63     styles/night.css \
  64     pkg/changelog \
  65     pkg/maemo/build-scratchbox.sh \
  66     styles/sand.css \
  67     styles/default.css \
  68     pkg/version.txt \
  69     styles/sand.js \
  70     styles/night.js \
  71     styles/default.js \
  72     styles/day.js \
  73     www/index.html
  74
  75 DEFINES += \
  76     USE_FILE32API \
  77     DORIAN_TEST_MODEL
  78
  79 include(modeltest/modeltest.pri)
  80
  81 unix {
  82     LIBS += -lz
  83 }
  84 windows {
  85     # FIXME: Build zlib, too
  86 }
  87 maemo5 {
  88     QT += maemo5
  89     isEmpty(PREFIX) {
  90         PREFIX = /usr
  91     }
  92     BINDIR = $$PREFIX/bin
  93     DATADIR =$$PREFIX/share
  94     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  95
  96     # For "make install"
  97
  98     INSTALLS += target desktop icon48 iconscalable
  99
 100     target.path = $$BINDIR
 101
 102     desktop.path = $$DATADIR/applications/hildon
 103     desktop.files += pkg/maemo/dorian.desktop
 104
 105     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 106     icon48.files += pkg/maemo/icon-48/dorian.png
 107
 108     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 109     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 110 }