vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [1])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58         want_config_output=no
  59         ;;
  60 #  NetBSD*)
  61 #    WANT_KVM=yes
  62 #    WANT_OSSLIB=yes
  63 #    ;;
  64
  65   OpenBSD*)
  66     WANT_KVM=yes
  67     WANT_OSSLIB=yes
  68     ;;
  69
  70 # Solaris doesn't work at all right now
  71 #  SunOS*)
  72 #    WANT_KSTAT=yes
  73 #    ;;
  74
  75   *)
  76     echo "Your operating system $uname isn't supported"
  77     echo "Feel free to help. :P"
  78     exit 1
  79     ;;
  80 esac
  81
  82 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  83 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  84 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  85 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  86 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  87
  88 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  89 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  90 AC_SUBST(BUILD_DATE)
  91 AC_SUBST(BUILD_ARCH)
  92
  93
  94 dnl
  95 dnl BUILD_CONFIG_OUTPUT option
  96 dnl
  97
  98 AC_ARG_ENABLE([config_output],
  99               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) Note: not available on FreeBSD @<:@default=yes@:>@]),
 100               [want_config_output="$enableval"], [want_config_output=yes])
 101
 102 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 103 AM_CONDITIONAL(BUILD_FOR_FOPENCOOKIE, test x$want_config_output = xyes)
 104 if test x$want_config_output = xyes; then
 105   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 106   AC_CHECK_FUNCS(fopencookie)
 107 fi
 108
 109 dnl
 110 dnl OWN_WINDOW option
 111 dnl
 112
 113 AC_ARG_ENABLE([own_window],
 114               AC_HELP_STRING([--disable-own-window],
 115                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 116               [dah="$enableval"], [dah=yes])
 117
 118 if test $dah != "no"; then
 119   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 120 fi
 121
 122
 123 dnl
 124 dnl Audacious Media Player
 125 dnl
 126
 127 AC_ARG_ENABLE([audacious],
 128               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 129                              [enable audacious player support @<:@default=no@:>@]),
 130               [want_audacious="$enableval"], [want_audacious=no])
 131
 132 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 133 if test x$want_audacious = xyes; then
 134       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 135       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 136       LIBS="$LIBS $Audacious_LIBS"
 137       save_CPPFLAGS="$CPPFLAGS"
 138       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 139       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 140                        [], AC_MSG_ERROR([required header(s) not found]))
 141       CPPFLAGS="$save_CPPFLAGS"
 142       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 143 else if test x$want_audacious = xlegacy; then
 144       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 145       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 146       LIBS="$LIBS $Audacious_LIBS"
 147       save_CPPFLAGS="$CPPFLAGS"
 148       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 149       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 150       CPPFLAGS="$save_CPPFLAGS"
 151       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 152       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 153       fi
 154 fi
 155
 156
 157 dnl
 158 dnl BMPx
 159 dnl
 160
 161 AC_ARG_ENABLE([bmpx],
 162               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 163               [want_bmpx="$enableval"], [want_bmpx=no])
 164
 165 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 166 if test x$want_bmpx = xyes; then
 167   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 168   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 169   LIBS="$LIBS $BMPx_LIBS"
 170   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 171 fi
 172
 173
 174 dnl
 175 dnl Support for IBM/Lenovo notebooks
 176 dnl
 177
 178 AC_ARG_ENABLE([ibm],
 179               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 180               [want_ibm="$enableval"], [want_ibm=no])
 181
 182 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 183 if test x$want_ibm = xyes; then
 184         if test x"$uname" != xLinux; then
 185                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 186                 want_ibm=no
 187         else
 188                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 189         fi
 190 fi
 191
 192
 193 dnl
 194 dnl Hddtemp
 195 dnl
 196
 197 AC_ARG_ENABLE([hddtemp],
 198               AC_HELP_STRING([--disable-hddtemp],
 199                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 200               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 201
 202 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 203 if test x$want_hddtemp = xyes; then
 204   if test x"$uname" != xLinux; then
 205       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 206       want_hddtemp=no
 207   else
 208       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 209   fi
 210 fi
 211
 212 dnl
 213 dnl Math
 214 dnl
 215
 216 AC_ARG_ENABLE([math],
 217               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 218               [want_math="$enableval"], [want_math=yes])
 219
 220 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 221 if test x$want_math = xyes; then
 222   LIBS="$LIBS -lm"
 223   AC_DEFINE(MATH, 1, [Define if you want math support])
 224 fi
 225
 226 dnl
 227 dnl MPD
 228 dnl
 229
 230 AC_ARG_ENABLE([mpd],
 231               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 232               [want_mpd="$enableval"], [want_mpd=yes])
 233
 234 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 235 if test x$want_mpd = xyes; then
 236   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 237 fi
 238
 239 dnl
 240 dnl MOC
 241 dnl
 242
 243 AC_ARG_ENABLE([moc],
 244               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 245               [want_moc="$enableval"], [want_moc=yes])
 246
 247 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 248 if test x$want_moc = xyes; then
 249   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 250 fi
 251
 252 dnl
 253 dnl XMMS2
 254 dnl
 255
 256 AC_ARG_ENABLE([xmms2],
 257               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 258               [want_xmms2="$enableval"], [want_xmms2=no])
 259
 260 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 261 if test x$want_xmms2 = xyes; then
 262   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 263     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 264     LIBS="$LIBS $XMMS2_LIBS"
 265     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 266 fi
 267
 268 dnl
 269 dnl EVE Skill Monitor
 270 dnl
 271
 272 AC_ARG_ENABLE([eve],
 273               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 274               [want_eve="$enableval"], [want_eve=no])
 275
 276 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 277 if test x$want_eve = xyes; then
 278         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 279         PKG_CHECK_MODULES([libcurl], libcurl)
 280         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 281         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 282         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 283         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 284         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 285         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 286         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 287 fi
 288
 289 dnl
 290 dnl RSS
 291 dnl
 292
 293 AC_ARG_ENABLE([rss],
 294               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 295               [want_rss="$enableval"], [want_rss=no])
 296 #
 297 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 298 if test x$want_rss = xyes; then
 299         WANT_GLIB=yes
 300         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 301         PKG_CHECK_MODULES([libcurl], libcurl)
 302         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 303         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 304         AC_DEFINE(RSS, 1, [Define if you want rss support])
 305 fi
 306
 307 dnl
 308 dnl Wireless extensions
 309 dnl
 310
 311 AC_ARG_ENABLE([wlan],
 312               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 313               [want_wlan="$enableval"], [want_wlan=no])
 314
 315 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 316 if test x$want_wlan = xyes; then
 317   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 318   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 319         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 320 fi
 321
 322 dnl
 323 dnl IMLIB2
 324 dnl
 325
 326 dnl --commented out until brenden finishes it --
 327 dnl AC_ARG_ENABLE([imlib2],
 328 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 329 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 330 dnl
 331 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 332 dnl if test x$want_imlib2 = xyes; then
 333 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 334 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 335 dnl LIBS="$LIBS $Imlib2_LIBS"
 336 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 337 dnl fi
 338
 339
 340 dnl
 341 dnl PORT_MONITORS
 342 dnl
 343
 344 AC_ARG_ENABLE([portmon],
 345               AC_HELP_STRING([--disable-portmon],
 346                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 347               [want_portmon="$enableval"], [want_portmon=yes])
 348
 349 if test x"$want_portmon" = xyes; then
 350   if test x"$uname" != xLinux; then
 351       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 352       want_portmon=no
 353   else
 354         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 355         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 356            [PORT_MONITORS_MISSING=yes])
 357         if test x"$PORT_MONITORS_MISSING" = xyes; then
 358               AC_MSG_ERROR([missing a needed network header for port monitoring])
 359         fi
 360         WANT_GLIB=yes
 361         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 362   fi
 363 fi
 364 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 365
 366
 367 dnl
 368 dnl ICONV
 369 dnl
 370
 371 AM_ICONV
 372 if test "$am_cv_func_iconv" != yes; then
 373   AC_MSG_WARN([Could not find libiconv])
 374 else
 375   LIBS="$LIBS $LIBICONV"
 376 fi
 377
 378 dnl
 379 dnl X11
 380 dnl
 381
 382 AC_ARG_ENABLE([x11],
 383               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 384               [want_x11="$enableval"], [want_x11=yes])
 385
 386 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 387 if test "x$want_x11" = "xyes"; then
 388     if $PKG_CONFIG --exists x11; then
 389       PKG_CHECK_MODULES([X11], [x11])
 390       CFLAGS="$CFLAGS $X11_CFLAGS"
 391       LIBS="$LIBS $X11_LIBS"
 392     else
 393       dnl non-modular X11 installations
 394       AC_PATH_X
 395       AC_PATH_XTRA
 396       CFLAGS="$CFLAGS $X_CFLAGS"
 397       LIBS="$LIBS $X_LIBS"
 398       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 399       if test "x$no_x" = "xyes"; then
 400         AC_MSG_ERROR([Can't locate your X11 installation])
 401       fi
 402       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 403     fi
 404     AC_DEFINE(X11, 1, [Define if you want to use X11])
 405 fi
 406
 407
 408 dnl
 409 dnl Xext Double-buffering Extension
 410 dnl
 411
 412 AC_ARG_ENABLE([double_buffer],
 413               AC_HELP_STRING([--disable-double-buffer],
 414                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 415               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 416
 417 if test "x$want_double_buffer" = "xyes"; then
 418     if test "x$want_x11" != "xyes"; then
 419       dnl silently disable if no x11
 420       want_double_buffer=no
 421     else
 422       if $PKG_CONFIG --exists xext; then
 423         PKG_CHECK_MODULES([Xext],[xext])
 424         CFLAGS="$CFLAGS $Xext_CFLAGS"
 425         LIBS="$LIBS $Xext_LIBS"
 426       else
 427         dnl non-modular X11 installation
 428         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 429                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 430       fi
 431       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 432     fi
 433 fi
 434
 435
 436 dnl
 437 dnl Xdamage Extension
 438 dnl
 439
 440 AC_ARG_ENABLE([xdamage],
 441               AC_HELP_STRING([--disable-xdamage],
 442                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 443               [want_xdamage="$enableval"], [want_xdamage=yes])
 444
 445 if test "x$want_xdamage" = "xyes"; then
 446     if test "x$want_x11" != "xyes"; then
 447       dnl silently disable if no x11
 448       want_xdamage=no
 449     else
 450       if $PKG_CONFIG --exists xdamage; then
 451         PKG_CHECK_MODULES([XDamage],[xdamage])
 452         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 453         LIBS="$LIBS $XDamage_LIBS"
 454       else
 455         dnl non-modular X11 installation
 456         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 457                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 458       fi
 459       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 460     fi
 461 fi
 462
 463
 464 dnl
 465 dnl Xft
 466 dnl
 467
 468 AC_ARG_ENABLE([xft],
 469               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 470               [want_xft="$enableval"], [want_xft=yes])
 471
 472 if test x$want_xft = "xyes"; then
 473     if test "x$want_x11" != "xyes"; then
 474       dnl silently disable if no x11
 475       want_xft=no
 476     else
 477       PKG_CHECK_MODULES([Xft], [xft])
 478       CFLAGS="$CFLAGS $Xft_CFLAGS"
 479       LIBS="$LIBS $Xft_LIBS"
 480       AC_DEFINE(XFT, 1, [Define for Xft support])
 481     fi
 482 fi
 483
 484 dnl
 485 dnl NVIDIA libXNVCtrl support
 486 dnl
 487
 488 AC_ARG_ENABLE([nvidia],
 489                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 490                 [want_nvidia="$enableval"], [want_nvidia=no])
 491 if test x$want_nvidia = xyes; then
 492     if test "x$want_x11" != "xyes"; then
 493                 # do nada
 494                 want_nvidia=no
 495         else
 496                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 497 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 498 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 499 dnl ## am I Stupid ??
 500 dnl ## it won't find the lib for some reason!?
 501                 LIBS="$LIBS -lXNVCtrl"
 502                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 503         fi
 504 fi
 505 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 506
 507 dnl
 508 dnl GLIB
 509 dnl
 510
 511 if test x$WANT_GLIB = xyes; then
 512         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 513         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 514         LIBS="$LIBS $GLib2_LIBS"
 515 fi
 516
 517 dnl
 518 dnl KVM
 519 dnl
 520
 521 if test x$WANT_KVM = xyes; then
 522   AC_CHECK_LIB(kvm, kvm_open,
 523     LIBS="$LIBS -lkvm",
 524   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 525   )
 526 fi
 527
 528 dnl
 529 dnl devstat
 530 dnl
 531
 532 if test x$WANT_DEVSTAT = xyes; then
 533   AC_CHECK_LIB(devstat, devstat_getversion,
 534          LIBS="$LIBS -ldevstat",
 535          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 536   )
 537 fi
 538
 539 dnl
 540 dnl OSSLIB for NetBSD/OpenBSD
 541 dnl
 542
 543 if test x$WANT_OSSLIB = xyes; then
 544     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 545   LIBS="$LIBS -lossaudio",
 546   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 547     )
 548 fi
 549
 550 dnl
 551 dnl ALSA for Linux
 552 dnl
 553 AC_ARG_ENABLE([alsa],
 554               AC_HELP_STRING([--disable-alsa], [disable if you do not
 555   want ALSA support @<:@default=yes@:>@]),
 556               [want_alsa="$enableval"], [want_alsa=yes])
 557
 558 if test x$want_alsa = xyes; then
 559     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 560 fi
 561 if test x$want_alsa = xyes; then
 562     AC_CHECK_LIB(asound, snd_pcm_open,LIBS="$LIBS -lasound", want_alsa=no)
 563 fi
 564 if test x$want_alsa = xyes; then
 565 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 566 fi
 567 dnl
 568 dnl Some headers
 569 dnl
 570
 571 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 572       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 573 AC_CHECK_HEADERS([sys/mount.h], [], [],
 574      [#ifdef HAVE_SYS_PARAM_H
 575       #include <sys/param.h>
 576       #endif
 577       ])
 578
 579 dnl
 580 dnl Some defines
 581 dnl
 582
 583 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 584 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 585 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 586 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 587 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 588
 589 dnl
 590 dnl Some functions
 591 dnl
 592
 593 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 594 AC_SEARCH_LIBS(clock_gettime, [rt],
 595                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 596                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 597
 598 dnl
 599 dnl Structure checks
 600 dnl
 601
 602 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 603                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 604                  [],
 605                  [#include <sys/statfs.h>])
 606
 607 dnl
 608 dnl Check for zlib
 609 dnl
 610
 611 AC_CHECK_HEADER(zlib.h,
 612                 [],
 613                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 614
 615
 616 dnl
 617 dnl Check for OpenMP support
 618 dnl
 619
 620 AX_OPENMP([
 621   gcc_version=`$CC -dumpversion`
 622   gcc_major=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 623   gcc_minor=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 624   dnl check that the gcc version is >=4.3, if we're using gcc
 625   if test ! "x$GCC" = "xyes" -o $gcc_major -ge 4 -a $gcc_minor -ge 3; then
 626     AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 627     CFLAGS="$CFLAGS $OPENMP_CFLAGS"
 628   fi
 629
 630 ])
 631
 632 dnl
 633 dnl Check doc stuff
 634 dnl
 635
 636 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 637 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 638 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 639 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 640   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 641 else
 642   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 643 fi
 644
 645 dnl
 646 dnl kstat in Solaris
 647 dnl
 648
 649 if test x$WANT_KSTAT = xyes; then
 650   dah=no
 651   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 652
 653   if test x$dah = xyes; then
 654     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 655     LDFLAGS="$LDFLAGS -lkstat"
 656   fi
 657 fi
 658
 659 AC_DEFUN([AM_LANGINFO_CODESET],
 660 [
 661   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 662     [AC_TRY_LINK([#include <langinfo.h>],
 663       [char* cs = nl_langinfo(CODESET);],
 664       am_cv_langinfo_codeset=yes,
 665       am_cv_langinfo_codeset=no)
 666     ])
 667   if test $am_cv_langinfo_codeset = yes; then
 668     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 669       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 670   fi
 671 ])
 672
 673
 674 dnl ************************
 675 dnl * Linker optimizations *
 676 dnl ************************
 677 AC_MSG_CHECKING([if $LD accepts -O1])
 678 case `$LD -O1 -v 2>&1 </dev/null` in
 679 *GNU* | *BSD*)
 680   LDFLAGS="$LDFLAGS -Wl,-O1"
 681   AC_MSG_RESULT([yes])
 682   ;;
 683 *)
 684   AC_MSG_RESULT([no])
 685   ;;
 686 esac
 687
 688 dnl Solve multiple definitions (only necessary when gnulib is used)
 689 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 690
 691 dnl
 692 dnl Da.
 693 dnl
 694
 695 CFLAGS="$CFLAGS -Wall -W"
 696
 697 dnl
 698 dnl debug
 699 dnl
 700
 701 AC_ARG_ENABLE([debug],
 702               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 703               [want_debug="$enableval"], [want_debug=no])
 704
 705 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 706   CFLAGS="$CFLAGS -g3"
 707   AC_DEFINE([DEBUG], 1, [Define for debugging])
 708 fi
 709
 710 dnl
 711 dnl testing
 712 dnl
 713
 714 AC_ARG_ENABLE([testing],
 715               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 716               [want_testing="$enableval"], [want_testing=no])
 717
 718 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 719   if test "x$want_debug" = "xyes"; then
 720     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 721     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 722   else
 723     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 724     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 725   fi
 726 fi
 727
 728 AC_SUBST(CFLAGS)
 729 AC_SUBST(X11_LIBS)
 730
 731 AC_OUTPUT
 732
 733 dnl
 734 dnl Print summary
 735 dnl
 736 cat << EOF
 737
 738 $PACKAGE $VERSION configured successfully:
 739
 740  Installing into:   $prefix
 741  System config dir: $sysconfdir
 742  C compiler flags:  $CFLAGS
 743  Linker flags:      $LDFLAGS
 744  Libraries:         $LIBS
 745
 746  * X11:
 747   X11 support:      $want_x11
 748   XDamage support:  $want_xdamage
 749   XDBE support:     $want_double_buffer
 750   Xft support:      $want_xft
 751
 752  * Music detection:
 753   Audacious:        $want_audacious
 754   BMPx:             $want_bmpx
 755   MPD:              $want_mpd
 756   MOC:              $want_moc
 757   XMMS2:            $want_xmms2
 758
 759  * General:
 760   math:             $want_math
 761   hddtemp:          $want_hddtemp
 762   portmon:          $want_portmon
 763   RSS:              $want_rss
 764   wireless:         $want_wlan
 765   IBM:              $want_ibm
 766   nvidia:           $want_nvidia
 767   eve-online:       $want_eve
 768   config-output:    $want_config_output
 769   ALSA mixer:       $want_alsa
 770 EOF