vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [4])
   6 m4_define([conky_version_micro], [6])
   7 m4_define([conky_version_tag], [svn]) dnl [] for releases
   8 m4_define([conky_version_revision],[r@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [svn],
  12       [-conky_version_tag()-conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [-conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19
  20 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  21 dnl libtool must be deleted with make distclean to see this fix.
  22 if test x"$CFLAGS" = x""; then
  23   AC_SUBST(CFLAGS, [ ])
  24 fi
  25
  26 dnl
  27 dnl Tools
  28 dnl
  29 AC_PROG_CC
  30 AC_PROG_LD
  31 AC_PROG_INSTALL
  32 AC_PROG_LIBTOOL
  33
  34 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  35 if test x"$HAVE_PKGCONFIG" = x"no"; then
  36   AC_MSG_ERROR([pkg-config is required!])
  37 fi
  38 PKG_PROG_PKG_CONFIG([0.17.2])
  39
  40 AC_CONFIG_FILES(
  41   Makefile
  42   doc/Makefile
  43   src/Makefile
  44   src/build.h
  45   )
  46
  47 uname=`uname`
  48
  49 case $uname in
  50   Linux*)
  51     WANT_SYSINFO=yes
  52     ;;
  53   FreeBSD*)
  54     WANT_KVM=yes
  55     WANT_DEVSTAT=yes
  56     ;;
  57 #  NetBSD*)
  58 #    WANT_KVM=yes
  59 #    WANT_OSSLIB=yes
  60 #    ;;
  61
  62   OpenBSD*)
  63     WANT_KVM=yes
  64     WANT_OSSLIB=yes
  65     ;;
  66
  67 # Solaris doesn't work at all right now
  68 #  SunOS*)
  69 #    WANT_KSTAT=yes
  70 #    ;;
  71
  72   *)
  73     echo "Your operating system $uname isn't supported"
  74     echo "Feel free to help. :P"
  75     exit 1
  76     ;;
  77 esac
  78
  79 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  80 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  81 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD)
  82 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  83 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  84
  85 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  86 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  87 AC_SUBST(BUILD_DATE)
  88 AC_SUBST(BUILD_ARCH)
  89
  90
  91 dnl
  92 dnl OWN_WINDOW option
  93 dnl
  94
  95 AC_ARG_ENABLE([own_window],
  96               AC_HELP_STRING([--disable-own-window],
  97                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
  98               [dah="$enableval"], [dah=yes])
  99
 100 if test $dah != "no"; then
 101   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 102 fi
 103
 104
 105 dnl
 106 dnl Audacious Media Player
 107 dnl
 108
 109 AC_ARG_ENABLE([audacious],
 110               AC_HELP_STRING([--enable-audacious], [enable audacious player support @<:@default=no@:>@]),
 111               [want_audacious="$enableval"], [want_audacious=no])
 112
 113 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes)
 114 if test x$want_audacious = xyes; then
 115   PKG_CHECK_MODULES([AUDACIOUS], [audacious >= 0.1])
 116       CFLAGS="$CFLAGS $AUDACIOUS_CFLAGS"
 117       LIBS="$LIBS $AUDACIOUS_LIBS"
 118       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 119 fi
 120
 121
 122 dnl
 123 dnl BMPx
 124 dnl
 125
 126 AC_ARG_ENABLE([bmpx],
 127               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 128               [want_bmpx="$enableval"], [want_bmpx=no])
 129
 130 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 131 if test x$want_bmpx = xyes; then
 132   PKG_CHECK_MODULES([BMPX], [bmp-2.0 >= 0.14.0])
 133   CFLAGS="$CFLAGS $BMPX_CFLAGS"
 134   LIBS="$LIBS $BMPX_LIBS"
 135   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 136 fi
 137
 138
 139 dnl
 140 dnl Hddtemp
 141 dnl
 142
 143 AC_ARG_ENABLE([hddtemp],
 144               AC_HELP_STRING([--disable-hddtemp],
 145                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 146               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 147
 148 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 149 if test x$want_hddtemp = xyes; then
 150   AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 151 fi
 152
 153 dnl
 154 dnl MPD
 155 dnl
 156
 157 AC_ARG_ENABLE([mpd],
 158               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 159               [want_mpd="$enableval"], [want_mpd=yes])
 160
 161 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 162 if test x$want_mpd = xyes; then
 163   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 164 fi
 165
 166 dnl
 167 dnl XMMS2
 168 dnl
 169
 170 AC_ARG_ENABLE([xmms2],
 171               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 172               [want_xmms2="$enableval"], [want_xmms2=no])
 173
 174 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 175 if test x$want_xmms2 = xyes; then
 176   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 177     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 178     LIBS="$LIBS $XMMS2_LIBS"
 179     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 180 fi
 181
 182 dnl
 183 dnl RSS
 184 dnl
 185
 186 AC_ARG_ENABLE([rss],
 187               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 188               [want_rss="$enableval"], [want_rss=no])
 189 #
 190 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 191 if test x$want_rss = xyes; then
 192         WANT_GLIB=yes
 193         PKG_CHECK_MODULES(RSS, libxml-2.0 libcurl,,exit)
 194         CFLAGS="$CFLAGS $RSS_CFLAGS"
 195         LIBS="$LIBS $RSS_LIBS"
 196         AC_DEFINE(RSS, 1, [Define if you want rss support])
 197 fi
 198
 199 dnl
 200 dnl IMLIB2
 201 dnl
 202
 203 dnl --commented out until brenden finishes it --
 204 dnl AC_ARG_ENABLE([imlib2],
 205 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 206 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 207 dnl
 208 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 209 dnl if test x$want_imlib2 = xyes; then
 210 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 211 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 212 dnl LIBS="$LIBS $Imlib2_LIBS"
 213 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 214 dnl fi
 215
 216
 217 dnl
 218 dnl PORT_MONITORS
 219 dnl
 220
 221 AC_ARG_ENABLE([portmon],
 222               AC_HELP_STRING([--disable-portmon],
 223                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 224               [want_portmon="$enableval"], [want_portmon=yes])
 225
 226 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x$want_portmon = xyes)
 227 if test x$want_portmon = xyes; then
 228   if test "x$uname" != xLinux; then
 229       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 230       want_portmon=no
 231   else
 232         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 233            [PORT_MONITORS_MISSING=yes])
 234         if test "x$PORT_MONITORS_MISSING" = xyes; then
 235               AC_MSG_ERROR([missing a needed network header for port monitoring])
 236         fi
 237         WANT_GLIB=yes
 238         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 239   fi
 240 fi
 241
 242
 243 dnl
 244 dnl ICONV
 245 dnl
 246
 247 AM_ICONV
 248 if test "$am_cv_func_iconv" != yes; then
 249   AC_MSG_WARN([Could not find libiconv])
 250 else
 251   LIBS="$LIBS $LIBICONV"
 252 fi
 253
 254 dnl
 255 dnl debug
 256 dnl
 257
 258 AC_ARG_ENABLE([debug],
 259               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 260               [want_debug="$enableval"], [want_debug=no])
 261
 262 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 263   CFLAGS="$CFLAGS -g3"
 264   AC_DEFINE([DEBUG], [], [Define for debugging])
 265 fi
 266
 267 dnl
 268 dnl X11
 269 dnl
 270
 271 AC_ARG_ENABLE([x11],
 272               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 273               [want_x11="$enableval"], [want_x11=yes])
 274
 275 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 276 if test "x$want_x11" = "xyes"; then
 277     if $PKG_CONFIG --exists x11; then
 278       PKG_CHECK_MODULES([X11], [x11])
 279       CFLAGS="$CFLAGS $X11_CFLAGS"
 280       LIBS="$LIBS $X11_LIBS"
 281     else
 282       dnl non-modular X11 installations
 283       AC_PATH_X
 284       AC_PATH_XTRA
 285       CFLAGS="$CFLAGS $X_CFLAGS"
 286       LIBS="$LIBS $X_LIBS"
 287       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 288       if test "x$no_x" = "xyes"; then
 289         AC_MSG_ERROR([Can't locate your X11 installation])
 290       fi
 291       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 292     fi
 293     AC_DEFINE(X11, 1, [Define if you want to use X11])
 294 fi
 295
 296
 297 dnl
 298 dnl Xext Double-buffering Extension
 299 dnl
 300
 301 AC_ARG_ENABLE([double_buffer],
 302               AC_HELP_STRING([--disable-double-buffer],
 303                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 304               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 305
 306 if test "x$want_double_buffer" = "xyes"; then
 307     if test "x$want_x11" != "xyes"; then
 308       dnl silently disable if no x11
 309       want_double_buffer=no
 310     else
 311       if $PKG_CONFIG --exists xext; then
 312         PKG_CHECK_MODULES([XEXT],[xext])
 313         CFLAGS="$CFLAGS $XEXT_CFLAGS"
 314         LIBS="$LIBS $XEXT_LIBS"
 315       else
 316         dnl non-modular X11 installation
 317         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 318                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 319       fi
 320       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 321     fi
 322 fi
 323
 324
 325 dnl
 326 dnl Xdamage Extension
 327 dnl
 328
 329 AC_ARG_ENABLE([xdamage],
 330               AC_HELP_STRING([--disable-xdamage],
 331                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 332               [want_xdamage="$enableval"], [want_xdamage=yes])
 333
 334 if test "x$want_xdamage" = "xyes"; then
 335     if test "x$want_x11" != "xyes"; then
 336       dnl silently disable if no x11
 337       want_xdamage=no
 338     else
 339       if $PKG_CONFIG --exists xdamage; then
 340         PKG_CHECK_MODULES([XDAMAGE],[xdamage])
 341         CFLAGS="$CFLAGS $XDAMAGE_CFLAGS"
 342         LIBS="$LIBS $XDAMAGE_LIBS"
 343       else
 344         dnl non-modular X11 installation
 345         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 346                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 347       fi
 348       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 349     fi
 350 fi
 351
 352
 353 dnl
 354 dnl Xft
 355 dnl
 356
 357 AC_ARG_ENABLE([xft],
 358               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 359               [want_xft="$enableval"], [want_xft=yes])
 360
 361 if test x$want_xft = "xyes"; then
 362     if test "x$want_x11" != "xyes"; then
 363       dnl silently disable if no x11
 364       want_xft=no
 365     else
 366       PKG_CHECK_MODULES(XFT, [xft])
 367       CFLAGS="$CFLAGS $XFT_CFLAGS"
 368       LIBS="$LIBS $XFT_LIBS"
 369       AC_DEFINE(XFT, 1, [Define for Xft support])
 370     fi
 371 fi
 372
 373 dnl
 374 dnl GLIB
 375 dnl
 376
 377 if test x$WANT_GLIB = xyes; then
 378         PKG_CHECK_MODULES([GLIB], [glib-2.0])
 379         CFLAGS="$CFLAGS $GLIB_CFLAGS"
 380         LIBS="$LIBS $GLIB_LIBS"
 381 fi
 382
 383 dnl
 384 dnl KVM
 385 dnl
 386
 387 if test x$WANT_KVM = xyes; then
 388   AC_CHECK_LIB(kvm, kvm_open,
 389     LIBS="$LIBS -lkvm",
 390   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 391   )
 392 fi
 393
 394 dnl
 395 dnl devstat
 396 dnl
 397
 398 if test x$WANT_DEVSTAT = xyes; then
 399   AC_CHECK_LIB(devstat, devstat_getversion,
 400          LIBS="$LIBS -ldevstat",
 401          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 402   )
 403 fi
 404
 405 dnl
 406 dnl OSSLIB for NetBSD/OpenBSD
 407 dnl
 408
 409 if test x$WANT_OSSLIB = xyes; then
 410     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 411   LIBS="$LIBS -lossaudio",
 412   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 413     )
 414 fi
 415
 416 dnl
 417 dnl Some headers
 418 dnl
 419
 420 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 421       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 422 AC_CHECK_HEADERS([sys/mount.h], [], [],
 423      [#ifdef HAVE_SYS_PARAM_H
 424       #include <sys/param.h>
 425       #endif
 426       ])
 427
 428 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
 429
 430 dnl
 431 dnl Some functions
 432 dnl
 433
 434 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr])
 435 AC_SEARCH_LIBS(clock_gettime, [rt],
 436                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 437                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 438
 439
 440 dnl
 441 dnl Check for zlib
 442 dnl
 443
 444 AC_CHECK_HEADER(zlib.h,
 445                 [],
 446                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 447
 448
 449 dnl
 450 dnl Check doc stuff
 451 dnl
 452
 453 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 454 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 455 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 456 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 457   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 458 else
 459   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 460 fi
 461
 462
 463 dnl
 464 dnl kstat in Solaris
 465 dnl
 466
 467 if test x$WANT_KSTAT = xyes; then
 468   dah=no
 469   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 470
 471   if test x$dah = xyes; then
 472     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 473     LDFLAGS="$LDFLAGS -lkstat"
 474   fi
 475 fi
 476
 477 AC_DEFUN([AM_LANGINFO_CODESET],
 478 [
 479   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 480     [AC_TRY_LINK([#include <langinfo.h>],
 481       [char* cs = nl_langinfo(CODESET);],
 482       am_cv_langinfo_codeset=yes,
 483       am_cv_langinfo_codeset=no)
 484     ])
 485   if test $am_cv_langinfo_codeset = yes; then
 486     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 487       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 488   fi
 489 ])
 490
 491
 492 dnl ************************
 493 dnl * Linker optimizations *
 494 dnl ************************
 495 AC_MSG_CHECKING([if $LD accepts -O1])
 496 case `$LD -O1 -v 2>&1 </dev/null` in
 497 *GNU* | *BSD*)
 498   LDFLAGS="$LDFLAGS -Wl,-O1"
 499   AC_MSG_RESULT([yes])
 500   ;;
 501 *)
 502   AC_MSG_RESULT([no])
 503   ;;
 504 esac
 505
 506
 507 dnl
 508 dnl Da.
 509 dnl
 510
 511 CFLAGS="$CFLAGS -Wall -W"
 512
 513 AC_SUBST(CFLAGS)
 514 AC_SUBST(X11_LIBS)
 515
 516 AC_OUTPUT
 517
 518 dnl
 519 dnl Print summary
 520 dnl
 521 cat << EOF
 522
 523 $PACKAGE $VERSION configured successfully:
 524
 525  Installing into:   $prefix
 526  C compiler flags:  $CFLAGS
 527  Linker flags:      $LDFLAGS
 528  Libraries:         $LIBS
 529
 530  * x11:
 531   x11 support:      $want_x11
 532   xdamage support:  $want_xdamage
 533   xdbe support:     $want_double_buffer
 534   xft support:      $want_xft
 535
 536  * music detection:
 537   audacious:        $want_audacious
 538   bmpx:             $want_bmpx
 539   mpd:              $want_mpd
 540   xmms2:            $want_xmms2
 541
 542  * general:
 543   hddtemp:          $want_hddtemp
 544   portmon:          $want_portmon
 545   RSS:              $want_rss
 546 EOF