vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [1])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58     ;;
  59 #  NetBSD*)
  60 #    WANT_KVM=yes
  61 #    WANT_OSSLIB=yes
  62 #    ;;
  63
  64   OpenBSD*)
  65     WANT_KVM=yes
  66     WANT_OSSLIB=yes
  67     ;;
  68
  69 # Solaris doesn't work at all right now
  70 #  SunOS*)
  71 #    WANT_KSTAT=yes
  72 #    ;;
  73
  74   *)
  75     echo "Your operating system $uname isn't supported"
  76     echo "Feel free to help. :P"
  77     exit 1
  78     ;;
  79 esac
  80
  81 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  82 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  83 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  84 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  85 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  86
  87 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  88 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  89 AC_SUBST(BUILD_DATE)
  90 AC_SUBST(BUILD_ARCH)
  91
  92
  93 dnl
  94 dnl BUILD_CONFIG_OUTPUT option
  95 dnl
  96
  97 AC_ARG_ENABLE([config_output],
  98               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) @<:@default=yes@:>@]),
  99               [want_config_output="$enableval"], [want_config_output=yes])
 100
 101 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 102 if test x$want_config_output = xyes; then
 103   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 104   AC_CHECK_FUNCS(fopencookie, AM_CONDITIONAL(BUILD_FOR_FOPENCOOKIE, true))
 105 fi
 106
 107 dnl
 108 dnl OWN_WINDOW option
 109 dnl
 110
 111 AC_ARG_ENABLE([own_window],
 112               AC_HELP_STRING([--disable-own-window],
 113                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 114               [dah="$enableval"], [dah=yes])
 115
 116 if test $dah != "no"; then
 117   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 118 fi
 119
 120
 121 dnl
 122 dnl Audacious Media Player
 123 dnl
 124
 125 AC_ARG_ENABLE([audacious],
 126               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 127                              [enable audacious player support @<:@default=no@:>@]),
 128               [want_audacious="$enableval"], [want_audacious=no])
 129
 130 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 131 if test x$want_audacious = xyes; then
 132       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 133       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 134       LIBS="$LIBS $Audacious_LIBS"
 135       save_CPPFLAGS="$CPPFLAGS"
 136       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 137       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 138                        [], AC_MSG_ERROR([required header(s) not found]))
 139       CPPFLAGS="$save_CPPFLAGS"
 140       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 141 else if test x$want_audacious = xlegacy; then
 142       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 143       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 144       LIBS="$LIBS $Audacious_LIBS"
 145       save_CPPFLAGS="$CPPFLAGS"
 146       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 147       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 148       CPPFLAGS="$save_CPPFLAGS"
 149       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 150       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 151       fi
 152 fi
 153
 154
 155 dnl
 156 dnl BMPx
 157 dnl
 158
 159 AC_ARG_ENABLE([bmpx],
 160               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 161               [want_bmpx="$enableval"], [want_bmpx=no])
 162
 163 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 164 if test x$want_bmpx = xyes; then
 165   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 166   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 167   LIBS="$LIBS $BMPx_LIBS"
 168   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 169 fi
 170
 171
 172 dnl
 173 dnl Support for IBM/Lenovo notebooks
 174 dnl
 175
 176 AC_ARG_ENABLE([ibm],
 177               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 178               [want_ibm="$enableval"], [want_ibm=no])
 179
 180 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 181 if test x$want_ibm = xyes; then
 182         if test x"$uname" != xLinux; then
 183                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 184                 want_ibm=no
 185         else
 186                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks])
 187         fi
 188 fi
 189
 190
 191 dnl
 192 dnl Hddtemp
 193 dnl
 194
 195 AC_ARG_ENABLE([hddtemp],
 196               AC_HELP_STRING([--disable-hddtemp],
 197                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 198               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 199
 200 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 201 if test x$want_hddtemp = xyes; then
 202   if test x"$uname" != xLinux; then
 203       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 204       want_hddtemp=no
 205   else
 206       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 207   fi
 208 fi
 209
 210 dnl
 211 dnl Math
 212 dnl
 213
 214 AC_ARG_ENABLE([math],
 215               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 216               [want_math="$enableval"], [want_math=yes])
 217
 218 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 219 if test x$want_math = xyes; then
 220   LIBS="$LIBS -lm"
 221   AC_DEFINE(MATH, 1, [Define if you want math support])
 222 fi
 223
 224 dnl
 225 dnl MPD
 226 dnl
 227
 228 AC_ARG_ENABLE([mpd],
 229               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 230               [want_mpd="$enableval"], [want_mpd=yes])
 231
 232 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 233 if test x$want_mpd = xyes; then
 234   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 235 fi
 236
 237 dnl
 238 dnl MOC
 239 dnl
 240
 241 AC_ARG_ENABLE([moc],
 242               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 243               [want_moc="$enableval"], [want_moc=yes])
 244
 245 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 246 if test x$want_moc = xyes; then
 247   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 248 fi
 249
 250 dnl
 251 dnl XMMS2
 252 dnl
 253
 254 AC_ARG_ENABLE([xmms2],
 255               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 256               [want_xmms2="$enableval"], [want_xmms2=no])
 257
 258 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 259 if test x$want_xmms2 = xyes; then
 260   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 261     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 262     LIBS="$LIBS $XMMS2_LIBS"
 263     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 264 fi
 265
 266 dnl
 267 dnl EVE Skill Monitor
 268 dnl
 269
 270 AC_ARG_ENABLE([eve],
 271               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 272               [want_eve="$enableval"], [want_eve=no])
 273
 274 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 275 if test x$want_eve = xyes; then
 276         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 277         PKG_CHECK_MODULES([libcurl], libcurl)
 278         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 279         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 280         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 281         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 282         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 283         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 284         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 285 fi
 286
 287 dnl
 288 dnl RSS
 289 dnl
 290
 291 AC_ARG_ENABLE([rss],
 292               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 293               [want_rss="$enableval"], [want_rss=no])
 294 #
 295 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 296 if test x$want_rss = xyes; then
 297         WANT_GLIB=yes
 298         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 299         PKG_CHECK_MODULES([libcurl], libcurl)
 300         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 301         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 302         AC_DEFINE(RSS, 1, [Define if you want rss support])
 303 fi
 304
 305 dnl
 306 dnl Wireless extensions
 307 dnl
 308
 309 AC_ARG_ENABLE([wlan],
 310               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 311               [want_wlan="$enableval"], [want_wlan=no])
 312
 313 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 314 if test x$want_wlan = xyes; then
 315   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 316   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 317         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 318 fi
 319
 320 dnl
 321 dnl IMLIB2
 322 dnl
 323
 324 dnl --commented out until brenden finishes it --
 325 dnl AC_ARG_ENABLE([imlib2],
 326 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 327 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 328 dnl
 329 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 330 dnl if test x$want_imlib2 = xyes; then
 331 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 332 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 333 dnl LIBS="$LIBS $Imlib2_LIBS"
 334 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 335 dnl fi
 336
 337
 338 dnl
 339 dnl PORT_MONITORS
 340 dnl
 341
 342 AC_ARG_ENABLE([portmon],
 343               AC_HELP_STRING([--disable-portmon],
 344                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 345               [want_portmon="$enableval"], [want_portmon=yes])
 346
 347 if test x"$want_portmon" = xyes; then
 348   if test x"$uname" != xLinux; then
 349       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 350       want_portmon=no
 351   else
 352         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 353         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 354            [PORT_MONITORS_MISSING=yes])
 355         if test x"$PORT_MONITORS_MISSING" = xyes; then
 356               AC_MSG_ERROR([missing a needed network header for port monitoring])
 357         fi
 358         WANT_GLIB=yes
 359         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 360   fi
 361 fi
 362 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 363
 364
 365 dnl
 366 dnl ICONV
 367 dnl
 368
 369 AM_ICONV
 370 if test "$am_cv_func_iconv" != yes; then
 371   AC_MSG_WARN([Could not find libiconv])
 372 else
 373   LIBS="$LIBS $LIBICONV"
 374 fi
 375
 376 dnl
 377 dnl X11
 378 dnl
 379
 380 AC_ARG_ENABLE([x11],
 381               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 382               [want_x11="$enableval"], [want_x11=yes])
 383
 384 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 385 if test "x$want_x11" = "xyes"; then
 386     if $PKG_CONFIG --exists x11; then
 387       PKG_CHECK_MODULES([X11], [x11])
 388       CFLAGS="$CFLAGS $X11_CFLAGS"
 389       LIBS="$LIBS $X11_LIBS"
 390     else
 391       dnl non-modular X11 installations
 392       AC_PATH_X
 393       AC_PATH_XTRA
 394       CFLAGS="$CFLAGS $X_CFLAGS"
 395       LIBS="$LIBS $X_LIBS"
 396       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 397       if test "x$no_x" = "xyes"; then
 398         AC_MSG_ERROR([Can't locate your X11 installation])
 399       fi
 400       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 401     fi
 402     AC_DEFINE(X11, 1, [Define if you want to use X11])
 403 fi
 404
 405
 406 dnl
 407 dnl Xext Double-buffering Extension
 408 dnl
 409
 410 AC_ARG_ENABLE([double_buffer],
 411               AC_HELP_STRING([--disable-double-buffer],
 412                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 413               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 414
 415 if test "x$want_double_buffer" = "xyes"; then
 416     if test "x$want_x11" != "xyes"; then
 417       dnl silently disable if no x11
 418       want_double_buffer=no
 419     else
 420       if $PKG_CONFIG --exists xext; then
 421         PKG_CHECK_MODULES([Xext],[xext])
 422         CFLAGS="$CFLAGS $Xext_CFLAGS"
 423         LIBS="$LIBS $Xext_LIBS"
 424       else
 425         dnl non-modular X11 installation
 426         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 427                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 428       fi
 429       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 430     fi
 431 fi
 432
 433
 434 dnl
 435 dnl Xdamage Extension
 436 dnl
 437
 438 AC_ARG_ENABLE([xdamage],
 439               AC_HELP_STRING([--disable-xdamage],
 440                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 441               [want_xdamage="$enableval"], [want_xdamage=yes])
 442
 443 if test "x$want_xdamage" = "xyes"; then
 444     if test "x$want_x11" != "xyes"; then
 445       dnl silently disable if no x11
 446       want_xdamage=no
 447     else
 448       if $PKG_CONFIG --exists xdamage; then
 449         PKG_CHECK_MODULES([XDamage],[xdamage])
 450         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 451         LIBS="$LIBS $XDamage_LIBS"
 452       else
 453         dnl non-modular X11 installation
 454         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 455                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 456       fi
 457       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 458     fi
 459 fi
 460
 461
 462 dnl
 463 dnl Xft
 464 dnl
 465
 466 AC_ARG_ENABLE([xft],
 467               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 468               [want_xft="$enableval"], [want_xft=yes])
 469
 470 if test x$want_xft = "xyes"; then
 471     if test "x$want_x11" != "xyes"; then
 472       dnl silently disable if no x11
 473       want_xft=no
 474     else
 475       PKG_CHECK_MODULES([Xft], [xft])
 476       CFLAGS="$CFLAGS $Xft_CFLAGS"
 477       LIBS="$LIBS $Xft_LIBS"
 478       AC_DEFINE(XFT, 1, [Define for Xft support])
 479     fi
 480 fi
 481
 482 dnl
 483 dnl NVIDIA libXNVCtrl support
 484 dnl
 485
 486 AC_ARG_ENABLE([nvidia],
 487                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 488                 [want_nvidia="$enableval"], [want_nvidia=no])
 489 if test x$want_nvidia = xyes; then
 490     if test "x$want_x11" != "xyes"; then
 491                 # do nada
 492                 want_nvidia=no
 493         else
 494                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 495 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 496 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 497 dnl ## am I Stupid ??
 498 dnl ## it won't find the lib for some reason!?
 499                 LIBS="$LIBS -lXNVCtrl"
 500                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 501         fi
 502 fi
 503 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 504
 505 dnl
 506 dnl GLIB
 507 dnl
 508
 509 if test x$WANT_GLIB = xyes; then
 510         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 511         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 512         LIBS="$LIBS $GLib2_LIBS"
 513 fi
 514
 515 dnl
 516 dnl KVM
 517 dnl
 518
 519 if test x$WANT_KVM = xyes; then
 520   AC_CHECK_LIB(kvm, kvm_open,
 521     LIBS="$LIBS -lkvm",
 522   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 523   )
 524 fi
 525
 526 dnl
 527 dnl devstat
 528 dnl
 529
 530 if test x$WANT_DEVSTAT = xyes; then
 531   AC_CHECK_LIB(devstat, devstat_getversion,
 532          LIBS="$LIBS -ldevstat",
 533          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 534   )
 535 fi
 536
 537 dnl
 538 dnl OSSLIB for NetBSD/OpenBSD
 539 dnl
 540
 541 if test x$WANT_OSSLIB = xyes; then
 542     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 543   LIBS="$LIBS -lossaudio",
 544   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 545     )
 546 fi
 547
 548 dnl
 549 dnl Some headers
 550 dnl
 551
 552 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 553       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 554 AC_CHECK_HEADERS([sys/mount.h], [], [],
 555      [#ifdef HAVE_SYS_PARAM_H
 556       #include <sys/param.h>
 557       #endif
 558       ])
 559
 560 dnl
 561 dnl Some defines
 562 dnl
 563
 564 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 565 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 566 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 567 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 568 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 569
 570 dnl
 571 dnl Some functions
 572 dnl
 573
 574 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 575 AC_SEARCH_LIBS(clock_gettime, [rt],
 576                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 577                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 578
 579 dnl
 580 dnl Structure checks
 581 dnl
 582
 583 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 584                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 585                  [],
 586                  [#include <sys/statfs.h>])
 587
 588 dnl
 589 dnl Check for zlib
 590 dnl
 591
 592 AC_CHECK_HEADER(zlib.h,
 593                 [],
 594                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 595
 596
 597 dnl
 598 dnl Check doc stuff
 599 dnl
 600
 601 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 602 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 603 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 604 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 605   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 606 else
 607   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 608 fi
 609
 610
 611 dnl
 612 dnl kstat in Solaris
 613 dnl
 614
 615 if test x$WANT_KSTAT = xyes; then
 616   dah=no
 617   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 618
 619   if test x$dah = xyes; then
 620     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 621     LDFLAGS="$LDFLAGS -lkstat"
 622   fi
 623 fi
 624
 625 AC_DEFUN([AM_LANGINFO_CODESET],
 626 [
 627   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 628     [AC_TRY_LINK([#include <langinfo.h>],
 629       [char* cs = nl_langinfo(CODESET);],
 630       am_cv_langinfo_codeset=yes,
 631       am_cv_langinfo_codeset=no)
 632     ])
 633   if test $am_cv_langinfo_codeset = yes; then
 634     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 635       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 636   fi
 637 ])
 638
 639
 640 dnl ************************
 641 dnl * Linker optimizations *
 642 dnl ************************
 643 AC_MSG_CHECKING([if $LD accepts -O1])
 644 case `$LD -O1 -v 2>&1 </dev/null` in
 645 *GNU* | *BSD*)
 646   LDFLAGS="$LDFLAGS -Wl,-O1"
 647   AC_MSG_RESULT([yes])
 648   ;;
 649 *)
 650   AC_MSG_RESULT([no])
 651   ;;
 652 esac
 653
 654 dnl Solve multiple definitions (only necessary when gnulib is used)
 655 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 656
 657 dnl
 658 dnl Da.
 659 dnl
 660
 661 CFLAGS="$CFLAGS -Wall -W"
 662
 663 dnl
 664 dnl debug
 665 dnl
 666
 667 AC_ARG_ENABLE([debug],
 668               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 669               [want_debug="$enableval"], [want_debug=no])
 670
 671 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 672   CFLAGS="$CFLAGS -g3"
 673   AC_DEFINE([DEBUG], 1, [Define for debugging])
 674 fi
 675
 676 dnl
 677 dnl testing
 678 dnl
 679
 680 AC_ARG_ENABLE([testing],
 681               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 682               [want_testing="$enableval"], [want_testing=no])
 683
 684 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 685   if test "x$want_debug" = "xyes"; then
 686     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 687     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 688   else
 689     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 690     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 691   fi
 692 fi
 693
 694 AC_SUBST(CFLAGS)
 695 AC_SUBST(X11_LIBS)
 696
 697 AC_OUTPUT
 698
 699 dnl
 700 dnl Print summary
 701 dnl
 702 cat << EOF
 703
 704 $PACKAGE $VERSION configured successfully:
 705
 706  Installing into:   $prefix
 707  System config dir: $sysconfdir
 708  C compiler flags:  $CFLAGS
 709  Linker flags:      $LDFLAGS
 710  Libraries:         $LIBS
 711
 712  * X11:
 713   X11 support:      $want_x11
 714   XDamage support:  $want_xdamage
 715   XDBE support:     $want_double_buffer
 716   Xft support:      $want_xft
 717
 718  * Music detection:
 719   Audacious:        $want_audacious
 720   BMPx:             $want_bmpx
 721   MPD:              $want_mpd
 722   MOC:              $want_moc
 723   XMMS2:            $want_xmms2
 724
 725  * General:
 726   math:             $want_math
 727   hddtemp:          $want_hddtemp
 728   portmon:          $want_portmon
 729   RSS:              $want_rss
 730   wireless:         $want_wlan
 731   IBM:              $want_ibm
 732   nvidia:           $want_nvidia
 733   eve-online:       $want_eve
 734   config-output:    $want_config_output
 735 EOF