vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [2])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58     ;;
  59 #  NetBSD*)
  60 #    WANT_KVM=yes
  61 #    WANT_OSSLIB=yes
  62 #    ;;
  63
  64   OpenBSD*)
  65     WANT_KVM=yes
  66     WANT_OSSLIB=yes
  67     ;;
  68
  69 # Solaris doesn't work at all right now
  70 #  SunOS*)
  71 #    WANT_KSTAT=yes
  72 #    ;;
  73
  74   *)
  75     echo "Your operating system $uname isn't supported"
  76     echo "Feel free to help. :P"
  77     exit 1
  78     ;;
  79 esac
  80
  81 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  82 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  83 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  84 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  85 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  86
  87 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  88 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  89 AC_SUBST(BUILD_DATE)
  90 AC_SUBST(BUILD_ARCH)
  91
  92
  93 dnl
  94 dnl BUILD_CONFIG_OUTPUT option
  95 dnl
  96
  97 AC_ARG_ENABLE([config_output],
  98               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) @<:@default=yes@:>@]),
  99               [want_config_output="$enableval"], [want_config_output=yes])
 100
 101 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 102 AM_CONDITIONAL(BUILD_FOR_FOPENCOOKIE, test x$want_config_output = xyes)
 103 if test x$want_config_output = xyes; then
 104   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 105   AC_CHECK_FUNCS(fopencookie)
 106 fi
 107
 108 dnl
 109 dnl OWN_WINDOW option
 110 dnl
 111
 112 AC_ARG_ENABLE([own_window],
 113               AC_HELP_STRING([--disable-own-window],
 114                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 115               [dah="$enableval"], [dah=yes])
 116
 117 if test $dah != "no"; then
 118   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 119 fi
 120
 121
 122 dnl
 123 dnl Audacious Media Player
 124 dnl
 125
 126 AC_ARG_ENABLE([audacious],
 127               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 128                              [enable audacious player support @<:@default=no@:>@]),
 129               [want_audacious="$enableval"], [want_audacious=no])
 130
 131 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 132 if test x$want_audacious = xyes; then
 133       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 134       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 135       LIBS="$LIBS $Audacious_LIBS"
 136       save_CPPFLAGS="$CPPFLAGS"
 137       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 138       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 139                        [], AC_MSG_ERROR([required header(s) not found]))
 140       CPPFLAGS="$save_CPPFLAGS"
 141       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 142 else if test x$want_audacious = xlegacy; then
 143       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 144       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 145       LIBS="$LIBS $Audacious_LIBS"
 146       save_CPPFLAGS="$CPPFLAGS"
 147       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 148       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 149       CPPFLAGS="$save_CPPFLAGS"
 150       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 151       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 152       fi
 153 fi
 154
 155
 156 dnl
 157 dnl BMPx
 158 dnl
 159
 160 AC_ARG_ENABLE([bmpx],
 161               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 162               [want_bmpx="$enableval"], [want_bmpx=no])
 163
 164 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 165 if test x$want_bmpx = xyes; then
 166   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 167   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 168   LIBS="$LIBS $BMPx_LIBS"
 169   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 170 fi
 171
 172
 173 dnl
 174 dnl Support for IBM/Lenovo notebooks
 175 dnl
 176
 177 AC_ARG_ENABLE([ibm],
 178               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 179               [want_ibm="$enableval"], [want_ibm=no])
 180
 181 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 182 if test x$want_ibm = xyes; then
 183         if test x"$uname" != xLinux; then
 184                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 185                 want_ibm=no
 186         else
 187                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 188         fi
 189 fi
 190
 191
 192 dnl
 193 dnl Hddtemp
 194 dnl
 195
 196 AC_ARG_ENABLE([hddtemp],
 197               AC_HELP_STRING([--disable-hddtemp],
 198                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 199               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 200
 201 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 202 if test x$want_hddtemp = xyes; then
 203   if test x"$uname" != xLinux; then
 204       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 205       want_hddtemp=no
 206   else
 207       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 208   fi
 209 fi
 210
 211
 212 dnl
 213 dnl Apcupsd
 214 dnl
 215
 216 AC_ARG_ENABLE([apcupsd],
 217               AC_HELP_STRING([--disable-apcupsd],
 218                              [disable if you do not want apcupsd support @<:@default=yes@:>@]),
 219               [want_apcupsd="$enableval"], [want_apcupsd=yes])
 220
 221 if test x$want_apcupsd = xyes; then
 222   if test x"$uname" != xLinux; then
 223       AC_MSG_NOTICE([apcupsd not supported on $uname... disabling])
 224       want_apcupsd=no
 225   else
 226       AC_DEFINE(APCUPSD, 1, [Define if you want apcupsd support])
 227   fi
 228 fi
 229 AM_CONDITIONAL(BUILD_APCUPSD, test x$want_apcupsd = xyes)
 230
 231
 232 dnl
 233 dnl I/O stats
 234 dnl
 235
 236 AC_ARG_ENABLE([iostats],
 237               AC_HELP_STRING([--enable-iostats],
 238                              [enable if you want support for per-task I/O statistics @<:@default=no@:>@]),
 239               [want_iostats="$enableval"], [want_iostats=no])
 240
 241 if test x$want_iostats = xyes; then
 242   if test x"$uname" != xLinux; then
 243       AC_MSG_NOTICE([iostats not supported on $uname... disabling])
 244       want_apcupsd=no
 245   else
 246       AC_DEFINE(IOSTATS, 1, [Define if you want support for per-task I/O statistics])
 247   fi
 248 fi
 249
 250
 251 dnl
 252 dnl Math
 253 dnl
 254
 255 AC_ARG_ENABLE([math],
 256               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 257               [want_math="$enableval"], [want_math=yes])
 258
 259 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 260 if test x$want_math = xyes; then
 261   LIBS="$LIBS -lm"
 262   AC_DEFINE(MATH, 1, [Define if you want math support])
 263 fi
 264
 265 dnl
 266 dnl MPD
 267 dnl
 268
 269 AC_ARG_ENABLE([mpd],
 270               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 271               [want_mpd="$enableval"], [want_mpd=yes])
 272
 273 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 274 if test x$want_mpd = xyes; then
 275   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 276 fi
 277
 278 dnl
 279 dnl MOC
 280 dnl
 281
 282 AC_ARG_ENABLE([moc],
 283               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 284               [want_moc="$enableval"], [want_moc=yes])
 285
 286 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 287 if test x$want_moc = xyes; then
 288   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 289 fi
 290
 291 dnl
 292 dnl XMMS2
 293 dnl
 294
 295 AC_ARG_ENABLE([xmms2],
 296               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 297               [want_xmms2="$enableval"], [want_xmms2=no])
 298
 299 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 300 if test x$want_xmms2 = xyes; then
 301   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 302     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 303     LIBS="$LIBS $XMMS2_LIBS"
 304     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 305 fi
 306
 307 dnl
 308 dnl EVE Skill Monitor
 309 dnl
 310
 311 AC_ARG_ENABLE([eve],
 312               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 313               [want_eve="$enableval"], [want_eve=no])
 314
 315 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 316 if test x$want_eve = xyes; then
 317         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 318         PKG_CHECK_MODULES([libcurl], libcurl)
 319         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 320         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 321         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 322         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 323         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 324         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 325         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 326 fi
 327
 328 dnl
 329 dnl RSS
 330 dnl
 331
 332 AC_ARG_ENABLE([rss],
 333               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 334               [want_rss="$enableval"], [want_rss=no])
 335 #
 336 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 337 if test x$want_rss = xyes; then
 338         WANT_GLIB=yes
 339         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 340         PKG_CHECK_MODULES([libcurl], libcurl)
 341         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 342         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 343         AC_DEFINE(RSS, 1, [Define if you want rss support])
 344 fi
 345
 346 dnl
 347 dnl Lua
 348 dnl
 349
 350 AC_ARG_ENABLE([lua],
 351               AC_HELP_STRING([--enable-lua], [enable if you want Lua scripting support @<:@default=yes@:>@]),
 352               [want_lua="$enableval"], [want_lua=yes])
 353 #
 354 AM_CONDITIONAL(BUILD_LUA, test x$want_lua = xyes)
 355 if test x$want_lua = xyes; then
 356         PKG_CHECK_MODULES(LUA, lua >= 5.1, [ ],[
 357                 PKG_CHECK_MODULES(LUA51, lua-5.1 >= 5.1, [ ],[
 358                         PKG_CHECK_MODULES(LUA51, lua5.1 >= 5.1)
 359                 ])
 360         ])
 361         CFLAGS="$CFLAGS $LUA_CFLAGS $LUA51_CFLAGS"
 362         LIBS="$LIBS $LUA_LIBS $LUA51_LIBS"
 363         AC_DEFINE(HAVE_LUA, 1, [Define if you want Lua scripting support])
 364 fi
 365
 366 dnl
 367 dnl Wireless extensions
 368 dnl
 369
 370 AC_ARG_ENABLE([wlan],
 371               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 372               [want_wlan="$enableval"], [want_wlan=no])
 373
 374 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 375 if test x$want_wlan = xyes; then
 376   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 377   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 378         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 379 fi
 380
 381 dnl
 382 dnl PORT_MONITORS
 383 dnl
 384
 385 AC_ARG_ENABLE([portmon],
 386               AC_HELP_STRING([--disable-portmon],
 387                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 388               [want_portmon="$enableval"], [want_portmon=yes])
 389
 390 if test x"$want_portmon" = xyes; then
 391   if test x"$uname" != xLinux; then
 392       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 393       want_portmon=no
 394   else
 395         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 396         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 397            [PORT_MONITORS_MISSING=yes])
 398         if test x"$PORT_MONITORS_MISSING" = xyes; then
 399               AC_MSG_ERROR([missing a needed network header for port monitoring])
 400         fi
 401         WANT_GLIB=yes
 402         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 403   fi
 404 fi
 405 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 406
 407
 408 dnl
 409 dnl ICONV
 410 dnl
 411
 412 AM_ICONV
 413 if test "$am_cv_func_iconv" != yes; then
 414   AC_MSG_WARN([Could not find libiconv])
 415 else
 416   LIBS="$LIBS $LIBICONV"
 417 fi
 418
 419 dnl
 420 dnl X11
 421 dnl
 422
 423 AC_ARG_ENABLE([x11],
 424               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 425               [want_x11="$enableval"], [want_x11=yes])
 426
 427 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 428 if test "x$want_x11" = "xyes"; then
 429     if $PKG_CONFIG --exists x11; then
 430       PKG_CHECK_MODULES([X11], [x11])
 431       CFLAGS="$CFLAGS $X11_CFLAGS"
 432       LIBS="$LIBS $X11_LIBS"
 433     else
 434       dnl non-modular X11 installations
 435       AC_PATH_X
 436       AC_PATH_XTRA
 437       CFLAGS="$CFLAGS $X_CFLAGS"
 438       LIBS="$LIBS $X_LIBS"
 439       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 440       if test "x$no_x" = "xyes"; then
 441         AC_MSG_ERROR([Can't locate your X11 installation])
 442       fi
 443       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 444     fi
 445     AC_DEFINE(X11, 1, [Define if you want to use X11])
 446 fi
 447
 448
 449 dnl
 450 dnl Xext Double-buffering Extension
 451 dnl
 452
 453 AC_ARG_ENABLE([double_buffer],
 454               AC_HELP_STRING([--disable-double-buffer],
 455                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 456               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 457
 458 if test "x$want_double_buffer" = "xyes"; then
 459     if test "x$want_x11" != "xyes"; then
 460       dnl silently disable if no x11
 461       want_double_buffer=no
 462     else
 463       if $PKG_CONFIG --exists xext; then
 464         PKG_CHECK_MODULES([Xext],[xext])
 465         CFLAGS="$CFLAGS $Xext_CFLAGS"
 466         LIBS="$LIBS $Xext_LIBS"
 467       else
 468         dnl non-modular X11 installation
 469         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 470                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 471       fi
 472       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 473     fi
 474 fi
 475
 476
 477 dnl
 478 dnl Xdamage Extension
 479 dnl
 480
 481 AC_ARG_ENABLE([xdamage],
 482               AC_HELP_STRING([--disable-xdamage],
 483                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 484               [want_xdamage="$enableval"], [want_xdamage=yes])
 485
 486 if test "x$want_xdamage" = "xyes"; then
 487     if test "x$want_x11" != "xyes"; then
 488       dnl silently disable if no x11
 489       want_xdamage=no
 490     else
 491       if $PKG_CONFIG --exists xdamage; then
 492         PKG_CHECK_MODULES([XDamage],[xdamage])
 493         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 494         LIBS="$LIBS $XDamage_LIBS"
 495       else
 496         dnl non-modular X11 installation
 497         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 498                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 499       fi
 500       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 501     fi
 502 fi
 503
 504
 505 dnl
 506 dnl Xft
 507 dnl
 508
 509 AC_ARG_ENABLE([xft],
 510               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 511               [want_xft="$enableval"], [want_xft=yes])
 512
 513 if test x$want_xft = "xyes"; then
 514     if test "x$want_x11" != "xyes"; then
 515       dnl silently disable if no x11
 516       want_xft=no
 517     else
 518       PKG_CHECK_MODULES([Xft], [xft])
 519       CFLAGS="$CFLAGS $Xft_CFLAGS"
 520       LIBS="$LIBS $Xft_LIBS"
 521       AC_DEFINE(XFT, 1, [Define for Xft support])
 522     fi
 523 fi
 524
 525 dnl
 526 dnl IMLIB2
 527 dnl
 528
 529 AC_ARG_ENABLE([imlib2],
 530                           AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 531                           [want_imlib2="$enableval"], [want_imlib2=no])
 532 if test x$want_imlib2 = xyes; then
 533         if test "x$want_x11" != "xyes"; then
 534                 dnl silently disable if no x11
 535                 want_imlib2=no
 536         else
 537                 PKG_CHECK_MODULES([Imlib2], [imlib2])
 538                 CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 539                 LIBS="$LIBS $Imlib2_LIBS"
 540                 AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 541         fi
 542 fi
 543 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 544
 545 dnl
 546 dnl NVIDIA libXNVCtrl support
 547 dnl
 548
 549 AC_ARG_ENABLE([nvidia],
 550                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 551                 [want_nvidia="$enableval"], [want_nvidia=no])
 552 if test x$want_nvidia = xyes; then
 553     if test "x$want_x11" != "xyes"; then
 554                 # do nada
 555                 want_nvidia=no
 556         else
 557                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 558 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 559 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 560 dnl ## am I Stupid ??
 561 dnl ## it won't find the lib for some reason!?
 562                 LIBS="$LIBS -lXNVCtrl"
 563                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 564         fi
 565 fi
 566 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 567
 568 dnl
 569 dnl GLIB
 570 dnl
 571
 572 if test x$WANT_GLIB = xyes; then
 573         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 574         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 575         LIBS="$LIBS $GLib2_LIBS"
 576 fi
 577
 578 dnl
 579 dnl KVM
 580 dnl
 581
 582 if test x$WANT_KVM = xyes; then
 583   AC_CHECK_LIB(kvm, kvm_open,
 584     LIBS="$LIBS -lkvm",
 585   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 586   )
 587 fi
 588
 589 dnl
 590 dnl devstat
 591 dnl
 592
 593 if test x$WANT_DEVSTAT = xyes; then
 594   AC_CHECK_LIB(devstat, devstat_getversion,
 595          LIBS="$LIBS -ldevstat",
 596          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 597   )
 598 fi
 599
 600 dnl
 601 dnl OSSLIB for NetBSD/OpenBSD
 602 dnl
 603
 604 if test x$WANT_OSSLIB = xyes; then
 605     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 606   LIBS="$LIBS -lossaudio",
 607   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 608     )
 609 fi
 610
 611 dnl
 612 dnl ALSA for Linux
 613 dnl
 614 AC_ARG_ENABLE([alsa],
 615               AC_HELP_STRING([--disable-alsa], [disable if you do not
 616   want ALSA support @<:@default=yes@:>@]),
 617               [want_alsa="$enableval"], [want_alsa=yes])
 618
 619 if test x$want_alsa = xyes; then
 620     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 621 fi
 622 if test x$want_alsa = xyes; then
 623     AC_CHECK_LIB(asound, snd_pcm_open,LIBS="$LIBS -lasound", want_alsa=no)
 624 fi
 625 if test x$want_alsa = xyes; then
 626 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 627 fi
 628 dnl
 629 dnl Some headers
 630 dnl
 631
 632 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 633       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 634 AC_CHECK_HEADERS([sys/mount.h], [], [],
 635      [#ifdef HAVE_SYS_PARAM_H
 636       #include <sys/param.h>
 637       #endif
 638       ])
 639 # check if we have inotify support
 640 AC_CHECK_HEADERS([sys/inotify.h])
 641
 642 dnl
 643 dnl Some defines
 644 dnl
 645
 646 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 647 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 648 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 649 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 650 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 651
 652 dnl
 653 dnl Some functions
 654 dnl
 655
 656 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 657 AC_SEARCH_LIBS(clock_gettime, [rt],
 658                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 659                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 660
 661 dnl
 662 dnl Structure checks
 663 dnl
 664
 665 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 666                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 667                  [],
 668                  [#include <sys/statfs.h>])
 669
 670 dnl
 671 dnl Check for zlib
 672 dnl
 673
 674 AC_CHECK_HEADER(zlib.h,
 675                 [],
 676                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 677
 678
 679 dnl
 680 dnl Check for OpenMP support
 681 dnl
 682
 683 AC_ARG_ENABLE([openmp],
 684               AC_HELP_STRING([--enable-openmp], [enable if you want OpenMP support @<:@default=no@:>@]),
 685               [want_openmp="$enableval"], [want_openmp=no])
 686
 687 if test x$want_openmp = xyes; then
 688         AX_OPENMP([
 689           gcc_version=`$CC -dumpversion`
 690           gcc_major=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 691           gcc_minor=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 692           dnl check that the gcc version is >=4.3, if we're using gcc
 693           if test ! "x$GCC" = "xyes" -o $gcc_major -ge 4 -a $gcc_minor -ge 3; then
 694             AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 695             CFLAGS="$CFLAGS $OPENMP_CFLAGS"
 696           else
 697             want_openmp=no
 698           fi
 699
 700         ])
 701 fi
 702
 703 dnl
 704 dnl Check doc stuff
 705 dnl
 706
 707 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 708 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 709 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 710 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 711   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 712 else
 713   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 714 fi
 715
 716 dnl
 717 dnl kstat in Solaris
 718 dnl
 719
 720 if test x$WANT_KSTAT = xyes; then
 721   dah=no
 722   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 723
 724   if test x$dah = xyes; then
 725     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 726     LDFLAGS="$LDFLAGS -lkstat"
 727   fi
 728 fi
 729
 730 AC_DEFUN([AM_LANGINFO_CODESET],
 731 [
 732   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 733     [AC_TRY_LINK([#include <langinfo.h>],
 734       [char* cs = nl_langinfo(CODESET);],
 735       am_cv_langinfo_codeset=yes,
 736       am_cv_langinfo_codeset=no)
 737     ])
 738   if test $am_cv_langinfo_codeset = yes; then
 739     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 740       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 741   fi
 742 ])
 743
 744
 745 dnl ************************
 746 dnl * Linker optimizations *
 747 dnl ************************
 748 AC_MSG_CHECKING([if $LD accepts -O1])
 749 case `$LD -O1 -v 2>&1 </dev/null` in
 750 *GNU* | *BSD*)
 751   LDFLAGS="$LDFLAGS -Wl,-O1"
 752   AC_MSG_RESULT([yes])
 753   ;;
 754 *)
 755   AC_MSG_RESULT([no])
 756   ;;
 757 esac
 758
 759 dnl Solve multiple definitions (only necessary when gnulib is used)
 760 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 761
 762 dnl
 763 dnl Da.
 764 dnl
 765
 766 CFLAGS="$CFLAGS -Wall -W"
 767
 768 dnl
 769 dnl debug
 770 dnl
 771
 772 AC_ARG_ENABLE([debug],
 773               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 774               [want_debug="$enableval"], [want_debug=no])
 775
 776 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 777   CFLAGS="$CFLAGS -g3"
 778   AC_DEFINE([DEBUG], 1, [Define for debugging])
 779 fi
 780
 781 dnl
 782 dnl testing
 783 dnl
 784
 785 AC_ARG_ENABLE([testing],
 786               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 787               [want_testing="$enableval"], [want_testing=no])
 788
 789 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 790   if test "x$want_debug" = "xyes"; then
 791     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 792     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 793   else
 794     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 795     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 796   fi
 797 fi
 798
 799 AC_SUBST(CFLAGS)
 800 AC_SUBST(X11_LIBS)
 801
 802 AC_OUTPUT
 803
 804 dnl
 805 dnl Print summary
 806 dnl
 807 cat << EOF
 808
 809 $PACKAGE $VERSION configured successfully:
 810
 811  Installing into:   $prefix
 812  System config dir: $sysconfdir
 813  C compiler flags:  $CFLAGS
 814  Linker flags:      $LDFLAGS
 815  Libraries:         $LIBS
 816
 817  * X11:
 818   X11 support:      $want_x11
 819   XDamage support:  $want_xdamage
 820   XDBE support:     $want_double_buffer
 821   Xft support:      $want_xft
 822
 823  * Music detection:
 824   Audacious:        $want_audacious
 825   BMPx:             $want_bmpx
 826   MPD:              $want_mpd
 827   MOC:              $want_moc
 828   XMMS2:            $want_xmms2
 829
 830  * General:
 831   OpenMP:           $want_openmp
 832   math:             $want_math
 833   hddtemp:          $want_hddtemp
 834   portmon:          $want_portmon
 835   RSS:              $want_rss
 836   Lua:              $want_lua
 837   wireless:         $want_wlan
 838   IBM:              $want_ibm
 839   nvidia:           $want_nvidia
 840   eve-online:       $want_eve
 841   config-output:    $want_config_output
 842   Imlib2:           $want_imlib2
 843   ALSA mixer:       $want_alsa
 844   apcupsd:          $want_apcupsd
 845   I/O stats:        $want_iostats
 846 EOF