vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [6])
   6 m4_define([conky_version_micro], [0])
   7 m4_define([conky_version_tag], [pre]) dnl [] for releases
   8 m4_define([conky_version_revision],[_pre@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [pre],
  12       [conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  22 dnl libtool must be deleted with make distclean to see this fix.
  23 if test x"$CFLAGS" = x""; then
  24   AC_SUBST(CFLAGS, [ ])
  25 fi
  26
  27 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  28
  29 dnl
  30 dnl Tools
  31 dnl
  32 AC_PROG_CC
  33 AC_PROG_LD
  34 AC_PROG_INSTALL
  35 AC_PROG_LIBTOOL
  36
  37 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  38 if test x"$HAVE_PKGCONFIG" = x"no"; then
  39   AC_MSG_ERROR([pkg-config is required!])
  40 fi
  41 PKG_PROG_PKG_CONFIG([0.19])
  42
  43 AC_CONFIG_FILES(
  44   Makefile
  45   data/Makefile
  46   doc/Makefile
  47   src/Makefile
  48   src/build.h
  49   )
  50
  51 uname=`uname`
  52
  53 case $uname in
  54   Linux*)
  55     WANT_SYSINFO=yes
  56     ;;
  57   FreeBSD*|GNU/kFreeBSD*)
  58     WANT_KVM=yes
  59     WANT_DEVSTAT=yes
  60     ;;
  61 #  NetBSD*)
  62 #    WANT_KVM=yes
  63 #    WANT_OSSLIB=yes
  64 #    ;;
  65
  66   OpenBSD*)
  67     WANT_KVM=yes
  68     WANT_OSSLIB=yes
  69     ;;
  70
  71 # Solaris doesn't work at all right now
  72 #  SunOS*)
  73 #    WANT_KSTAT=yes
  74 #    ;;
  75
  76   *)
  77     echo "Your operating system $uname isn't supported"
  78     echo "Feel free to help. :P"
  79     exit 1
  80     ;;
  81 esac
  82
  83 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  84 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  85 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  86 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  87 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  88
  89 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  90 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  91 AC_SUBST(BUILD_DATE)
  92 AC_SUBST(BUILD_ARCH)
  93
  94
  95 dnl
  96 dnl OWN_WINDOW option
  97 dnl
  98
  99 AC_ARG_ENABLE([own_window],
 100               AC_HELP_STRING([--disable-own-window],
 101                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 102               [dah="$enableval"], [dah=yes])
 103
 104 if test $dah != "no"; then
 105   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 106 fi
 107
 108
 109 dnl
 110 dnl Audacious Media Player
 111 dnl
 112
 113 AC_ARG_ENABLE([audacious],
 114               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 115                              [enable audacious player support @<:@default=no@:>@]),
 116               [want_audacious="$enableval"], [want_audacious=no])
 117
 118 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 119 if test x$want_audacious = xyes; then
 120       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 121       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 122       LIBS="$LIBS $Audacious_LIBS"
 123       save_CPPFLAGS="$CPPFLAGS"
 124       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 125       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 126                        [], AC_MSG_ERROR([required header(s) not found]))
 127       CPPFLAGS="$save_CPPFLAGS"
 128       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 129 else if test x$want_audacious = xlegacy; then
 130       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 131       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 132       LIBS="$LIBS $Audacious_LIBS"
 133       save_CPPFLAGS="$CPPFLAGS"
 134       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 135       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 136       CPPFLAGS="$save_CPPFLAGS"
 137       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 138       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 139       fi
 140 fi
 141
 142
 143 dnl
 144 dnl BMPx
 145 dnl
 146
 147 AC_ARG_ENABLE([bmpx],
 148               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 149               [want_bmpx="$enableval"], [want_bmpx=no])
 150
 151 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 152 if test x$want_bmpx = xyes; then
 153   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 154   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 155   LIBS="$LIBS $BMPx_LIBS"
 156   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 157 fi
 158
 159
 160 dnl
 161 dnl Hddtemp
 162 dnl
 163
 164 AC_ARG_ENABLE([hddtemp],
 165               AC_HELP_STRING([--disable-hddtemp],
 166                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 167               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 168
 169 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 170 if test x$want_hddtemp = xyes; then
 171   if test x"$uname" != xLinux; then
 172       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 173       want_hddtemp=no
 174   else
 175       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 176   fi
 177 fi
 178
 179 dnl
 180 dnl Math
 181 dnl
 182
 183 AC_ARG_ENABLE([math],
 184               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 185               [want_math="$enableval"], [want_math=yes])
 186
 187 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 188 if test x$want_math = xyes; then
 189   LIBS="$LIBS -lm"
 190   AC_DEFINE(MATH, 1, [Define if you want math support])
 191 fi
 192
 193 dnl
 194 dnl MPD
 195 dnl
 196
 197 AC_ARG_ENABLE([mpd],
 198               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 199               [want_mpd="$enableval"], [want_mpd=yes])
 200
 201 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 202 if test x$want_mpd = xyes; then
 203   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 204 fi
 205
 206 dnl
 207 dnl XMMS2
 208 dnl
 209
 210 AC_ARG_ENABLE([xmms2],
 211               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 212               [want_xmms2="$enableval"], [want_xmms2=no])
 213
 214 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 215 if test x$want_xmms2 = xyes; then
 216   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 217     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 218     LIBS="$LIBS $XMMS2_LIBS"
 219     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 220 fi
 221
 222 dnl
 223 dnl EVE Skill Monitor
 224 dnl
 225
 226 AC_ARG_ENABLE([eve],
 227               EC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 228               [want_eve="$enableval"], [want_eve=no])
 229
 230 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 231 if test x$want_eve = xyes; then
 232         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 233         PKG_CHECK_MODULES([libcurl], libcurl)
 234         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 235         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 236         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 237         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 238         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 239         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 240         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 241 fi
 242
 243 dnl
 244 dnl RSS
 245 dnl
 246
 247 AC_ARG_ENABLE([rss],
 248               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 249               [want_rss="$enableval"], [want_rss=no])
 250 #
 251 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 252 if test x$want_rss = xyes; then
 253         WANT_GLIB=yes
 254         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 255         PKG_CHECK_MODULES([libcurl], libcurl)
 256         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 257         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 258         AC_DEFINE(RSS, 1, [Define if you want rss support])
 259 fi
 260
 261 dnl
 262 dnl SMAPI
 263 dnl
 264
 265 AC_ARG_ENABLE([smapi],
 266               AC_HELP_STRING([--enable-smapi], [enable if you want smapi support @<:@default=no@:>@]),
 267               [want_smapi="$enableval"], [want_smapi=no])
 268
 269 AM_CONDITIONAL(BUILD_SMAPI, test x$want_smapi = xyes)
 270 if test x$want_smapi = xyes; then
 271         AC_DEFINE(SMAPI, 1, [Define if you want smapi support])
 272 fi
 273
 274 dnl
 275 dnl Wireless extensions
 276 dnl
 277
 278 AC_ARG_ENABLE([wlan],
 279               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 280               [want_wlan="$enableval"], [want_wlan=no])
 281
 282 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 283 if test x$want_wlan = xyes; then
 284   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 285   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 286         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 287 fi
 288
 289 dnl
 290 dnl NVIDIA libXNVCtrl support
 291 dnl
 292
 293 AC_ARG_ENABLE([nvidia],
 294                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 295                 [want_nvidia="$enableval"], [want_nvidia=no])
 296 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 297 if test x$want_nvidia = xyes; then
 298         AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 299 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 300 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 301 dnl ## am I Stupid ??
 302 dnl ## it won't find the lib for some reason!?
 303         LIBS="$LIBS -lXNVCtrl"
 304                 AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 305 fi
 306
 307 dnl
 308 dnl IMLIB2
 309 dnl
 310
 311 dnl --commented out until brenden finishes it --
 312 dnl AC_ARG_ENABLE([imlib2],
 313 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 314 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 315 dnl
 316 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 317 dnl if test x$want_imlib2 = xyes; then
 318 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 319 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 320 dnl LIBS="$LIBS $Imlib2_LIBS"
 321 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 322 dnl fi
 323
 324
 325 dnl
 326 dnl PORT_MONITORS
 327 dnl
 328
 329 AC_ARG_ENABLE([portmon],
 330               AC_HELP_STRING([--disable-portmon],
 331                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 332               [want_portmon="$enableval"], [want_portmon=yes])
 333
 334 if test x"$want_portmon" = xyes; then
 335   if test x"$uname" != xLinux; then
 336       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 337       want_portmon=no
 338   else
 339         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 340         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 341            [PORT_MONITORS_MISSING=yes])
 342         if test x"$PORT_MONITORS_MISSING" = xyes; then
 343               AC_MSG_ERROR([missing a needed network header for port monitoring])
 344         fi
 345         WANT_GLIB=yes
 346         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 347   fi
 348 fi
 349 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 350
 351
 352 dnl
 353 dnl ICONV
 354 dnl
 355
 356 AM_ICONV
 357 if test "$am_cv_func_iconv" != yes; then
 358   AC_MSG_WARN([Could not find libiconv])
 359 else
 360   LIBS="$LIBS $LIBICONV"
 361 fi
 362
 363 dnl
 364 dnl X11
 365 dnl
 366
 367 AC_ARG_ENABLE([x11],
 368               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 369               [want_x11="$enableval"], [want_x11=yes])
 370
 371 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 372 if test "x$want_x11" = "xyes"; then
 373     if $PKG_CONFIG --exists x11; then
 374       PKG_CHECK_MODULES([X11], [x11])
 375       CFLAGS="$CFLAGS $X11_CFLAGS"
 376       LIBS="$LIBS $X11_LIBS"
 377     else
 378       dnl non-modular X11 installations
 379       AC_PATH_X
 380       AC_PATH_XTRA
 381       CFLAGS="$CFLAGS $X_CFLAGS"
 382       LIBS="$LIBS $X_LIBS"
 383       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 384       if test "x$no_x" = "xyes"; then
 385         AC_MSG_ERROR([Can't locate your X11 installation])
 386       fi
 387       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 388     fi
 389     AC_DEFINE(X11, 1, [Define if you want to use X11])
 390 fi
 391
 392
 393 dnl
 394 dnl Xext Double-buffering Extension
 395 dnl
 396
 397 AC_ARG_ENABLE([double_buffer],
 398               AC_HELP_STRING([--disable-double-buffer],
 399                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 400               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 401
 402 if test "x$want_double_buffer" = "xyes"; then
 403     if test "x$want_x11" != "xyes"; then
 404       dnl silently disable if no x11
 405       want_double_buffer=no
 406     else
 407       if $PKG_CONFIG --exists xext; then
 408         PKG_CHECK_MODULES([Xext],[xext])
 409         CFLAGS="$CFLAGS $Xext_CFLAGS"
 410         LIBS="$LIBS $Xext_LIBS"
 411       else
 412         dnl non-modular X11 installation
 413         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 414                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 415       fi
 416       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 417     fi
 418 fi
 419
 420
 421 dnl
 422 dnl Xdamage Extension
 423 dnl
 424
 425 AC_ARG_ENABLE([xdamage],
 426               AC_HELP_STRING([--disable-xdamage],
 427                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 428               [want_xdamage="$enableval"], [want_xdamage=yes])
 429
 430 if test "x$want_xdamage" = "xyes"; then
 431     if test "x$want_x11" != "xyes"; then
 432       dnl silently disable if no x11
 433       want_xdamage=no
 434     else
 435       if $PKG_CONFIG --exists xdamage; then
 436         PKG_CHECK_MODULES([XDamage],[xdamage])
 437         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 438         LIBS="$LIBS $XDamage_LIBS"
 439       else
 440         dnl non-modular X11 installation
 441         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 442                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 443       fi
 444       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 445     fi
 446 fi
 447
 448
 449 dnl
 450 dnl Xft
 451 dnl
 452
 453 AC_ARG_ENABLE([xft],
 454               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 455               [want_xft="$enableval"], [want_xft=yes])
 456
 457 if test x$want_xft = "xyes"; then
 458     if test "x$want_x11" != "xyes"; then
 459       dnl silently disable if no x11
 460       want_xft=no
 461     else
 462       PKG_CHECK_MODULES([Xft], [xft])
 463       CFLAGS="$CFLAGS $Xft_CFLAGS"
 464       LIBS="$LIBS $Xft_LIBS"
 465       AC_DEFINE(XFT, 1, [Define for Xft support])
 466     fi
 467 fi
 468
 469 dnl
 470 dnl GLIB
 471 dnl
 472
 473 if test x$WANT_GLIB = xyes; then
 474         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 475         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 476         LIBS="$LIBS $GLib2_LIBS"
 477 fi
 478
 479 dnl
 480 dnl KVM
 481 dnl
 482
 483 if test x$WANT_KVM = xyes; then
 484   AC_CHECK_LIB(kvm, kvm_open,
 485     LIBS="$LIBS -lkvm",
 486   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 487   )
 488 fi
 489
 490 dnl
 491 dnl devstat
 492 dnl
 493
 494 if test x$WANT_DEVSTAT = xyes; then
 495   AC_CHECK_LIB(devstat, devstat_getversion,
 496          LIBS="$LIBS -ldevstat",
 497          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 498   )
 499 fi
 500
 501 dnl
 502 dnl OSSLIB for NetBSD/OpenBSD
 503 dnl
 504
 505 if test x$WANT_OSSLIB = xyes; then
 506     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 507   LIBS="$LIBS -lossaudio",
 508   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 509     )
 510 fi
 511
 512 dnl
 513 dnl Some headers
 514 dnl
 515
 516 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 517       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 518 AC_CHECK_HEADERS([sys/mount.h], [], [],
 519      [#ifdef HAVE_SYS_PARAM_H
 520       #include <sys/param.h>
 521       #endif
 522       ])
 523
 524 dnl
 525 dnl Some defines
 526 dnl
 527
 528 AC_DEFINE(DEFAULTNETDEV, "eth0", [Set to the default networkdevice])
 529
 530 dnl
 531 dnl Some functions
 532 dnl
 533
 534 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 535 AC_SEARCH_LIBS(clock_gettime, [rt],
 536                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 537                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 538
 539 dnl
 540 dnl Structure checks
 541 dnl
 542
 543 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 544                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 545                  [],
 546                  [#include <sys/statfs.h>])
 547
 548 dnl
 549 dnl Check for zlib
 550 dnl
 551
 552 AC_CHECK_HEADER(zlib.h,
 553                 [],
 554                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 555
 556
 557 dnl
 558 dnl Check doc stuff
 559 dnl
 560
 561 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 562 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 563 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 564 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 565   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 566 else
 567   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 568 fi
 569
 570
 571 dnl
 572 dnl kstat in Solaris
 573 dnl
 574
 575 if test x$WANT_KSTAT = xyes; then
 576   dah=no
 577   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 578
 579   if test x$dah = xyes; then
 580     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 581     LDFLAGS="$LDFLAGS -lkstat"
 582   fi
 583 fi
 584
 585 AC_DEFUN([AM_LANGINFO_CODESET],
 586 [
 587   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 588     [AC_TRY_LINK([#include <langinfo.h>],
 589       [char* cs = nl_langinfo(CODESET);],
 590       am_cv_langinfo_codeset=yes,
 591       am_cv_langinfo_codeset=no)
 592     ])
 593   if test $am_cv_langinfo_codeset = yes; then
 594     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 595       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 596   fi
 597 ])
 598
 599
 600 dnl ************************
 601 dnl * Linker optimizations *
 602 dnl ************************
 603 AC_MSG_CHECKING([if $LD accepts -O1])
 604 case `$LD -O1 -v 2>&1 </dev/null` in
 605 *GNU* | *BSD*)
 606   LDFLAGS="$LDFLAGS -Wl,-O1"
 607   AC_MSG_RESULT([yes])
 608   ;;
 609 *)
 610   AC_MSG_RESULT([no])
 611   ;;
 612 esac
 613
 614 dnl Solve multiple definitions (only necessary when gnulib is used)
 615 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 616
 617 dnl
 618 dnl Da.
 619 dnl
 620
 621 CFLAGS="$CFLAGS -Wall -W"
 622
 623 dnl
 624 dnl debug
 625 dnl
 626
 627 AC_ARG_ENABLE([debug],
 628               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 629               [want_debug="$enableval"], [want_debug=no])
 630
 631 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 632   CFLAGS="$CFLAGS -g3"
 633   AC_DEFINE([DEBUG], [], [Define for debugging])
 634 fi
 635
 636 dnl
 637 dnl testing
 638 dnl
 639
 640 AC_ARG_ENABLE([testing],
 641               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 642               [want_testing="$enableval"], [want_testing=no])
 643
 644 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 645   if test "x$want_debug" = "xyes"; then
 646     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 647     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 648   else
 649     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 650     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 651   fi
 652 fi
 653
 654 AC_SUBST(CFLAGS)
 655 AC_SUBST(X11_LIBS)
 656
 657 AC_OUTPUT
 658
 659 dnl
 660 dnl Print summary
 661 dnl
 662 cat << EOF
 663
 664 $PACKAGE $VERSION configured successfully:
 665
 666  Installing into:   $prefix
 667  System config dir: $sysconfdir
 668  C compiler flags:  $CFLAGS
 669  Linker flags:      $LDFLAGS
 670  Libraries:         $LIBS
 671
 672  * X11:
 673   X11 support:      $want_x11
 674   XDamage support:  $want_xdamage
 675   XDBE support:     $want_double_buffer
 676   Xft support:      $want_xft
 677
 678  * Music detection:
 679   Audacious:        $want_audacious
 680   BMPx:             $want_bmpx
 681   MPD:              $want_mpd
 682   XMMS2:            $want_xmms2
 683
 684  * General:
 685   math:             $want_math
 686   hddtemp:          $want_hddtemp
 687   portmon:          $want_portmon
 688   RSS:              $want_rss
 689   wireless:         $want_wlan
 690   SMAPI:            $want_smapi
 691   nvidia:           $want_nvidia
 692   eve-online:       $want_eve
 693 EOF