vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [6])
   4 m4_define([conky_version_micro], [2])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58     ;;
  59 #  NetBSD*)
  60 #    WANT_KVM=yes
  61 #    WANT_OSSLIB=yes
  62 #    ;;
  63
  64   OpenBSD*)
  65     WANT_KVM=yes
  66     WANT_OSSLIB=yes
  67     ;;
  68
  69 # Solaris doesn't work at all right now
  70 #  SunOS*)
  71 #    WANT_KSTAT=yes
  72 #    ;;
  73
  74   *)
  75     echo "Your operating system $uname isn't supported"
  76     echo "Feel free to help. :P"
  77     exit 1
  78     ;;
  79 esac
  80
  81 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  82 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  83 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  84 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  85 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  86
  87 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  88 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  89 AC_SUBST(BUILD_DATE)
  90 AC_SUBST(BUILD_ARCH)
  91
  92
  93 dnl
  94 dnl BUILD_CONFIG_OUTPUT option
  95 dnl
  96
  97 AC_ARG_ENABLE([config_output],
  98               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) @<:@default=yes@:>@]),
  99               [want_config_output="$enableval"], [want_config_output=yes])
 100
 101 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 102 if test x$want_config_output = xyes; then
 103   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 104 fi
 105
 106 dnl
 107 dnl OWN_WINDOW option
 108 dnl
 109
 110 AC_ARG_ENABLE([own_window],
 111               AC_HELP_STRING([--disable-own-window],
 112                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 113               [dah="$enableval"], [dah=yes])
 114
 115 if test $dah != "no"; then
 116   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 117 fi
 118
 119
 120 dnl
 121 dnl Audacious Media Player
 122 dnl
 123
 124 AC_ARG_ENABLE([audacious],
 125               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 126                              [enable audacious player support @<:@default=no@:>@]),
 127               [want_audacious="$enableval"], [want_audacious=no])
 128
 129 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 130 if test x$want_audacious = xyes; then
 131       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 132       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 133       LIBS="$LIBS $Audacious_LIBS"
 134       save_CPPFLAGS="$CPPFLAGS"
 135       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 136       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 137                        [], AC_MSG_ERROR([required header(s) not found]))
 138       CPPFLAGS="$save_CPPFLAGS"
 139       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 140 else if test x$want_audacious = xlegacy; then
 141       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 142       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 143       LIBS="$LIBS $Audacious_LIBS"
 144       save_CPPFLAGS="$CPPFLAGS"
 145       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 146       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 147       CPPFLAGS="$save_CPPFLAGS"
 148       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 149       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 150       fi
 151 fi
 152
 153
 154 dnl
 155 dnl BMPx
 156 dnl
 157
 158 AC_ARG_ENABLE([bmpx],
 159               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 160               [want_bmpx="$enableval"], [want_bmpx=no])
 161
 162 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 163 if test x$want_bmpx = xyes; then
 164   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 165   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 166   LIBS="$LIBS $BMPx_LIBS"
 167   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 168 fi
 169
 170
 171 dnl
 172 dnl Hddtemp
 173 dnl
 174
 175 AC_ARG_ENABLE([hddtemp],
 176               AC_HELP_STRING([--disable-hddtemp],
 177                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 178               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 179
 180 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 181 if test x$want_hddtemp = xyes; then
 182   if test x"$uname" != xLinux; then
 183       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 184       want_hddtemp=no
 185   else
 186       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 187   fi
 188 fi
 189
 190 dnl
 191 dnl Math
 192 dnl
 193
 194 AC_ARG_ENABLE([math],
 195               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 196               [want_math="$enableval"], [want_math=yes])
 197
 198 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 199 if test x$want_math = xyes; then
 200   LIBS="$LIBS -lm"
 201   AC_DEFINE(MATH, 1, [Define if you want math support])
 202 fi
 203
 204 dnl
 205 dnl MPD
 206 dnl
 207
 208 AC_ARG_ENABLE([mpd],
 209               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 210               [want_mpd="$enableval"], [want_mpd=yes])
 211
 212 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 213 if test x$want_mpd = xyes; then
 214   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 215 fi
 216
 217 dnl
 218 dnl MOC
 219 dnl
 220
 221 AC_ARG_ENABLE([moc],
 222               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 223               [want_moc="$enableval"], [want_moc=yes])
 224
 225 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 226 if test x$want_moc = xyes; then
 227   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 228 fi
 229
 230 dnl
 231 dnl XMMS2
 232 dnl
 233
 234 AC_ARG_ENABLE([xmms2],
 235               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 236               [want_xmms2="$enableval"], [want_xmms2=no])
 237
 238 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 239 if test x$want_xmms2 = xyes; then
 240   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 241     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 242     LIBS="$LIBS $XMMS2_LIBS"
 243     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 244 fi
 245
 246 dnl
 247 dnl EVE Skill Monitor
 248 dnl
 249
 250 AC_ARG_ENABLE([eve],
 251               EC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 252               [want_eve="$enableval"], [want_eve=no])
 253
 254 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 255 if test x$want_eve = xyes; then
 256         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 257         PKG_CHECK_MODULES([libcurl], libcurl)
 258         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 259         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 260         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 261         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 262         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 263         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 264         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 265 fi
 266
 267 dnl
 268 dnl RSS
 269 dnl
 270
 271 AC_ARG_ENABLE([rss],
 272               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 273               [want_rss="$enableval"], [want_rss=no])
 274 #
 275 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 276 if test x$want_rss = xyes; then
 277         WANT_GLIB=yes
 278         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 279         PKG_CHECK_MODULES([libcurl], libcurl)
 280         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 281         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 282         AC_DEFINE(RSS, 1, [Define if you want rss support])
 283 fi
 284
 285 dnl
 286 dnl SMAPI
 287 dnl
 288
 289 AC_ARG_ENABLE([smapi],
 290               AC_HELP_STRING([--enable-smapi], [enable if you want smapi support @<:@default=no@:>@]),
 291               [want_smapi="$enableval"], [want_smapi=no])
 292
 293 AM_CONDITIONAL(BUILD_SMAPI, test x$want_smapi = xyes)
 294 if test x$want_smapi = xyes; then
 295         AC_DEFINE(SMAPI, 1, [Define if you want smapi support])
 296 fi
 297
 298 dnl
 299 dnl Wireless extensions
 300 dnl
 301
 302 AC_ARG_ENABLE([wlan],
 303               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 304               [want_wlan="$enableval"], [want_wlan=no])
 305
 306 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 307 if test x$want_wlan = xyes; then
 308   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 309   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 310         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 311 fi
 312
 313 dnl
 314 dnl NVIDIA libXNVCtrl support
 315 dnl
 316
 317 AC_ARG_ENABLE([nvidia],
 318                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 319                 [want_nvidia="$enableval"], [want_nvidia=no])
 320 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 321 if test x$want_nvidia = xyes; then
 322         AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 323 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 324 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 325 dnl ## am I Stupid ??
 326 dnl ## it won't find the lib for some reason!?
 327         LIBS="$LIBS -lXNVCtrl"
 328                 AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 329 fi
 330
 331 dnl
 332 dnl IMLIB2
 333 dnl
 334
 335 dnl --commented out until brenden finishes it --
 336 dnl AC_ARG_ENABLE([imlib2],
 337 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 338 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 339 dnl
 340 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 341 dnl if test x$want_imlib2 = xyes; then
 342 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 343 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 344 dnl LIBS="$LIBS $Imlib2_LIBS"
 345 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 346 dnl fi
 347
 348
 349 dnl
 350 dnl PORT_MONITORS
 351 dnl
 352
 353 AC_ARG_ENABLE([portmon],
 354               AC_HELP_STRING([--disable-portmon],
 355                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 356               [want_portmon="$enableval"], [want_portmon=yes])
 357
 358 if test x"$want_portmon" = xyes; then
 359   if test x"$uname" != xLinux; then
 360       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 361       want_portmon=no
 362   else
 363         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 364         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 365            [PORT_MONITORS_MISSING=yes])
 366         if test x"$PORT_MONITORS_MISSING" = xyes; then
 367               AC_MSG_ERROR([missing a needed network header for port monitoring])
 368         fi
 369         WANT_GLIB=yes
 370         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 371   fi
 372 fi
 373 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 374
 375
 376 dnl
 377 dnl ICONV
 378 dnl
 379
 380 AM_ICONV
 381 if test "$am_cv_func_iconv" != yes; then
 382   AC_MSG_WARN([Could not find libiconv])
 383 else
 384   LIBS="$LIBS $LIBICONV"
 385 fi
 386
 387 dnl
 388 dnl X11
 389 dnl
 390
 391 AC_ARG_ENABLE([x11],
 392               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 393               [want_x11="$enableval"], [want_x11=yes])
 394
 395 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 396 if test "x$want_x11" = "xyes"; then
 397     if $PKG_CONFIG --exists x11; then
 398       PKG_CHECK_MODULES([X11], [x11])
 399       CFLAGS="$CFLAGS $X11_CFLAGS"
 400       LIBS="$LIBS $X11_LIBS"
 401     else
 402       dnl non-modular X11 installations
 403       AC_PATH_X
 404       AC_PATH_XTRA
 405       CFLAGS="$CFLAGS $X_CFLAGS"
 406       LIBS="$LIBS $X_LIBS"
 407       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 408       if test "x$no_x" = "xyes"; then
 409         AC_MSG_ERROR([Can't locate your X11 installation])
 410       fi
 411       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 412     fi
 413     AC_DEFINE(X11, 1, [Define if you want to use X11])
 414 fi
 415
 416
 417 dnl
 418 dnl Xext Double-buffering Extension
 419 dnl
 420
 421 AC_ARG_ENABLE([double_buffer],
 422               AC_HELP_STRING([--disable-double-buffer],
 423                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 424               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 425
 426 if test "x$want_double_buffer" = "xyes"; then
 427     if test "x$want_x11" != "xyes"; then
 428       dnl silently disable if no x11
 429       want_double_buffer=no
 430     else
 431       if $PKG_CONFIG --exists xext; then
 432         PKG_CHECK_MODULES([Xext],[xext])
 433         CFLAGS="$CFLAGS $Xext_CFLAGS"
 434         LIBS="$LIBS $Xext_LIBS"
 435       else
 436         dnl non-modular X11 installation
 437         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 438                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 439       fi
 440       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 441     fi
 442 fi
 443
 444
 445 dnl
 446 dnl Xdamage Extension
 447 dnl
 448
 449 AC_ARG_ENABLE([xdamage],
 450               AC_HELP_STRING([--disable-xdamage],
 451                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 452               [want_xdamage="$enableval"], [want_xdamage=yes])
 453
 454 if test "x$want_xdamage" = "xyes"; then
 455     if test "x$want_x11" != "xyes"; then
 456       dnl silently disable if no x11
 457       want_xdamage=no
 458     else
 459       if $PKG_CONFIG --exists xdamage; then
 460         PKG_CHECK_MODULES([XDamage],[xdamage])
 461         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 462         LIBS="$LIBS $XDamage_LIBS"
 463       else
 464         dnl non-modular X11 installation
 465         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 466                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 467       fi
 468       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 469     fi
 470 fi
 471
 472
 473 dnl
 474 dnl Xft
 475 dnl
 476
 477 AC_ARG_ENABLE([xft],
 478               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 479               [want_xft="$enableval"], [want_xft=yes])
 480
 481 if test x$want_xft = "xyes"; then
 482     if test "x$want_x11" != "xyes"; then
 483       dnl silently disable if no x11
 484       want_xft=no
 485     else
 486       PKG_CHECK_MODULES([Xft], [xft])
 487       CFLAGS="$CFLAGS $Xft_CFLAGS"
 488       LIBS="$LIBS $Xft_LIBS"
 489       AC_DEFINE(XFT, 1, [Define for Xft support])
 490     fi
 491 fi
 492
 493 dnl
 494 dnl GLIB
 495 dnl
 496
 497 if test x$WANT_GLIB = xyes; then
 498         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 499         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 500         LIBS="$LIBS $GLib2_LIBS"
 501 fi
 502
 503 dnl
 504 dnl KVM
 505 dnl
 506
 507 if test x$WANT_KVM = xyes; then
 508   AC_CHECK_LIB(kvm, kvm_open,
 509     LIBS="$LIBS -lkvm",
 510   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 511   )
 512 fi
 513
 514 dnl
 515 dnl devstat
 516 dnl
 517
 518 if test x$WANT_DEVSTAT = xyes; then
 519   AC_CHECK_LIB(devstat, devstat_getversion,
 520          LIBS="$LIBS -ldevstat",
 521          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 522   )
 523 fi
 524
 525 dnl
 526 dnl OSSLIB for NetBSD/OpenBSD
 527 dnl
 528
 529 if test x$WANT_OSSLIB = xyes; then
 530     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 531   LIBS="$LIBS -lossaudio",
 532   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 533     )
 534 fi
 535
 536 dnl
 537 dnl Some headers
 538 dnl
 539
 540 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 541       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 542 AC_CHECK_HEADERS([sys/mount.h], [], [],
 543      [#ifdef HAVE_SYS_PARAM_H
 544       #include <sys/param.h>
 545       #endif
 546       ])
 547
 548 dnl
 549 dnl Some defines
 550 dnl
 551
 552 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 553 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 554
 555 dnl
 556 dnl Some functions
 557 dnl
 558
 559 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 560 AC_SEARCH_LIBS(clock_gettime, [rt],
 561                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 562                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 563
 564 dnl
 565 dnl Structure checks
 566 dnl
 567
 568 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 569                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 570                  [],
 571                  [#include <sys/statfs.h>])
 572
 573 dnl
 574 dnl Check for zlib
 575 dnl
 576
 577 AC_CHECK_HEADER(zlib.h,
 578                 [],
 579                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 580
 581
 582 dnl
 583 dnl Check doc stuff
 584 dnl
 585
 586 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 587 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 588 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 589 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 590   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 591 else
 592   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 593 fi
 594
 595
 596 dnl
 597 dnl kstat in Solaris
 598 dnl
 599
 600 if test x$WANT_KSTAT = xyes; then
 601   dah=no
 602   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 603
 604   if test x$dah = xyes; then
 605     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 606     LDFLAGS="$LDFLAGS -lkstat"
 607   fi
 608 fi
 609
 610 AC_DEFUN([AM_LANGINFO_CODESET],
 611 [
 612   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 613     [AC_TRY_LINK([#include <langinfo.h>],
 614       [char* cs = nl_langinfo(CODESET);],
 615       am_cv_langinfo_codeset=yes,
 616       am_cv_langinfo_codeset=no)
 617     ])
 618   if test $am_cv_langinfo_codeset = yes; then
 619     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 620       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 621   fi
 622 ])
 623
 624
 625 dnl ************************
 626 dnl * Linker optimizations *
 627 dnl ************************
 628 AC_MSG_CHECKING([if $LD accepts -O1])
 629 case `$LD -O1 -v 2>&1 </dev/null` in
 630 *GNU* | *BSD*)
 631   LDFLAGS="$LDFLAGS -Wl,-O1"
 632   AC_MSG_RESULT([yes])
 633   ;;
 634 *)
 635   AC_MSG_RESULT([no])
 636   ;;
 637 esac
 638
 639 dnl Solve multiple definitions (only necessary when gnulib is used)
 640 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 641
 642 dnl
 643 dnl Da.
 644 dnl
 645
 646 CFLAGS="$CFLAGS -Wall -W"
 647
 648 dnl
 649 dnl debug
 650 dnl
 651
 652 AC_ARG_ENABLE([debug],
 653               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 654               [want_debug="$enableval"], [want_debug=no])
 655
 656 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 657   CFLAGS="$CFLAGS -g3"
 658   AC_DEFINE([DEBUG], [], [Define for debugging])
 659 fi
 660
 661 dnl
 662 dnl testing
 663 dnl
 664
 665 AC_ARG_ENABLE([testing],
 666               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 667               [want_testing="$enableval"], [want_testing=no])
 668
 669 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 670   if test "x$want_debug" = "xyes"; then
 671     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 672     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 673   else
 674     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 675     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 676   fi
 677 fi
 678
 679 AC_SUBST(CFLAGS)
 680 AC_SUBST(X11_LIBS)
 681
 682 AC_OUTPUT
 683
 684 dnl
 685 dnl Print summary
 686 dnl
 687 cat << EOF
 688
 689 $PACKAGE $VERSION configured successfully:
 690
 691  Installing into:   $prefix
 692  System config dir: $sysconfdir
 693  C compiler flags:  $CFLAGS
 694  Linker flags:      $LDFLAGS
 695  Libraries:         $LIBS
 696
 697  * X11:
 698   X11 support:      $want_x11
 699   XDamage support:  $want_xdamage
 700   XDBE support:     $want_double_buffer
 701   Xft support:      $want_xft
 702
 703  * Music detection:
 704   Audacious:        $want_audacious
 705   BMPx:             $want_bmpx
 706   MPD:              $want_mpd
 707   MOC:              $want_moc
 708   XMMS2:            $want_xmms2
 709
 710  * General:
 711   math:             $want_math
 712   hddtemp:          $want_hddtemp
 713   portmon:          $want_portmon
 714   RSS:              $want_rss
 715   wireless:         $want_wlan
 716   SMAPI:            $want_smapi
 717   nvidia:           $want_nvidia
 718   eve-online:       $want_eve
 719   config-output:    $want_config_output
 720 EOF