vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [4])
   6 m4_define([conky_version_micro], [6])
   7 m4_define([conky_version_tag], [svn]) dnl [] for releases
   8 m4_define([conky_version_revision],[r@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [svn],
  12       [-conky_version_tag()-conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [-conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19
  20 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  21 dnl libtool must be deleted with make distclean to see this fix.
  22 if test x"$CFLAGS" = x""; then
  23   AC_SUBST(CFLAGS, [ ])
  24 fi
  25
  26 dnl
  27 dnl Tools
  28 dnl
  29 AC_PROG_CC
  30 AC_PROG_LD
  31 AC_PROG_INSTALL
  32 AC_PROG_LIBTOOL
  33
  34 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  35 if test x"$HAVE_PKGCONFIG" = x"no"; then
  36   AC_MSG_ERROR([pkg-config is required!])
  37 fi
  38 PKG_PROG_PKG_CONFIG([0.17.2])
  39
  40 AC_CONFIG_FILES(
  41   Makefile
  42   doc/Makefile
  43   src/Makefile
  44   src/build.h
  45   )
  46
  47 uname=`uname`
  48
  49 case $uname in
  50   Linux*)
  51     WANT_SYSINFO=yes
  52     ;;
  53   FreeBSD*)
  54     WANT_KVM=yes
  55     WANT_DEVSTAT=yes
  56     ;;
  57 #  NetBSD*)
  58 #    WANT_KVM=yes
  59 #    WANT_OSSLIB=yes
  60 #    ;;
  61
  62   OpenBSD*)
  63     WANT_KVM=yes
  64     WANT_OSSLIB=yes
  65     ;;
  66
  67 # Solaris doesn't work at all right now
  68 #  SunOS*)
  69 #    WANT_KSTAT=yes
  70 #    ;;
  71
  72   *)
  73     echo "Your operating system $uname isn't supported"
  74     echo "Feel free to help. :P"
  75     exit 1
  76     ;;
  77 esac
  78
  79 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  80 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  81 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD)
  82 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  83 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  84
  85 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  86 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  87 AC_SUBST(BUILD_DATE)
  88 AC_SUBST(BUILD_ARCH)
  89
  90
  91 dnl
  92 dnl OWN_WINDOW option
  93 dnl
  94
  95 AC_ARG_ENABLE([own_window],
  96               AC_HELP_STRING([--disable-own-window],
  97                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
  98               [dah="$enableval"], [dah=yes])
  99
 100 if test $dah != "no"; then
 101   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 102 fi
 103
 104
 105 dnl
 106 dnl Audacious Media Player
 107 dnl
 108
 109 AC_ARG_ENABLE([audacious],
 110               AC_HELP_STRING([--enable-audacious], [enable audacious player support @<:@default=no@:>@]),
 111               [want_audacious="$enableval"], [want_audacious=no])
 112
 113 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes)
 114 if test x$want_audacious = xyes; then
 115   PKG_CHECK_MODULES([AUDACIOUS], [audacious >= 0.1])
 116       CFLAGS="$CFLAGS $AUDACIOUS_CFLAGS"
 117       LIBS="$LIBS $AUDACIOUS_LIBS"
 118       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 119 fi
 120
 121
 122 dnl
 123 dnl BMPx
 124 dnl
 125
 126 AC_ARG_ENABLE([bmpx],
 127               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 128               [want_bmpx="$enableval"], [want_bmpx=no])
 129
 130 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 131 if test x$want_bmpx = xyes; then
 132   PKG_CHECK_MODULES([BMPX], [bmp-2.0 >= 0.14.0])
 133   CFLAGS="$CFLAGS $BMPX_CFLAGS"
 134   LIBS="$LIBS $BMPX_LIBS"
 135   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 136 fi
 137
 138
 139 dnl
 140 dnl Hddtemp
 141 dnl
 142
 143 AC_ARG_ENABLE([hddtemp],
 144               AC_HELP_STRING([--disable-hddtemp],
 145                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 146               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 147
 148 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 149 if test x$want_hddtemp = xyes; then
 150   AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 151 fi
 152
 153 dnl
 154 dnl MPD
 155 dnl
 156
 157 AC_ARG_ENABLE([mpd],
 158               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 159               [want_mpd="$enableval"], [want_mpd=yes])
 160
 161 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 162 if test x$want_mpd = xyes; then
 163   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 164 fi
 165
 166 dnl
 167 dnl XMMS2
 168 dnl
 169
 170 AC_ARG_ENABLE([xmms2],
 171               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 172               [want_xmms2="$enableval"], [want_xmms2=no])
 173
 174 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 175 if test x$want_xmms2 = xyes; then
 176   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 177     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 178     LIBS="$LIBS $XMMS2_LIBS"
 179     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 180 fi
 181
 182 dnl
 183 dnl RSS
 184 dnl
 185
 186 AC_ARG_ENABLE([rss],
 187               AC_HELP_STRING([--enable-rss], [enable if you want rss support (requires libmrss) @<:@default=no@:>@]),
 188               [want_rss="$enableval"], [want_rss=no])
 189 #
 190 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 191 if test x$want_rss = xyes; then
 192         WANT_GLIB=yes
 193         CFLAGS="$CFLAGS `xml2-config --cflags`"
 194         LIBS="$LIBS `xml2-config --libs`"
 195         AC_DEFINE(RSS, 1, [Define if you want rss support])
 196 fi
 197
 198 dnl
 199 dnl IMLIB2
 200 dnl
 201
 202 dnl --commented out until brenden finishes it --
 203 dnl AC_ARG_ENABLE([imlib2],
 204 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 205 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 206 dnl
 207 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 208 dnl if test x$want_imlib2 = xyes; then
 209 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 210 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 211 dnl LIBS="$LIBS $Imlib2_LIBS"
 212 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 213 dnl fi
 214
 215
 216 dnl
 217 dnl PORT_MONITORS
 218 dnl
 219
 220 AC_ARG_ENABLE([portmon],
 221               AC_HELP_STRING([--disable-portmon],
 222                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 223               [want_portmon="$enableval"], [want_portmon=yes])
 224
 225 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x$want_portmon = xyes)
 226 if test x$want_portmon = xyes; then
 227   if test "x$uname" != xLinux; then
 228       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 229       want_portmon=no
 230   else
 231         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 232            [PORT_MONITORS_MISSING=yes])
 233         if test "x$PORT_MONITORS_MISSING" = xyes; then
 234               AC_MSG_ERROR([missing a needed network header for port monitoring])
 235         fi
 236         WANT_GLIB=yes
 237         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 238   fi
 239 fi
 240
 241
 242 dnl
 243 dnl ICONV
 244 dnl
 245
 246 AM_ICONV
 247 if test "$am_cv_func_iconv" != yes; then
 248   AC_MSG_WARN([Could not find libiconv])
 249 else
 250   LIBS="$LIBS $LIBICONV"
 251 fi
 252
 253 dnl
 254 dnl debug
 255 dnl
 256
 257 AC_ARG_ENABLE([debug],
 258               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 259               [want_debug="$enableval"], [want_debug=no])
 260
 261 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 262   CFLAGS="$CFLAGS -g3"
 263   AC_DEFINE([DEBUG], [], [Define for debugging])
 264 fi
 265
 266 dnl
 267 dnl X11
 268 dnl
 269
 270 AC_ARG_ENABLE([x11],
 271               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 272               [want_x11="$enableval"], [want_x11=yes])
 273
 274 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 275 if test "x$want_x11" = "xyes"; then
 276     if $PKG_CONFIG --exists x11; then
 277       PKG_CHECK_MODULES([X11], [x11])
 278       CFLAGS="$CFLAGS $X11_CFLAGS"
 279       LIBS="$LIBS $X11_LIBS"
 280     else
 281       dnl non-modular X11 installations
 282       AC_PATH_X
 283       AC_PATH_XTRA
 284       CFLAGS="$CFLAGS $X_CFLAGS"
 285       LIBS="$LIBS $X_LIBS"
 286       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 287       if test "x$no_x" = "xyes"; then
 288         AC_MSG_ERROR([Can't locate your X11 installation])
 289       fi
 290       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 291     fi
 292     AC_DEFINE(X11, 1, [Define if you want to use X11])
 293 fi
 294
 295
 296 dnl
 297 dnl Xext Double-buffering Extension
 298 dnl
 299
 300 AC_ARG_ENABLE([double_buffer],
 301               AC_HELP_STRING([--disable-double-buffer],
 302                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 303               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 304
 305 if test "x$want_double_buffer" = "xyes"; then
 306     if test "x$want_x11" != "xyes"; then
 307       dnl silently disable if no x11
 308       want_double_buffer=no
 309     else
 310       if $PKG_CONFIG --exists xext; then
 311         PKG_CHECK_MODULES([XEXT],[xext])
 312         CFLAGS="$CFLAGS $XEXT_CFLAGS"
 313         LIBS="$LIBS $XEXT_LIBS"
 314       else
 315         dnl non-modular X11 installation
 316         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 317                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 318       fi
 319       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 320     fi
 321 fi
 322
 323
 324 dnl
 325 dnl Xdamage Extension
 326 dnl
 327
 328 AC_ARG_ENABLE([xdamage],
 329               AC_HELP_STRING([--disable-xdamage],
 330                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 331               [want_xdamage="$enableval"], [want_xdamage=yes])
 332
 333 if test "x$want_xdamage" = "xyes"; then
 334     if test "x$want_x11" != "xyes"; then
 335       dnl silently disable if no x11
 336       want_xdamage=no
 337     else
 338       if $PKG_CONFIG --exists xdamage; then
 339         PKG_CHECK_MODULES([XDAMAGE],[xdamage])
 340         CFLAGS="$CFLAGS $XDAMAGE_CFLAGS"
 341         LIBS="$LIBS $XDAMAGE_LIBS"
 342       else
 343         dnl non-modular X11 installation
 344         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 345                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 346       fi
 347       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 348     fi
 349 fi
 350
 351
 352 dnl
 353 dnl Xft
 354 dnl
 355
 356 AC_ARG_ENABLE([xft],
 357               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 358               [want_xft="$enableval"], [want_xft=yes])
 359
 360 if test x$want_xft = "xyes"; then
 361     if test "x$want_x11" != "xyes"; then
 362       dnl silently disable if no x11
 363       want_xft=no
 364     else
 365       PKG_CHECK_MODULES(XFT, [xft])
 366       CFLAGS="$CFLAGS $XFT_CFLAGS"
 367       LIBS="$LIBS $XFT_LIBS"
 368       AC_DEFINE(XFT, 1, [Define for Xft support])
 369     fi
 370 fi
 371
 372 dnl
 373 dnl GLIB
 374 dnl
 375
 376 if test x$WANT_GLIB = xyes; then
 377         PKG_CHECK_MODULES([GLIB], [glib-2.0])
 378         CFLAGS="$CFLAGS $GLIB_CFLAGS"
 379         LIBS="$LIBS $GLIB_LIBS"
 380 fi
 381
 382 dnl
 383 dnl KVM
 384 dnl
 385
 386 if test x$WANT_KVM = xyes; then
 387   AC_CHECK_LIB(kvm, kvm_open,
 388     LIBS="$LIBS -lkvm",
 389   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 390   )
 391 fi
 392
 393 dnl
 394 dnl devstat
 395 dnl
 396
 397 if test x$WANT_DEVSTAT = xyes; then
 398   AC_CHECK_LIB(devstat, devstat_getversion,
 399          LIBS="$LIBS -ldevstat",
 400          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 401   )
 402 fi
 403
 404 dnl
 405 dnl OSSLIB for NetBSD/OpenBSD
 406 dnl
 407
 408 if test x$WANT_OSSLIB = xyes; then
 409     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 410   LIBS="$LIBS -lossaudio",
 411   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 412     )
 413 fi
 414
 415 dnl
 416 dnl Some headers
 417 dnl
 418
 419 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 420       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 421 AC_CHECK_HEADERS([sys/mount.h], [], [],
 422      [#ifdef HAVE_SYS_PARAM_H
 423       #include <sys/param.h>
 424       #endif
 425       ])
 426
 427 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
 428
 429 dnl
 430 dnl Some functions
 431 dnl
 432
 433 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr])
 434 AC_SEARCH_LIBS(clock_gettime, [rt],
 435                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 436                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 437
 438
 439 dnl
 440 dnl Check for zlib
 441 dnl
 442
 443 AC_CHECK_HEADER(zlib.h,
 444                 [],
 445                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 446
 447
 448 dnl
 449 dnl Check doc stuff
 450 dnl
 451
 452 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 453 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 454 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 455 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 456   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 457 else
 458   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 459 fi
 460
 461
 462 dnl
 463 dnl kstat in Solaris
 464 dnl
 465
 466 if test x$WANT_KSTAT = xyes; then
 467   dah=no
 468   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 469
 470   if test x$dah = xyes; then
 471     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 472     LDFLAGS="$LDFLAGS -lkstat"
 473   fi
 474 fi
 475
 476 AC_DEFUN([AM_LANGINFO_CODESET],
 477 [
 478   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 479     [AC_TRY_LINK([#include <langinfo.h>],
 480       [char* cs = nl_langinfo(CODESET);],
 481       am_cv_langinfo_codeset=yes,
 482       am_cv_langinfo_codeset=no)
 483     ])
 484   if test $am_cv_langinfo_codeset = yes; then
 485     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 486       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 487   fi
 488 ])
 489
 490
 491 dnl ************************
 492 dnl * Linker optimizations *
 493 dnl ************************
 494 AC_MSG_CHECKING([if $LD accepts -O1])
 495 case `$LD -O1 -v 2>&1 </dev/null` in
 496 *GNU* | *BSD*)
 497   LDFLAGS="$LDFLAGS -Wl,-O1"
 498   AC_MSG_RESULT([yes])
 499   ;;
 500 *)
 501   AC_MSG_RESULT([no])
 502   ;;
 503 esac
 504
 505
 506 dnl
 507 dnl Da.
 508 dnl
 509
 510 CFLAGS="$CFLAGS -Wall -W"
 511
 512 AC_SUBST(CFLAGS)
 513 AC_SUBST(X11_LIBS)
 514
 515 AC_OUTPUT
 516
 517 dnl
 518 dnl Print summary
 519 dnl
 520 cat << EOF
 521
 522 $PACKAGE $VERSION configured successfully:
 523
 524  Installing into:   $prefix
 525  C compiler flags:  $CFLAGS
 526  Linker flags:      $LDFLAGS
 527  Libraries:         $LIBS
 528
 529  * x11:
 530   x11 support:      $want_x11
 531   xdamage support:  $want_xdamage
 532   xdbe support:     $want_double_buffer
 533   xft support:      $want_xft
 534
 535  * music detection:
 536   audacious:        $want_audacious
 537   bmpx:             $want_bmpx
 538   mpd:              $want_mpd
 539   xmms2:            $want_xmms2
 540
 541  * general:
 542   hddtemp:          $want_hddtemp
 543   portmon:          $want_portmon
 544   RSS:              $want_rss
 545 EOF