vcs.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [2])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34 AM_PROG_LIBTOOL
  35 AM_PROG_CC_C_O
  36
  37 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  38 if test x"$HAVE_PKGCONFIG" = x"no"; then
  39   AC_MSG_ERROR([pkg-config is required!])
  40 fi
  41 PKG_PROG_PKG_CONFIG([0.19])
  42
  43 AC_CONFIG_FILES(
  44   Makefile
  45   data/Makefile
  46   doc/Makefile
  47   src/Makefile
  48   src/build.h
  49   lua/Makefile
  50   )
  51
  52 uname=`uname`
  53
  54 case $uname in
  55   Linux*)
  56     WANT_SYSINFO=yes
  57     ;;
  58   FreeBSD*|GNU/kFreeBSD*)
  59     WANT_KVM=yes
  60     WANT_DEVSTAT=yes
  61     ;;
  62 #  NetBSD*)
  63 #    WANT_KVM=yes
  64 #    WANT_OSSLIB=yes
  65 #    ;;
  66
  67   OpenBSD*)
  68     WANT_KVM=yes
  69     WANT_OSSLIB=yes
  70     ;;
  71
  72 # Solaris doesn't work at all right now
  73 #  SunOS*)
  74 #    WANT_KSTAT=yes
  75 #    ;;
  76
  77   *)
  78     echo "Your operating system $uname isn't supported"
  79     echo "Feel free to help. :P"
  80     exit 1
  81     ;;
  82 esac
  83
  84 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  85 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  86 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  87 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  88 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  89
  90 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  91 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  92 AC_SUBST(BUILD_DATE)
  93 AC_SUBST(BUILD_ARCH)
  94
  95
  96 dnl
  97 dnl BUILD_CONFIG_OUTPUT option
  98 dnl
  99
 100 AC_ARG_ENABLE([config_output],
 101               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) @<:@default=yes@:>@]),
 102               [want_config_output="$enableval"], [want_config_output=yes])
 103
 104 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 105 if test x$want_config_output = xyes; then
 106   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 107   AC_CHECK_FUNCS(fopencookie)
 108   AC_CHECK_FUNCS(funopen)
 109 fi
 110
 111 dnl
 112 dnl OWN_WINDOW option
 113 dnl
 114
 115 AC_ARG_ENABLE([own_window],
 116               AC_HELP_STRING([--disable-own-window],
 117                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 118               [dah="$enableval"], [dah=yes])
 119
 120 if test $dah != "no"; then
 121   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 122 fi
 123
 124
 125 dnl
 126 dnl Audacious Media Player
 127 dnl
 128
 129 AC_ARG_ENABLE([audacious],
 130               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 131                              [enable audacious player support @<:@default=no@:>@]),
 132               [want_audacious="$enableval"], [want_audacious=no])
 133
 134 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 135 if test x$want_audacious = xyes; then
 136       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 137       conky_CFLAGS="$conky_CFLAGS $Audacious_CFLAGS"
 138       conky_LIBS="$conky_LIBS $Audacious_LIBS"
 139       save_CPPFLAGS="$CPPFLAGS"
 140       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 141       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 142                        [], AC_MSG_ERROR([required header(s) not found]))
 143       CPPFLAGS="$save_CPPFLAGS"
 144       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 145 else if test x$want_audacious = xlegacy; then
 146       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 147       conky_CFLAGS="$conky_CFLAGS $Audacious_CFLAGS"
 148       conky_LIBS="$conky_LIBS $Audacious_LIBS"
 149       save_CPPFLAGS="$CPPFLAGS"
 150       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 151       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 152       CPPFLAGS="$save_CPPFLAGS"
 153       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 154       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 155       fi
 156 fi
 157
 158
 159 dnl
 160 dnl BMPx
 161 dnl
 162
 163 AC_ARG_ENABLE([bmpx],
 164               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 165               [want_bmpx="$enableval"], [want_bmpx=no])
 166
 167 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 168 if test x$want_bmpx = xyes; then
 169   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 170   conky_CFLAGS="$conky_CFLAGS $BMPx_CFLAGS"
 171   conky_LIBS="$conky_LIBS $BMPx_LIBS"
 172   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 173 fi
 174
 175
 176 dnl
 177 dnl Support for IBM/Lenovo notebooks
 178 dnl
 179
 180 AC_ARG_ENABLE([ibm],
 181               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 182               [want_ibm="$enableval"], [want_ibm=no])
 183
 184 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 185 if test x$want_ibm = xyes; then
 186         if test x"$uname" != xLinux; then
 187                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 188                 want_ibm=no
 189         else
 190                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 191         fi
 192 fi
 193
 194
 195 dnl
 196 dnl Hddtemp
 197 dnl
 198
 199 AC_ARG_ENABLE([hddtemp],
 200               AC_HELP_STRING([--disable-hddtemp],
 201                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 202               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 203
 204 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 205 if test x$want_hddtemp = xyes; then
 206   if test x"$uname" != xLinux; then
 207       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 208       want_hddtemp=no
 209   else
 210       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 211   fi
 212 fi
 213
 214
 215 dnl
 216 dnl Apcupsd
 217 dnl
 218
 219 AC_ARG_ENABLE([apcupsd],
 220               AC_HELP_STRING([--disable-apcupsd],
 221                              [disable if you do not want apcupsd support @<:@default=yes@:>@]),
 222               [want_apcupsd="$enableval"], [want_apcupsd=yes])
 223
 224 if test x$want_apcupsd = xyes; then
 225   if test x"$uname" != xLinux; then
 226       AC_MSG_NOTICE([apcupsd not supported on $uname... disabling])
 227       want_apcupsd=no
 228   else
 229       AC_DEFINE(APCUPSD, 1, [Define if you want apcupsd support])
 230   fi
 231 fi
 232 AM_CONDITIONAL(BUILD_APCUPSD, test x$want_apcupsd = xyes)
 233
 234
 235 dnl
 236 dnl I/O stats
 237 dnl
 238
 239 AC_ARG_ENABLE([iostats],
 240               AC_HELP_STRING([--enable-iostats],
 241                              [enable if you want support for per-task I/O statistics @<:@default=no@:>@]),
 242               [want_iostats="$enableval"], [want_iostats=no])
 243
 244 if test x$want_iostats = xyes; then
 245   if test x"$uname" != xLinux; then
 246       AC_MSG_NOTICE([iostats not supported on $uname... disabling])
 247       want_apcupsd=no
 248   else
 249       AC_DEFINE(IOSTATS, 1, [Define if you want support for per-task I/O statistics])
 250   fi
 251 fi
 252
 253
 254 dnl
 255 dnl Math
 256 dnl
 257
 258 AC_ARG_ENABLE([math],
 259               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 260               [want_math="$enableval"], [want_math=yes])
 261
 262 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 263 if test x$want_math = xyes; then
 264   conky_LIBS="$conky_LIBS -lm"
 265   AC_DEFINE(MATH, 1, [Define if you want math support])
 266 fi
 267
 268 dnl
 269 dnl MPD
 270 dnl
 271
 272 AC_ARG_ENABLE([mpd],
 273               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 274               [want_mpd="$enableval"], [want_mpd=yes])
 275
 276 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 277 if test x$want_mpd = xyes; then
 278   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 279 fi
 280
 281 dnl
 282 dnl MOC
 283 dnl
 284
 285 AC_ARG_ENABLE([moc],
 286               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 287               [want_moc="$enableval"], [want_moc=yes])
 288
 289 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 290 if test x$want_moc = xyes; then
 291   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 292 fi
 293
 294 dnl
 295 dnl XMMS2
 296 dnl
 297
 298 AC_ARG_ENABLE([xmms2],
 299               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 300               [want_xmms2="$enableval"], [want_xmms2=no])
 301
 302 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 303 if test x$want_xmms2 = xyes; then
 304   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 305     conky_CFLAGS="$conky_CFLAGS $XMMS2_CFLAGS"
 306     conky_LIBS="$conky_LIBS $XMMS2_LIBS"
 307     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 308 fi
 309
 310 dnl
 311 dnl EVE Skill Monitor
 312 dnl
 313
 314 AC_ARG_ENABLE([eve],
 315               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 316               [want_eve="$enableval"], [want_eve=no])
 317
 318 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 319 if test x$want_eve = xyes; then
 320         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 321         PKG_CHECK_MODULES([libcurl], libcurl)
 322         conky_CFLAGS="$conky_CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 323         conky_LIBS="$conky_LIBS $libxml2_LIBS $libcurl_LIBS"
 324         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 325         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 326         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 327         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 328         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 329 fi
 330
 331 dnl
 332 dnl RSS
 333 dnl
 334
 335 AC_ARG_ENABLE([rss],
 336               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 337               [want_rss="$enableval"], [want_rss=no])
 338 #
 339 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 340 if test x$want_rss = xyes; then
 341         WANT_GLIB=yes
 342         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 343         PKG_CHECK_MODULES([libcurl], libcurl)
 344         conky_CFLAGS="$conky_CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 345         conky_LIBS="$conky_LIBS $libxml2_LIBS $libcurl_LIBS"
 346         AC_DEFINE(RSS, 1, [Define if you want rss support])
 347 fi
 348
 349 dnl
 350 dnl WEATHER
 351 dnl
 352
 353 AC_ARG_ENABLE([weather],
 354               AC_HELP_STRING([--enable-weather], [enable if you want weather support @<:@default=no@:>@]),
 355               [want_weather="$enableval"], [want_weather=no])
 356 #
 357 AM_CONDITIONAL(BUILD_WEATHER, test x$want_weather = xyes)
 358 if test x$want_weather = xyes; then
 359         PKG_CHECK_MODULES([libcurl], libcurl)
 360         conky_CFLAGS="$conky_CFLAGS $libcurl_CFLAGS"
 361         conky_LIBS="$conky_LIBS $libcurl_LIBS"
 362         AC_DEFINE(WEATHER, 1, [Define if you want weather support])
 363 fi
 364
 365 dnl
 366 dnl X11
 367 dnl
 368
 369 AC_ARG_ENABLE([x11],
 370               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 371               [want_x11="$enableval"], [want_x11=yes])
 372
 373 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 374 if test "x$want_x11" = "xyes"; then
 375     if $PKG_CONFIG --exists x11; then
 376       PKG_CHECK_MODULES([X11], [x11])
 377       conky_CFLAGS="$conky_CFLAGS $X11_CFLAGS"
 378       conky_LIBS="$conky_LIBS $X11_LIBS"
 379     else
 380       dnl non-modular X11 installations
 381       AC_PATH_X
 382       AC_PATH_XTRA
 383       conky_CFLAGS="$conky_CFLAGS $X_CFLAGS"
 384       conky_LIBS="$conky_LIBS $X_LIBS"
 385       conky_LDFLAGS="$conky_LDFLAGS $conky_LIBS $X_PRE_LIBS"
 386       if test "x$no_x" = "xyes"; then
 387         AC_MSG_ERROR([Can't locate your X11 installation])
 388       fi
 389       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 390     fi
 391     AC_DEFINE(X11, 1, [Define if you want to use X11])
 392 fi
 393
 394 dnl
 395 dnl IMLIB2
 396 dnl
 397
 398 AC_ARG_ENABLE([imlib2],
 399                           AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support (also enables Lua Imlib2 support if lua-extras enabled) [[default=no]]]),
 400                           [want_imlib2="$enableval"], [want_imlib2=no])
 401 if test x$want_imlib2 = xyes; then
 402         if test "x$want_x11" != "xyes"; then
 403                 dnl silently disable if no x11
 404                 want_imlib2=no
 405         else
 406                 PKG_CHECK_MODULES([Imlib2], [imlib2])
 407                 conky_CFLAGS="$conky_CFLAGS $Imlib2_CFLAGS"
 408                 conky_LIBS="$conky_LIBS $Imlib2_LIBS"
 409                 AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 410         fi
 411 fi
 412 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 413
 414 dnl
 415 dnl Lua
 416 dnl
 417
 418 AC_ARG_ENABLE([lua],
 419               AC_HELP_STRING([--enable-lua], [enable if you want Lua scripting support @<:@default=yes@:>@]),
 420               [want_lua="$enableval"], [want_lua=yes])
 421 AC_ARG_ENABLE([lua-extras],
 422               AC_HELP_STRING([--enable-lua-extras], [enable if you want to install Lua extras (including bindings) @<:@default=no@:>@]),
 423               [want_lua_extras="$enableval"], [want_lua_extras=no])
 424 AC_ARG_ENABLE([lua-cairo],
 425               AC_HELP_STRING([--enable-lua-cairo], [enable if you want Lua Cairo bindings for Conky (requires lua-extras enabled) @<:@default=no@:>@]),
 426               [want_lua_cairo="$enableval"], [want_lua_cairo=no])
 427 want_lua_imlib2=no
 428
 429 AM_CONDITIONAL(BUILD_LUA, test x$want_lua = xyes)
 430 if test x$want_lua = xyes; then
 431         PKG_CHECK_MODULES(LUA, lua >= 5.1, [ ],[
 432                 PKG_CHECK_MODULES(LUA51, lua-5.1 >= 5.1, [ ],[
 433                         PKG_CHECK_MODULES(LUA51, lua5.1 >= 5.1)
 434                 ])
 435         ])
 436         conky_CFLAGS="$conky_CFLAGS $LUA_CFLAGS $LUA51_CFLAGS"
 437         conky_LIBS="$conky_LIBS $LUA_LIBS $LUA51_LIBS"
 438
 439         want_lua_imlib2="$want_imlib2"
 440         if test x$want_lua_extras != xyes; then
 441                 want_lua_cairo=no
 442                 want_lua_imlib2=no
 443         else
 444                 AC_CHECK_PROG(HAVE_TOLUAPP, tolua++, yes, no)
 445                 if test "x$want_x11" != "xyes"; then
 446                         dnl silently disable if no x11
 447                         want_lua_cairo=no
 448                 else
 449                         if test x$want_lua_cairo = xyes; then
 450                                 PKG_CHECK_MODULES([cairo], cairo)
 451                                 PKG_CHECK_MODULES([cairo_xlib], cairo-xlib)
 452                                 if test x"$HAVE_TOLUAPP" = x"no"; then
 453                                         AC_MSG_ERROR([tolua++ is required for Lua Cairo support.])
 454                                 else
 455                                         AC_CHECK_PROGS(toluapp, tolua++)
 456                                         AC_DEFINE(HAVE_LUA_CAIRO, 1, [Define if you want Lua Cairo bindings for Conky])
 457                                 fi
 458                                 libcairo_CFLAGS="$libcairo_CFLAGS $cairo_CFLAGS $cairo_xlib_CFLAGS"
 459                                 libcairo_LIBS="$libcairo_LIBS $cairo_LIBS $cairo_xlib_LIBS"
 460                         fi
 461                         if test x$want_imlib2 = xyes; then
 462                                 if test x"$HAVE_TOLUAPP" = x"no"; then
 463                                         AC_MSG_ERROR([tolua++ is required for Lua Imlib2 support.])
 464                                 else
 465                                         want_lua_imlib2=yes
 466                                         AC_CHECK_PROGS(toluapp, tolua++)
 467                                         AC_DEFINE(HAVE_LUA_IMLIB2, 1, [Define if you want Lua Imlib2 bindings for Conky])
 468                                 fi
 469                         fi
 470                 fi
 471         fi
 472         AC_DEFINE(HAVE_LUA, 1, [Define if you want Lua scripting support])
 473 fi
 474 AM_CONDITIONAL(BUILD_LUA_CAIRO, test x$want_lua_cairo = xyes)
 475 AM_CONDITIONAL(BUILD_LUA_IMLIB2, test x$want_lua_imlib2 = xyes)
 476
 477 dnl
 478 dnl Wireless extensions
 479 dnl
 480
 481 AC_ARG_ENABLE([wlan],
 482               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 483               [want_wlan="$enableval"], [want_wlan=no])
 484
 485 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 486 if test x$want_wlan = xyes; then
 487   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 488   AC_CHECK_LIB([iw], [iw_sockets_open], [conky_LIBS="$conky_LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 489         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 490 fi
 491
 492 dnl
 493 dnl PORT_MONITORS
 494 dnl
 495
 496 AC_ARG_ENABLE([portmon],
 497               AC_HELP_STRING([--disable-portmon],
 498                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 499               [want_portmon="$enableval"], [want_portmon=yes])
 500
 501 if test x"$want_portmon" = xyes; then
 502   if test x"$uname" != xLinux; then
 503       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 504       want_portmon=no
 505   else
 506         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 507         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 508            [PORT_MONITORS_MISSING=yes])
 509         if test x"$PORT_MONITORS_MISSING" = xyes; then
 510               AC_MSG_ERROR([missing a needed network header for port monitoring])
 511         fi
 512         WANT_GLIB=yes
 513         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 514   fi
 515 fi
 516 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 517
 518
 519 dnl
 520 dnl ICONV
 521 dnl
 522
 523 AM_ICONV
 524 if test "$am_cv_func_iconv" != yes; then
 525   AC_MSG_WARN([Could not find libiconv])
 526 else
 527   conky_LIBS="$conky_LIBS $LIBICONV"
 528 fi
 529
 530 dnl
 531 dnl Xext Double-buffering Extension
 532 dnl
 533
 534 AC_ARG_ENABLE([double_buffer],
 535               AC_HELP_STRING([--disable-double-buffer],
 536                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 537               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 538
 539 if test "x$want_double_buffer" = "xyes"; then
 540     if test "x$want_x11" != "xyes"; then
 541       dnl silently disable if no x11
 542       want_double_buffer=no
 543     else
 544       if $PKG_CONFIG --exists xext; then
 545         PKG_CHECK_MODULES([Xext],[xext])
 546         conky_CFLAGS="$conky_CFLAGS $Xext_CFLAGS"
 547         conky_LIBS="$conky_LIBS $Xext_LIBS"
 548       else
 549         dnl non-modular X11 installation
 550         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [conky_LIBS="$conky_LIBS -lXext"],
 551                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 552       fi
 553       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 554     fi
 555 fi
 556
 557
 558 dnl
 559 dnl Xdamage Extension
 560 dnl
 561
 562 AC_ARG_ENABLE([xdamage],
 563               AC_HELP_STRING([--disable-xdamage],
 564                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 565               [want_xdamage="$enableval"], [want_xdamage=yes])
 566
 567 if test "x$want_xdamage" = "xyes"; then
 568     if test "x$want_x11" != "xyes"; then
 569       dnl silently disable if no x11
 570       want_xdamage=no
 571     else
 572       if $PKG_CONFIG --exists xdamage; then
 573         PKG_CHECK_MODULES([XDamage],[xdamage])
 574         conky_CFLAGS="$conky_CFLAGS $XDamage_CFLAGS"
 575         conky_LIBS="$conky_LIBS $XDamage_LIBS"
 576       else
 577         dnl non-modular X11 installation
 578         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [conky_LIBS="$conky_LIBS -lXdamage"],
 579                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 580       fi
 581       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 582     fi
 583 fi
 584
 585
 586 dnl
 587 dnl Xft
 588 dnl
 589
 590 AC_ARG_ENABLE([xft],
 591               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 592               [want_xft="$enableval"], [want_xft=yes])
 593
 594 if test x$want_xft = "xyes"; then
 595     if test "x$want_x11" != "xyes"; then
 596       dnl silently disable if no x11
 597       want_xft=no
 598     else
 599       PKG_CHECK_MODULES([Xft], [xft])
 600       conky_CFLAGS="$conky_CFLAGS $Xft_CFLAGS"
 601       conky_LIBS="$conky_LIBS $Xft_LIBS"
 602       AC_DEFINE(XFT, 1, [Define for Xft support])
 603     fi
 604 fi
 605
 606 dnl
 607 dnl NVIDIA libXNVCtrl support
 608 dnl
 609
 610 AC_ARG_ENABLE([nvidia],
 611                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 612                 [want_nvidia="$enableval"], [want_nvidia=no])
 613 if test x$want_nvidia = xyes; then
 614     if test "x$want_x11" != "xyes"; then
 615                 # do nada
 616                 want_nvidia=no
 617         else
 618                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 619 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 620 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 621 dnl ## am I Stupid ??
 622 dnl ## it won't find the lib for some reason!?
 623                 conky_LIBS="$conky_LIBS -lXNVCtrl"
 624                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 625         fi
 626 fi
 627 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 628
 629 dnl
 630 dnl GLIB
 631 dnl
 632
 633 if test x$WANT_GLIB = xyes; then
 634         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 635         conky_CFLAGS="$conky_CFLAGS $GLib2_CFLAGS"
 636         conky_LIBS="$conky_LIBS $GLib2_LIBS"
 637 fi
 638
 639 dnl
 640 dnl KVM
 641 dnl
 642
 643 if test x$WANT_KVM = xyes; then
 644   AC_CHECK_LIB(kvm, kvm_open,
 645     conky_LIBS="$conky_LIBS -lkvm",
 646   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 647   )
 648 fi
 649
 650 dnl
 651 dnl devstat
 652 dnl
 653
 654 if test x$WANT_DEVSTAT = xyes; then
 655   AC_CHECK_LIB(devstat, devstat_getversion,
 656          conky_LIBS="$conky_LIBS -ldevstat",
 657          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 658   )
 659 fi
 660
 661 dnl
 662 dnl OSSLIB for NetBSD/OpenBSD
 663 dnl
 664
 665 if test x$WANT_OSSLIB = xyes; then
 666     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 667   conky_LIBS="$conky_LIBS -lossaudio",
 668   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 669     )
 670 fi
 671
 672 dnl
 673 dnl ALSA for Linux
 674 dnl
 675 AC_ARG_ENABLE([alsa],
 676               AC_HELP_STRING([--disable-alsa], [disable if you do not
 677   want ALSA support @<:@default=yes@:>@]),
 678               [want_alsa="$enableval"], [want_alsa=yes])
 679
 680 if test x$want_alsa = xyes; then
 681     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 682 fi
 683 if test x$want_alsa = xyes; then
 684     AC_CHECK_LIB(asound, snd_pcm_open,conky_LIBS="$conky_LIBS -lasound", want_alsa=no)
 685 fi
 686 if test x$want_alsa = xyes; then
 687 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 688 fi
 689 dnl
 690 dnl Some headers
 691 dnl
 692
 693 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 694       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 695 AC_CHECK_HEADERS([sys/mount.h], [], [],
 696      [#ifdef HAVE_SYS_PARAM_H
 697       #include <sys/param.h>
 698       #endif
 699       ])
 700 # check if we have inotify support
 701 AC_CHECK_HEADERS([sys/inotify.h])
 702
 703 dnl
 704 dnl Some defines
 705 dnl
 706
 707 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 708 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 709 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 710 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 711 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 712
 713 dnl
 714 dnl Some functions
 715 dnl
 716
 717 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 718 AC_SEARCH_LIBS(clock_gettime, [rt], conky_LIBS="$conky_LIBS -lrt"
 719                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 720                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 721
 722 dnl
 723 dnl Structure checks
 724 dnl
 725
 726 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 727                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 728                  [],
 729                  [#include <sys/statfs.h>])
 730
 731 dnl
 732 dnl Check for zlib
 733 dnl
 734
 735 AC_CHECK_HEADER(zlib.h,
 736                 [],
 737                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 738
 739
 740 dnl
 741 dnl Check for OpenMP support
 742 dnl
 743
 744 AC_ARG_ENABLE([openmp],
 745               AC_HELP_STRING([--enable-openmp], [enable if you want OpenMP support @<:@default=no@:>@]),
 746               [want_openmp="$enableval"], [want_openmp=no])
 747
 748 if test x$want_openmp = xyes; then
 749         AX_OPENMP([
 750           gcc_version=`$CC -dumpversion`
 751           gcc_major=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 752           gcc_minor=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 753           dnl check that the gcc version is >=4.3, if we're using gcc
 754           if test ! "x$GCC" = "xyes" -o $gcc_major -ge 4 -a $gcc_minor -ge 3; then
 755             AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 756             conky_CFLAGS="$conky_CFLAGS $OPENMP_CFLAGS"
 757           else
 758             want_openmp=no
 759           fi
 760
 761         ])
 762 fi
 763
 764 dnl
 765 dnl Check doc stuff
 766 dnl
 767
 768 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 769 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 770 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 771 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 772   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 773 else
 774   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 775 fi
 776
 777 dnl
 778 dnl kstat in Solaris
 779 dnl
 780
 781 if test x$WANT_KSTAT = xyes; then
 782   dah=no
 783   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 784
 785   if test x$dah = xyes; then
 786     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 787     conky_LDFLAGS="$conky_LDFLAGS -lkstat"
 788   fi
 789 fi
 790
 791 AC_DEFUN([AM_LANGINFO_CODESET],
 792 [
 793   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 794     [AC_TRY_LINK([#include <langinfo.h>],
 795       [char* cs = nl_langinfo(CODESET);],
 796       am_cv_langinfo_codeset=yes,
 797       am_cv_langinfo_codeset=no)
 798     ])
 799   if test $am_cv_langinfo_codeset = yes; then
 800     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 801       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 802   fi
 803 ])
 804
 805
 806 dnl ************************
 807 dnl * Linker optimizations *
 808 dnl ************************
 809 AC_MSG_CHECKING([if $LD accepts -O1])
 810 case `$LD -O1 -v 2>&1 </dev/null` in
 811 *GNU* | *BSD*)
 812   conky_LDFLAGS="$conky_LDFLAGS -Wl,-O1"
 813   AC_MSG_RESULT([yes])
 814   ;;
 815 *)
 816   AC_MSG_RESULT([no])
 817   ;;
 818 esac
 819
 820 dnl Solve multiple definitions (only necessary when gnulib is used)
 821 dnl conky_LDFLAGS="$conky_LDFLAGS -Xlinker -zmuldefs"
 822
 823 dnl
 824 dnl Da.
 825 dnl
 826
 827 conky_CFLAGS="$conky_CFLAGS -Wall -W"
 828
 829 dnl
 830 dnl debug
 831 dnl
 832
 833 AC_ARG_ENABLE([debug],
 834               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 835               [want_debug="$enableval"], [want_debug=no])
 836
 837 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 838   conky_CFLAGS="$conky_CFLAGS -g3"
 839   AC_DEFINE([DEBUG], 1, [Define for debugging])
 840 fi
 841
 842 dnl
 843 dnl testing
 844 dnl
 845
 846 AC_ARG_ENABLE([testing],
 847               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 848               [want_testing="$enableval"], [want_testing=no])
 849
 850 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 851   if test "x$want_debug" = "xyes"; then
 852     conky_CFLAGS="$conky_CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 853     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 854   else
 855     conky_CFLAGS="$conky_CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 856     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 857   fi
 858 fi
 859
 860 AC_SUBST(conky_CFLAGS)
 861 AC_SUBST(conky_LIBS)
 862 AC_SUBST(X11_LIBS)
 863
 864 AC_OUTPUT
 865
 866 dnl
 867 dnl Print summary
 868 dnl
 869 cat << EOF
 870
 871 $PACKAGE $VERSION configured successfully:
 872
 873  Installing into:   $prefix
 874  System config dir: $sysconfdir
 875  C compiler flags:  $conky_CFLAGS
 876  Libraries:         $conky_LIBS
 877  Linker flags:      $conky_LDFLAGS
 878
 879  * X11:
 880   X11 support:      $want_x11
 881   XDamage support:  $want_xdamage
 882   XDBE support:     $want_double_buffer
 883   Xft support:      $want_xft
 884
 885  * Music detection:
 886   Audacious:        $want_audacious
 887   BMPx:             $want_bmpx
 888   MPD:              $want_mpd
 889   MOC:              $want_moc
 890   XMMS2:            $want_xmms2
 891
 892  * General:
 893   OpenMP:           $want_openmp
 894   math:             $want_math
 895   hddtemp:          $want_hddtemp
 896   portmon:          $want_portmon
 897   RSS:              $want_rss
 898   Weather (METAR):  $want_weather
 899   wireless:         $want_wlan
 900   IBM:              $want_ibm
 901   nvidia:           $want_nvidia
 902   eve-online:       $want_eve
 903   config-output:    $want_config_output
 904   Imlib2:           $want_imlib2
 905   ALSA mixer:       $want_alsa
 906   apcupsd:          $want_apcupsd
 907   I/O stats:        $want_iostats
 908
 909  * Lua ($want_lua) bindings:
 910   Cairo:            $want_lua_cairo
 911   Imlib2:           $want_lua_imlib2
 912
 913 EOF